Удаление файлов нулевого размера в каталогах и подкаталогах

@Echo Off
SetLocal
For /F "Tokens=*" %%A In ('Dir /B /S /AD 2^>nul^|Sort /R') Do (
    For /F "Tokens=3*" %%B In ('Dir "%%A" /S /A-D /N /-C 2^>nul^|FindStr /irc:":[0-5][0-9] *0"') Do Del /F /Q "%%A\%%C" 2>nul&&Echo:Файл %%A\%%C удален.
    RD "%%A" 2>nul&&Echo:Каталог %%A удален.
)

@echo off
 
for /f "delims=" %%i in ('2^>nul dir/ad/b') do (
 for /f "delims=" %%j in ('2^>nul dir/a-d/b/s "%%i"') do (
  if %%~zj equ 0 del/a/f "%%j"&& set f=%%j&& (
   cmd/v/c echo Файл "!f:*%CD%\=!" удалён.
  )
 )
)

@echo off
set "src=C:\Test"
if not exist "%src%" echo Error. Not exist "%src%"&pause&exit
pushd "%src%"
For /F "Tokens=3*" %%B In ('Dir /S /A-D /N /-C 2^>nul^|FindStr /irc:":[0-5][0-9] *0"') Do Del /F /Q "%%~fC" 2>nul&&Echo:Файл %%~C удален.
popd
pause

@echo off
set "d=papka"
for /f "tokens=1,4" %%a in ('where /t /r "papka" *') do if %%a==0 del "%%b"
exit

@echo off
set "d=papka"
for /f "delims=" %%a in ('2^>nul dir/a-d/b/s "%d%\*"') do >nul findstr/rvc:"^$" "%%a" || del "%%a"
exit

@echo off
set "src=C:\Test"
if not exist "%src%" echo Error. Not exist "%src%"&pause&exit
for /f "delims=" %%a in ('2^>nul dir /b/s/a-d/os "%src%"') do if %%~za==0  del /f/q/a "%%~a"&echo Файл %%~a удален.
pause

@echo off
set "src=C:\Test"
if not exist "%src%" echo Error. Not exist "%src%"&pause&exit
for /f "tokens=3*" %%a in ('where /r "%src%" /f /t * ^|findstr /brc:"^ *0 "') do del /f/q/a %%b&echo Файл %%b удален.
pause