Вывести строку, являющуюся переменной

@alpap · Регистрация: 26.04.2015

Студворк — интернет-сервис помощи студентам

Надо решить такую задачку, только попрошу без участия "возможно, вероятно, наверное, попробуй"
Нужно четкое и правильное проверенное объяснение.

Вот так вывожу из файла строку "%f%"

Windows Batch file
1
2
3
4
@echo on
set "f=stroka"
<"file.txt" find "%%f%%"
pause

Вот так тоже могу вывести

Windows Batch file
1
2
3
4
@echo on
set "f=stroka"
<"file.txt" find "%%f%%"|set/p x=^& cmd/v/c call echo:!x!
pause

Так вижу искомую строку

Windows Batch file
1
2
3
4
@echo on
set "f=stroka"
for /f "delims=" %%a in ('type "file.txt"') do call echo %%a
pause

Но если беру в for

Windows Batch file
1
2
3
4
@echo on
set "f=stroka"
for /f "delims=" %%a in ('^<"file.txt" find "%%f%%"') do call echo %%a
pause

уже не выводится ни с call ни без, хотя, если закомментировать set и убрать call - выводится, но это-то все как раз надо.

И еще, чтобы новую тему не создавать
так переменная есть

Windows Batch file
1
type "file.txt"|set/p x=^& cmd/v/c echo:!x!

так нет

Windows Batch file
1
type "file.txt"|set/p x=^& cmd/v/c echo:!x:a=b!

надо именно так

Windows Batch file
1
type "file.txt"|set/p x=^& cmd/v/c echo !x:a=b!

почему?

greg zakharov · 03.06.2016, 13:48

Сообщение от alpap

Надо решить такую задачку...

В чем сложность?

Windows Batch file
1
2
3
4
5
6
@echo off
  setlocal
    set "f=stroka"
    for /f "delims=" %%i in ('3^<file.txt find "%f%" ^<^&3') do echo %%i
  endlocal
exit /b

Сообщение от alpap

почему?

Потому что невнимательны: !x:a=b! пытается заменить в переменной x все вхождения a на b.

@alpap · 03.06.2016, 14:13 **[ТС]**

greg zakharov,
Вы или пошутили...
В файле "file.txt", среди прочих есть строка "%f%", надо ее найти и вывести на экран, можно раскрыв можно нет или в файл тоже двумя вариантами. Ваш код в find раскрывает переменную и ищет уже "stroka", вместо "%f%", неужели я стал бы писать сюда такие мелочи?

Сообщение от greg zakharov

!x:a=b! пытается заменить в переменной x все вхождения a на b

да хоть 200раз, но почему тут echo:!x! двоеточие не мешает работе, а тут echo:!x:a=b! - мешает и приходиться писать echo !x:a=b!, а привычка дело сильное.

@ComSpec · 03.06.2016, 19:21

alpap, Вы, наверное, заметили, что я в своих кодах не использую echo:.

Делаю это не потому, что так писать нельзя, а потому что использование двоеточия, на мой взгляд, практически равносильно использованию точки, слешей, квадратных скобок и плюса.

На одном форуме даже было обсуждение преимуществ использования именно двоеточия, но случаи, которые там рассматривались для аргументация нежелательности использования других символов крайне маловероятны на практике.

Практика же на самом деле выявляет другие случаи...

Только использование открывающей круглой скобки, знака равенства, запятой и точки с запятой в Вашем случае не вызовет "катастрофических" последствий.

В своих кодах (они есть на нашем форуме, поленился искать

) для такого случая я использую echo( или echo=
(

Windows Batch file
1
type "file.txt"| set/p x=^& cmd/v/c echo(!x:a=b!

;

Windows Batch file
1
type "file.txt"| set/p x=^& cmd/v/c echo=!x:a=b!

)
или экранирую знак равенства в строке модифицированного расширения переменной
(

Windows Batch file
1
type "file.txt"| set/p x=^& cmd/v/c echo.!x:a^^^^=b!

;

Windows Batch file
1
type "file.txt"| set/p x=^& cmd/v/c echo[!x:a^^^^=b!

).

Хотя обычно я пишу примерно так:

Windows Batch file
1
type "file.txt"| cmd/v/c set/p x=^& echo.!x:a^^=b!

или так:

Windows Batch file
1
type "file.txt"| cmd/v/c "set/p x=& echo.!x:a^=b!"

.

Сообщение от alpap

... почему?

Есть многое на свете, друг Горацио,
Что и не снилось нашим мудрецам.

@alpap · 03.06.2016, 23:04 **[ТС]**

ComSpec, Спасибо, больше понравился больше (использовал не раз, но не придавал значения) вариант:

Windows Batch file
1
...cmd/v/c set/p x=^& echo.!x:a^^=b!

а вот почему все-таки конструкция

Windows Batch file
1
2
3
4
@echo on
set "f=stroka"
for /f "delims=" %%a in ('^<"file.txt" find "%%f%%"') do call echo %%a
pause

уперто не хочет выводить %f%, ни строкой ни раскрытой, я уже и экраны пробовал ставить, чего-то не хватает..., как же тогда искать подобные строки в файле?

YuS_2 · 03.06.2016, 23:43

Сообщение от alpap

уперто не хочет выводить %f%, ни строкой ни раскрытой

Если надо найти именно строку "%f%", то переменную такую использовать в сценарии нельзя. Интерпретатор раскрывает все переменные и соответственно, строку "%f%" найти будет невозможно, т.к. он воспринимает её только как переменную.
Т.е. при наличии
set "f=stroka"
переменная %f% раскрывается и найдены могут быть только строи, содержащие символы "stroka", в этом случае Вы увидите вывод. Т.о. при вхождении в цикл, происходит двойное раскрытие переменной...
для проверки можете добавить в файл строку "stroka"...

@alpap · 04.06.2016, 00:34 **[ТС]**

YuS_2,
Но ведь так-то вывожу

Windows Batch file
1
2
3
4
@echo on
set "f=stroka"
<"file.txt" find "%%f%%"
pause

что в цикле мешает?

YuS_2 · 04.06.2016, 06:34

Сообщение от alpap

так-то вывожу

Так нет двойного раскрытия, тут чистое экранирование символов %, поэтому работает.

Сообщение от alpap

что в цикле мешает?

В cmd вообще цикл или блоки со скобками - случай особый

@ComSpec · 04.06.2016, 12:00

Сообщение от alpap

... как же тогда искать подобные строки в файле?

Начну издалека...

1. Команда, вывод результата выполнения которой разбирается в цикле с помощью FOR, всегда выполняется в новом процессе cmd.exe.

Это можно увидеть, используя, например, такую конструкцию:

Windows Batch file
1
2
3
4
5
@echo off
 
for /f "delims=" %%a in ('^<"file.txt" find "%%f%%"^& wmic Process where Name^='cmd.exe' get CommandLine/value') do echo.%%a
 
pause

В результате мы получим все командные строки, с помощью которых запускались процессы cmd.exe, и одной из таких строк обязательно будет разбираемая команда:

Code
1
CommandLine=C:\Windows\system32\cmd.exe /c &lt;"file.txt" find "%f%"&amp; wmic Process where Name='cmd.exe' get CommandLine/value

.

2. Результат выполнения команды в новом процессе (в новом экземпляре интерпретатора) почти всегда идентичен результату выполнения команды с использованием CALL.

Как известно, синтаксис при таком использовании CALL как раз-таки основан на возможности использования так называемого двойного расширения переменных, то есть обрамления имён переменных удвоенными символами процента.

Но практически неизвестным фактом является допустимость применения удвоенных символов процента в конструкциях с cmd.

Например, если создать файл со строкой string, то при выполнении пакетного файла с кодами

Windows Batch file
1
2
3
4
5
6
7
@echo off
 
set "f=string"
 
<"file.txt" find "%f%"
 
pause

;

Windows Batch file
1
2
3
4
5
6
7
@echo off
 
set "f=string"
 
<"file.txt" call find "%f%"
 
pause

;

Windows Batch file
1
2
3
4
5
6
7
@echo off
 
set "f=string"
 
<"file.txt" call find "%%f%%"
 
pause

;

Windows Batch file
1
2
3
4
5
6
7
@echo off
 
set "f=string"
 
<"file.txt" cmd/c find "%f%"
 
pause

;

Windows Batch file
1
2
3
4
5
6
7
@echo off
 
set "f=string"
 
<"file.txt" cmd/c find "%%f%%"
 
pause

будет получен один и тот же результат — string.

Более того, удвоенные символы процента можно использовать и вместо восклицательных знаков в конструкциях с CMD /V.

То есть выполнение пакетного файла и с кодом

Windows Batch file
1
2
3
4
5
@echo off
 
set "f=string"& <"file.txt" call find "%%f%%"
 
pause

,
и с кодом

Windows Batch file
1
2
3
4
5
@echo off
 
set "f=string"& <"file.txt" cmd/v/c find "!f!"
 
pause

,
и с кодом

Windows Batch file
1
2
3
4
5
@echo off
 
set "f=string"& <"file.txt" cmd/v/c find "%%f%%"
 
pause

выдаст также один и тот же корректный результат — string.

3. Чтобы использовать содержащие символы процента строки в конструкциях с cmd, необходимо не только удваивать эти символы, но и ещё применять экранирование.

А в случае использования команды FIND или других команд, требующих использования кавычек, ещё необходимо экранировать и некоторые из этих кавычек.

Примеры:

Windows Batch file
1
2
3
4
5
6
7
@echo off
 
set "f=string"
 
<"file.txt" cmd/c find ^^"^%%f^%%"
 
pause

;

Windows Batch file
1
2
3
4
5
6
7
@echo off
 
set "f=string"
 
cmd/c findstr ^^%%f^^%% "file.txt"
 
pause

;

Windows Batch file
1
2
3
4
5
6
7
8
@echo off
 
set "f=string"
 
for /f "delims=" %%a in ('^<"file.txt" find ^^"^%%f^%%"') do echo %%a
for /f "delims=" %%a in ('^<"file.txt" find ^^"^%%f^%%"') do call echo %%a
 
pause

;

Windows Batch file
1
2
3
4
5
6
7
8
@echo off
 
set "f=string"
 
for /f "delims=" %%a in ('findstr ^^%%f^^%% "file.txt"') do echo %%a
for /f "delims=" %%a in ('findstr ^^%%f^^%% "file.txt"') do call echo %%a
 
pause

.

Новые блоги и статьи Все статьи Все блоги /
делаю науч статью по влиянию грибов на сукцессию anaschu 13.03.2026 прикрепляю статью	SDL3 для Desktop (MinGW): Создаём пустое окно с нуля для 2D-графики на SDL3, Си и C++ 8Observer8 10.03.2026 Содержание блога Финальные проекты на Си и на C++: hello-sdl3-c. zip hello-sdl3-cpp. zip Результат:	Установка CMake и MinGW 13.1 для сборки С и C++ приложений из консоли и из Qt Creator в EXE 8Observer8 10.03.2026 Содержание блога MinGW - это коллекция инструментов для сборки приложений в EXE. CMake - это система сборки приложений. Здесь описаны базовые шаги для старта программирования с помощью CMake и. . .	Как дизайн сайта влияет на конверсию: 7 решений, которые реально повышают заявки Neotwalker 08.03.2026 Многие до сих пор воспринимают дизайн сайта как “красивую оболочку”. На практике всё иначе: дизайн напрямую влияет на то, оставит человек заявку или уйдёт через несколько секунд. Даже если у вас. . .
Модульная разработка через nuget packages DevAlt 07.03.2026 Сложившийся в . Net-среде способ разработки чаще всего предполагает монорепозиторий в котором находятся все исходники. При создании нового решения, мы просто добавляем нужные проекты и имеем. . .	Модульный подход на примере F# DevAlt 06.03.2026 В блоге дяди Боба наткнулся на такое определение: В этой книге («Подход, основанный на вариантах использования») Ивар утверждает, что архитектура программного обеспечения — это структуры,. . .	Управление камерой с помощью скрипта OrbitControls.js на Three.js: Вращение, зум и панорамирование 8Observer8 05.03.2026 Содержание блога Финальная демка в браузере работает на Desktop и мобильных браузерах. Итоговый код: orbit-controls-threejs-js. zip. Сканируйте QR-код на мобильном. Вращайте камеру одним пальцем,. . .	SDL3 для Web (WebAssembly): Синхронизация спрайтов SDL3 и тел Box2D 8Observer8 04.03.2026 Содержание блога Финальная демка в браузере. Итоговый код: finish-sync-physics-sprites-sdl3-c. zip На первой гифке отладочные линии отключены, а на второй включены:. . .

Вывести строку, являющуюся переменной

Решение

Решение