Удалить часть строки в файле до определенной фразы

@blackeangel · Регистрация: 22.07.2015

Студворк — интернет-сервис помощи студентам

Всем привет. Возможно уже где то было, но не нашел.
Есть файл содержащий

Code
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
 179        0   15392768 mmcblk0
 179        1       3072 mmcblk0p1
 179        2       5120 mmcblk0p2
 179        3      10240 mmcblk0p3
 179        4      10240 mmcblk0p4
 179        5        512 mmcblk0p5
 179        6        512 mmcblk0p6
 179        7      16384 mmcblk0p7
 179        8      16384 mmcblk0p8
 179        9       8192 mmcblk0p9
 179       10      10240 mmcblk0p10
 179       11        512 mmcblk0p11
 179       12       2048 mmcblk0p12
 179       13       6144 mmcblk0p13
 179       14       8192 mmcblk0p14
 179       15       5120 mmcblk0p15
 179       16       5120 mmcblk0p16
 179       17       1024 mmcblk0p17
 179       18      32768 mmcblk0p18
 179       19      37888 mmcblk0p19
 179       20    1572864 mmcblk0p20
 179       21     409600 mmcblk0p21
 179       22   13213184 mmcblk0p22
 179       23      16384 mmcblk0p23
 179       96       4096 mmcblk0rpmb
 179       64       4096 mmcblk0boot1
 179       32       4096 mmcblk0boot0
 179      128   31207424 mmcblk1
 179      129   31203328 mmcblk1p1

надо откинуть все что до mmcblk
чтобы получилось

Code
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
mmcblk0
mmcblk0p1
mmcblk0p2
mmcblk0p3
mmcblk0p4
mmcblk0p5
mmcblk0p6
mmcblk0p7
mmcblk0p8
mmcblk0p9
mmcblk0p10
mmcblk0p11
mmcblk0p12
mmcblk0p13
mmcblk0p14
mmcblk0p15
mmcblk0p16
mmcblk0p17
mmcblk0p18
mmcblk0p19
mmcblk0p20
mmcblk0p21
mmcblk0p22
mmcblk0p23
mmcblk0rpmb
mmcblk0boot1
mmcblk0boot0
mmcblk1
mmcblk1p1

знаю что это как то можно через чистый *.bat. просто пока не хочется подтягивать sed.
ну и записать это в тот же файл
Добавлено через 17 минут
А потом этот файл читать до конца файла в переменную, считая что строка это и есть переменная.
то есть если пускать for то должно что то типа
...
for i=(1строка ) to (последняя строка) do
цикл
....
но i не integer, а стринг или что то другое.
тк дальше цикл будет такой

Windows Batch file
1
2
adb.exe shell su -c "dd if=/dev/block/platform/%%i of=/sdcard/%%i.img bs=4096">>backup.log
adb.exe pull /sdcard/%%i.img>>backup.log

@ComSpec · 07.03.2016, 13:52

blackeangel, это можно сделать без реального удаления частей строк в файле:

Windows Batch file
1
2
3
4
5
6
7
8
9
10
@echo off
 
<"source.txt">"backup.log" (
 for /f "tokens=* delims=0123456789 " %%i in ('more') do @(
  adb.exe shell su -c "dd if=/dev/block/platform/%%i of=/sdcard/%%i.img bs=4096"
  adb.exe pull /sdcard/%%i.img
 )
)
 
exit/b

.

@blackeangel · 07.03.2016, 14:50 **[ТС]**

ComSpec, пояснительная третью строку пожалуйста?

@ComSpec · 07.03.2016, 15:35

Из исходного файла считываются по очереди все непустые строки, от каждой строки отсекаютя слева все цифры и пробелы, а каждая оставшаяся часть строки "поступает" на обработку приложением, и всё, что выводится в результате этой обработки, записывается в лог-файл.

Это соответствует схеме

<"Исходный файл" (Блок обработки данных) >"Результирующий файл"

,
но записано это так:

<"Исходный файл">"Результирующий файл" (Блок обработки данных)

.

@blackeangel · 07.03.2016, 18:00 **[ТС]**

ComSpec, а как теперь переделать чтобы откинуло те строки, в которых не содержится mmcblk0p ? Или чтобы брались только они?

@ComSpec · 07.03.2016, 19:01

Сообщение от blackeangel

... а как теперь переделать, чтобы откинуло те строки, в которых не содержится mmcblk0p?..

Код:

Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
@echo off
 
<"source.txt">"backup.log" (
 for /f "tokens=* delims=0123456789 " %%i in ('more') do @(
  cmd/v/c set x=%%i^& if "!x:mmcblk0p=!" neq "%%i"^
  adb.exe shell su -c "dd if=/dev/block/platform/%%i of=/sdcard/%%i.img bs=4096"^&^
  adb.exe pull /sdcard/%%i.img
 )
)
 
exit/b

.

Сообщение от blackeangel

... Или чтобы брались только они?

Код:

Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
@echo off
 
<"source.txt">"backup.log" (
 for /f "tokens=* delims=0123456789 " %%i in ('more') do @(
  cmd/v/c set x=%%i^& if "!x:mmcblk0p=!" equ "%%i"^
  adb.exe shell su -c "dd if=/dev/block/platform/%%i of=/sdcard/%%i.img bs=4096"^&^
  adb.exe pull /sdcard/%%i.img
 )
)
 
exit/b

.

@blackeangel · 07.03.2016, 20:51 **[ТС]**

ComSpec, блин... Прошу прощения, но задача оказалась куда сложнее... В общем перед тем как делать все это, надо найти самый большой блок (2й столбец справа-в нем записан р-р) содержащий mmcblk0p и удалить его. Иначе места не на чем не хватит. Либо как то придумать чтоб во время отрезания цифровой части это учитывалось и пропускалось...

Добавлено через 10 минут
В данном случае это блок mmcblk0p22

@ComSpec · 07.03.2016, 22:12

Код:

Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
@echo off
 
setlocal enabledelayedexpansion
<"source.txt">"backup.log" (
 for %%g in (1 2) do @(
  for /f "tokens=3*" %%h in ('more') do @(
   set x=%%i
   if "!x:mmcblk0p=!" neq "%%i" (
    if %%g equ 1 (
     if %%h gtr !max! set max=%%h
    ) else (
     if %%h neq !max! (
      adb.exe shell su -c "dd if=/dev/block/platform/%%i of=/sdcard/%%i.img bs=4096"
      adb.exe pull /sdcard/%%i.img
     )
    )
   )
  )
 )
)
endlocal
 
exit/b

.

Будут обрабатываться только строки, содержащие "mmcblk0p", но с пропуском строки, содержащей в заданном месте самое большое число для этого типа строк.

@blackeangel · 09.03.2016, 19:38 **[ТС]**

ComSpec, в конце строки надо отрезать перенос на новую. А то получается так

Code
1
2
mmcblk0p
...

Вместо

Code
1
mmcblk0p...

Добавлено через 6 часов 42 минуты
Вот файлы. На форум загрузить не удалось, поэтому в облаке [ссылка удалена]
Файлы для того чтобы было понятно про какие переносы и пробелы я говорил, тк форум их зажевал.

@alpap · 10.03.2016, 12:46

blackeangel, Переноса нет

Windows Batch file
1
echo Backuping block: %%i...

, программа ваша держит рамки правого края столбика и кажется будто это вторая строка, надо, если есть, регулировать вывод программы, типа -autosize, смотрите ключи.

@blackeangel · 10.03.2016, 13:29 **[ТС]**

alpap, как нет? Есть, если внимательно глянуть backup.log то там написано

Code
1
2
Backuping block: mmcblk0p1
...

А должно быть

Code
1
Backuping block: mmcblk0p1...

то есть в %%i содержится перенос на новую строку, который берется из blocks.txt. Вот его бы отсечь...

@alpap · 10.03.2016, 13:40

Сообщение от blackeangel

А должно быть

, я же написал, такое ощущение что так, на самом деле переноса нет, все в одной строке, напишите в блокноте строку из двух слов, а потом сузьте границы окна так что второе слово перескочит типа на вторую строку, на самом деле оно как было так и остается на первой.

@blackeangel · 10.03.2016, 14:35 **[ТС]**

alpap, вот смотрите.
Скрины показывающие что перенос есть

@alpap · 10.03.2016, 15:43

blackeangel, Попробуйте так:

Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
@echo off
setlocal enabledelayedexpansion
cd %~dp0
adb.exe start-server>backup.log
adb.exe devices >>backup.log
echo Press OK on your phone and press Enter
pause>nul
::adb.exe shell mount >>backup.log
adb.exe shell cat /proc/partitions > blocks.txt
<"blocks.txt">>"backup.log" (
for %%g in (1 2) do @(
for /f "tokens=3*" %%h in ('more') do @(
set "x=%%i"
if "!x:mmcblk0p=!" neq "%%i" (
if %%g equ 1 (
if %%h gtr !max! set max=%%h
) else (
if %%h neq !max! (
<nul set /p="Backuping block: %%i..."
adb.exe shell su -c "dd if=/dev/block/%%i of=/sdcard/%%i.img bs=4096"
adb.exe pull /sdcard/%%i.img
 
)
)
)
)
)
)
taskkill /F /IM adb.exe >>backup.log
Echo Done!
pause
::adb.exe shell su rm /sdcard/%%i.img

.

@blackeangel · 10.03.2016, 16:08 **[ТС]**

alpap, так же. Надо отрезать сзади символы CRLF чтобы не переносило, тк переменная %%i уже содержит.

Добавлено через 6 минут
Вот на этом скриншоте

Удалить часть строки в файле до определенной фразы

Видно что есть пробел вместо

Code
1
mmcblk0p4.img

он пишет

Code
1
mmcblk0p4 .img

а значит и посылает с пробелом.

@alpap · 10.03.2016, 17:34

"Переоберните" переменную:

Windows Batch file
1
2
set "var=%%i"
!var: =! или !var:~0,-1!

Добавлено через 5 минут
А вообще-то more любит пробел подсовывать, можно так попробовать, стр.12 на:

Windows Batch file
1
for /f "tokens=3*" %%h in ('more^|findstr /vrc:"^$"') do @(

Добавлено через 6 минут
Даже я смотрю выше пробел был (учитывался), может так еще попробовать, убрать табуляцию.

Windows Batch file
1
for /f "tokens=3* delims= " %%h in ('more') do @(

@blackeangel · 11.03.2016, 10:04 **[ТС]**

alpap, в общем попробовал, то же самое. Надо видимо удалить все пустые строки, а потом в переменную закидывать. Что то в инете не нашёл как просто удалить пустые строки.

@alpap · 11.03.2016, 15:28

Вот выше давал

Windows Batch file
1
>$ findstr /vrc:"^$" "file.txt"& move /y $ "file.txt"

.

Новые блоги и статьи Все статьи Все блоги /
Access VikBal 11.12.2025 Помогите пожалуйста !! Как объединить 2 одинаковые БД Access с разными данными.	Новый ноутбук volvo 07.12.2025 Всем привет. По скидке в "черную пятницу" взял себе новый ноутбук Lenovo ThinkBook 16 G7 на Амазоне: Ryzen 5 7533HS 64 Gb DDR5 1Tb NVMe 16" Full HD Display Win11 Pro	Музыка, написанная Искусственным Интеллектом volvo 04.12.2025 Всем привет. Некоторое время назад меня заинтересовало, что уже умеет ИИ в плане написания музыки для песен, и, собственно, исполнения этих самых песен. Стихов у нас много, уже вышли 4 книги, еще 3. . .	От async/await к виртуальным потокам в Python IndentationError 23.11.2025 Армин Ронахер поставил под сомнение async/ await. Создатель Flask заявляет: цветные функции - провал, виртуальные потоки - решение. Не threading-динозавры, а новое поколение лёгких потоков. Откат?. . .	Поиск "дружественных имён" СОМ портов Argus19 22.11.2025 Поиск "дружественных имён" СОМ портов На странице: https:/ / norseev. ru/ 2018/ 01/ 04/ comportlist_windows/ нашёл схожую тему. Там приведён код на С++, который показывает только имена СОМ портов, типа,. . .
Сколько Государство потратило денег на меня, обеспечивая инсулином. Programma_Boinc 20.11.2025 Сколько Государство потратило денег на меня, обеспечивая инсулином. Вот решила сделать интересный приблизительный подсчет, сколько государство потратило на меня денег на покупку инсулинов. . . .	Ломающие изменения в C#.NStar Alpha Etyuhibosecyu 20.11.2025 Уже можно не только тестировать, но и пользоваться C#. NStar - писать оконные приложения, содержащие надписи, кнопки, текстовые поля и даже изображения, например, моя игра "Три в ряд" написана на этом. . .	Мысли в слух kumehtar 18.11.2025 Кстати, совсем недавно имел разговор на тему медитаций с людьми. И обнаружил, что они вообще не понимают что такое медитация и зачем она нужна. Самые базовые вещи. Для них это - когда просто люди. . .	Создание Single Page Application на фреймах krapotkin 16.11.2025 Статья исключительно для начинающих. Подходы оригинальностью не блещут. В век Веб все очень привыкли к дизайну Single-Page-Application . Быстренько разберем подход "на фреймах". Мы делаем одну. . .	Фото: Daniel Greenwood kumehtar 13.11.2025

Удалить часть строки в файле до определенной фразы

Решение

Решение

Решение

@blackeangel 19 / 10 / 1 Регистрация: 22.07.2015 Сообщений: 908
	07.03.2016, 14:50 [ТС]
	ComSpec, пояснительная третью строку пожалуйста? 0

@blackeangel 19 / 10 / 1 Регистрация: 22.07.2015 Сообщений: 908
	07.03.2016, 18:00 [ТС]
	ComSpec, а как теперь переделать чтобы откинуло те строки, в которых не содержится mmcblk0p ? Или чтобы брались только они? 0

@blackeangel 19 / 10 / 1 Регистрация: 22.07.2015 Сообщений: 908
	07.03.2016, 20:51 [ТС]
	ComSpec, блин... Прошу прощения, но задача оказалась куда сложнее... В общем перед тем как делать все это, надо найти самый большой блок (2й столбец справа-в нем записан р-р) содержащий mmcblk0p и удалить его. Иначе места не на чем не хватит. Либо как то придумать чтоб во время отрезания цифровой части это учитывалось и пропускалось... Добавлено через 10 минут В данном случае это блок mmcblk0p22 0

@blackeangel 19 / 10 / 1 Регистрация: 22.07.2015 Сообщений: 908
	10.03.2016, 14:35 [ТС]
	alpap, вот смотрите. Скрины показывающие что перенос есть Миниатюры 0

@blackeangel 19 / 10 / 1 Регистрация: 22.07.2015 Сообщений: 908
	11.03.2016, 10:04 [ТС]
	alpap, в общем попробовал, то же самое. Надо видимо удалить все пустые строки, а потом в переменную закидывать. Что то в инете не нашёл как просто удалить пустые строки. 0