Определение версии Java и версии браузера

@echo off
set "p_inet=%Programfiles%\Internet Explorer\iexplore.exe"
powershell "(gi '%p_inet%').versionInfo.fileversion"
pause

@echo off
  setlocal enabledelayedexpansion
    set "key=HKCR\http\shell\open\command"
    for /f "tokens=2,*" %%i in (
      'reg query %key% /ve ^| findstr /irc:"reg_sz"'
    ) do set "cmd=%%j"&set "cmd=!cmd:%%1=!"
    set "cmd=%cmd:"=%"   % rem : удаляем кавычки
    set "cmd=%cmd:~,-1%" % rem : удаляем '\0' символ
    echo:Default browser path : %cmd%
    for %%i in ("%cmd%") do set "rex=%%~ni"
    set "key=HKLM\SOFTWARE\Microsoft\Windows"
    set "key=%key%\CurrentVersion\Uninstall"
    for /f "delims=" %%i in (
      'reg query %key% ^| findstr /irc:"!rex!"'
    ) do (
      for /f "tokens=2,*" %%j in (
        'reg query "%%i" /v DisplayVersion^
         ^| findstr /irc:"reg_sz"'
      ) do set "ver=%%k"
    )
    echo:Default browser ver. : %ver%
  endlocal
exit /b

@echo off
setlocal enabledelayedexpansion
:: Получаем версию браузера по умолчанию
:: первый вариант - ftype читает из HKLM, поэтому дает не совсем достоверную информацию - бразуер уже может быть переназначен
echo "--------------------"
for /f "tokens=2 delims==-" %%i in ('ftype http') do (
  set x=%%i
  set x=!x:~1,-2!
  set x=!x:\=\\!
)
 
call :get_version "%x%"
echo HKLM:%x%: %ver%
:: Получаем версию браузера по умолчанию
::второй вариант - читаем из HKCU - здесь должен быть записан последний браузер, который пользователь назначил дефолтным
set ver=
for /f "skip=2 tokens=2 delims=REG_SZ-" %%i in ('reg query HKEY_CURRENT_USER\Software\Classes\http\shell\open\command') do (
  set x=%%i
  set x=!x:~5,-2!
  set x=!x:\=\\! 
)
 
call :get_version "%x%"
echo HKCU:%x%: !ver!
echo Версии Java: JRE\JDK
echo "--------------------"
:: узнаем локацию java
for /f "tokens=* delims=" %%i  in ('where /R "%programfiles%\java" java.exe') do (
  set "java=!java!"%%i" "
)
set java=!java:\=\\!
:: версии java
for  %%i in (%java%) do (
  set ver=
  rem спрашиваем версию у java через опцию -version 
  rem а также читаем ее из атрибутов файла
  %%i -version &call :get_version %%i
  echo.%%~i: !ver!
  echo "--------------------"
  
)
 
pause&exit/b
 
:get_version
for /f "skip=1 usebackq" %%i in (`wmic path CIM_Datafile where name^='%~1' get version`) do (
  set ver=!ver!%%i
)