Удаление файлов нулевого размера в каталогах и подкаталогах

@Myrena_fox · Регистрация: 25.09.2015

Author24 — интернет-сервис помощи студентам

Добрый вечер.

Нужна помощь в корректировке маленького скрипта:

Windows Batch file

@Echo Off
SetLocal
For /F "Tokens=*" %%A In ('Dir /B /S /AD 2^>nul^|Sort /R') Do (
    For /F "Tokens=3*" %%B In ('Dir "%%A" /S /A-D /N /-C 2^>nul^|FindStr /irc:":[0-5][0-9] *0"') Do Del /F /Q "%%A\%%C" 2>nul&&Echo:Файл %%A\%%C удален.
    RD "%%A" 2>nul&&Echo:Каталог %%A удален.
)

Он удаляет все нулевые файлы в каталогах и всех подкаталогах и пустые каталоги. Нужно сделать так, что-бы скрипт удалял только нулевые файлы , а пустые каталоги не трогал.

Прошу помощи в знатоков.
Спасибо

@ComSpec · 07.11.2016, 03:59

Windows Batch file

@echo off
 
for /f "delims=" %%i in ('2^>nul dir/ad/b') do (
 for /f "delims=" %%j in ('2^>nul dir/a-d/b/s "%%i"') do (
  if %%~zj equ 0 del/a/f "%%j"&& set f=%%j&& (
   cmd/v/c echo Файл "!f:*%CD%\=!" удалён.
  )
 )
)

@Myrena_fox · 07.11.2016, 04:09 **[ТС]**

Как всегда Вы меня выручаете. Спасибо

YuS_2 · 07.11.2016, 04:27

Сообщение от Myrena_fox

сделать так, что-бы скрипт удалял только нулевые файлы , а пустые каталоги не трогал.

Другими словами, чтобы каталоги совсем не трогал? Тогда оставьте один цикл, который используется для удаления файлов:

Windows Batch file

@echo off
set "src=C:\Test"
if not exist "%src%" echo Error. Not exist "%src%"&pause&exit
pushd "%src%"
For /F "Tokens=3*" %%B In ('Dir /S /A-D /N /-C 2^>nul^|FindStr /irc:":[0-5][0-9] *0"') Do Del /F /Q "%%~fC" 2>nul&&Echo:Файл %%~C удален.
popd
pause

@alpap · 07.11.2016, 11:38

До кучи:
По 0-му размеру

Windows Batch file

@echo off
set "d=papka"
for /f "tokens=1,4" %%a in ('where /t /r "papka" *') do if %%a==0 del "%%b"
exit

По 0-му содержанию

Windows Batch file

@echo off
set "d=papka"
for /f "delims=" %%a in ('2^>nul dir/a-d/b/s "%d%\*"') do >nul findstr/rvc:"^$" "%%a" || del "%%a"
exit

Добавлено через 11 минут

Не по теме:

YuS_2,
Ваш код не будет работать для подпапок и более правильно записать его так:

Windows Batch file

@echo off
setlocal
set "d=papka"
for /f "tokens=3*" %%a in ('2^>nul dir/a-d/-c "%d%\*"^|findstr/brc:"[^ ][^ ]*  *[^ ][^ ]*  *0 "') do del /a/f "%d%\%%b"
endlocal
exit/b

но, повторюсь, вглубь удалять он не будет, мы работаем только с именем, нет полного пути, можете проверить, напишет что файл удален, но на самом деле он будет на месте.

YuS_2 · 08.11.2016, 05:25

Сообщение от alpap

Ваш код не будет работать для подпапок и более правильно записать его так

Да, всё верно. Код не совсем мой, это чуть подкорректированная строка из первого сообщения и, к сожалению, не проверил её... спасибо.
Но записать этот код без ключа /s в команде dir :

Сообщение от alpap

нет полного пути, можете проверить

тоже не совсем правильно.
Вообще, я бы сделал так:

Windows Batch file

@echo off
set "src=C:\Test"
if not exist "%src%" echo Error. Not exist "%src%"&pause&exit
for /f "delims=" %%a in ('2^>nul dir /b/s/a-d/os "%src%"') do if %%~za==0  del /f/q/a "%%~a"&echo Файл %%~a удален.
pause

Или даже такой вот, более быстрый (не требуется обработка ненулевых файлов), вариант:

Windows Batch file

@echo off
set "src=C:\Test"
if not exist "%src%" echo Error. Not exist "%src%"&pause&exit
for /f "tokens=3*" %%a in ('where /r "%src%" /f /t * ^|findstr /brc:"^ *0 "') do del /f/q/a %%b&echo Файл %%b удален.
pause

@Myrena_fox 0 / 0 / 0 Регистрация: 25.09.2015 Сообщений: 74
	07.11.2016, 04:09 [ТС]	3
	Как всегда Вы меня выручаете. Спасибо 0

	08.11.2016, 05:25

Удаление файлов нулевого размера в каталогах и подкаталогах

Решение