Копирование новых файлов каждые 30 минут

::-------- file must be save in plain text, codepage 866 aka OEM
@echo off &@prompt $g
cls
SetLocal EnableExtensions EnableDelayedExpansion
pushd "%~dp0" || (echo.%~nx0: не могу перейти в каталог "%~dp0" &pause&exit /b 1)
 
:: %d_State% каталог для ведения статистики, создаётся в каталоге со скриптом
:: не удалять содержимое каталога %d_State%!
set "d_State=STATE"
if NOT exist "%d_State%" md "%d_State%" || (echo.%~nx0: не могу создать каталог "%d_State%" &pause&exit /b 1)
 
:: %f_LOG% файл - журнал работы, лежит в каталоге %d_State%
set "f_LOG=%d_State%\%~n0.LOG"
if NOT exist "%f_LOG%" >nul 2>nul copy nul "%f_LOG%" || (echo.%~nx0: не могу писать в файл "%f_LOG%" &pause&exit /b 1)
 
:: %f_Snapshot% снимок скопированных файлов ПРЕДЫДУЩЕГО запуска скрипта,
:: лежит в каталоге %d_State%
set "f_Snapshot=Snapshot"
 
:: %SYSLOG% что-то вроде макроса для журналирования
set "SYSLOG=call:logged"
%SYSLOG% "начало работы"
 
:: %d_Source% в этот каталог каждые 5 минут
:: сваливаются всякие разные непонятные файлы
set "d_Source=диск:\путь\cat-1"
if "%d_Source:~-1%" == "\" set "d_Source=%d_Source:~0,-1%"
if NOT exist "%d_Source%" (
  %SYSLOG% "нет каталога-источника '%d_Source%'"
  goto ExitError
)
 
:: скрипт должен копировать (не перемещать) все подходящие
:: под правило файлы в каталог %d_Destination%
set "d_Destination=диск:\путь\cat-2"
if "%d_Destination:~-1%" == "\" set "d_Destination=%d_Destination:~0,-1%"
if NOT exist "%d_Destination%" (
  %SYSLOG% "нет каталога-приёмника '%d_Destination%'"
  goto ExitError
)
 
if "%d_Source" == "%d_Destination%" (
  %SYSLOG% "каталог-приёмник совпадает с каталогом-источником '%d_Destination%'"
  goto ExitError
)
 
:: скрипт должен искать в %d_Source% файлы,
:: начинающиеся с Английской буквы I, с любым расширением
set "mask-file=I*.*"
 
if NOT exist "%d_State%\%f_Snapshot%" (
  %SYSLOG% "первый запуск, создаём снимок копирумых файлов"
  >nul copy nul "%d_State%\%f_Snapshot%"
)
:: %$%  снимок скопированных файлов ТЕКУЩЕГО запуска скрипта,
:: лежит в каталоге %temp%
set "$=%temp%\%f_Snapshot%"
 
:: %CNT%    скопировано файлов в ТЕКУЩЕМ запуске скрипта
:: %ERROR%  кол-во ошибок копирования файлов в ТЕКУЩЕМ запуске скрипта
set /a CNT=0,ERROR=0
 
:: сканируем каталог %d_Source% на предмет нужных файлов
for /f "usebackq tokens=*" %%v in (`2^>nul dir "%d_Source%\%mask-file%" /a:-d /b`) do (
  call :GetLine "%d_Source%\%%~v"
  rem !GetLine! содержит что-то типа
  rem "<имя файла>|<длина файла>|<timestamp файла>"
  rem ЕЖЕЛИ этого файла НЕТ в снимке файлов ПРЕДЫДУЩЕГО запуска скрипта
  rem ТО скопируем этот файл в каталог назначения
  <"%d_State%\%f_Snapshot%" >nul find /c "!GetLine!" 
  if !ERRORLEVEL! == 1 call :copy2destintion "%d_Source%\%%~v" && (
          rem удалось скопировать файл, отметим это
          set /a CNT+=1 
          %SYSLOG% "'%d_Source%\%%~v'")
  echo:"!GetLine!"
)>"%$%"
 
:: переписываем снимок скопированных файлов
>nul 2>nul move /y "%$%" "%d_State%\%f_Snapshot%"
goto ExitOK
-----------
:copy2destintion    %1 имя файла
  >nul copy /y /b "%~1" "%d_Destination%\%~nx1" && exit /b 0
  >nul timeout /t 5
  >nul copy /y /b "%~1" "%d_Destination%\%~nx1" && exit /b 0
  %SYSLOG% "ошибка копировании '%~1'"
  set /a ERROR+=1
exit /b 1
-----------
:GetLine        %1 имя файла 
  setlocal
  set "return=%0"
  set "return=%return:~1%"
  endlocal & set "%return%=%~nx1|%~z1|%~t1"
exit /b
-----------
:LOGGED
  >>%f_LOG% echo:%date% %time:~0,8% %~1
exit /b
-----------
:ExitError
  SetLocal DisableDelayedExpansion
  %SYSLOG% "завершение работы, АВАРИЯ!"
  %SYSLOG% " "
  popd
exit /b 2
-----------
:ExitOK
  SetLocal DisableDelayedExpansion
  %SYSLOG% "файлов: %CNT%"
  if %ERROR% NEQ 0 (
    %SYSLOG% "завершение работы, количество ошибок при копировании: %ERROR%"
  ) else (
    %SYSLOG% "завершение работы, OK!"
  )
  %SYSLOG% " "
  popd
exit /b 0