Обработка pdf файлов в каталогах с подкаталогами

@echo off & prompt $G
setlocal EnableExtensions EnableDelayedExpansion
 
                                :: программа конвертации .PDF в .TXT
 
set "pCONVERT=pdftotext.exe"
 
                                :: %dirSRC% корневой каталог с исходными *.pdf
                                :: !!! без завершающего \
 
set "dirSRC=.\dir1"
call :full "%dirSRC%"
 
                                :: %dirDST% каталог с конвертированными файлами из *.pdf
                                :: !!! без завершающего \
 
set "dirDST=.\dir2"
>nul 2>nul md "%dirDST%"
 
                                :: счётчик файлов *.pdf
set /a CNT=0
 
for /f "tokens=*" %%F in ('dir /b/s "%dirSRC%\*.pdf"') do (
  set /a CNT+=1 & set "dirOUT=%%~dpF" & set "dirOUT=%dirDST%\!dirOUT!"
  set "dirOUT=!dirOUT:*%dirSRC%=!"
  if "!dirOUT!" == "\" (
    %pCONVERT% "%%~fF" "%dirDST%\%%~nF.txt"
  ) else (
    >nul 2>nul md %dirDST%!dirOUT:~0,-1!
    %pCONVERT% "%%~fF" "%dirDST%!dirOUT!%%~nF.txt"
  )
)
if CNT EQU 0 (echo:file *.pdf not found in %dirSRC%&pause&exit /b 1)
echo:%CNT% file(s) convert from *.pdf to *.txt&pause&exit /b 0
 
:full
  set "dirSRC=%~f1"
  goto :EOF