Перемещение выделенных строк ТЧ из одного документа в другой

&НаСервере
Процедура ПеренестиСтрокиНаСервере()   
    ТабИсходная = Объект.ОборудованиеИКомплектующие.Выгрузить();
    ОтборТаб = Новый Структура("Флаг", Истина);
    СтрокиДляПеремещения = ТабИсходная.НайтиСтроки(ОтборТаб);
    // проверка на предмет наличия выбранного ДокументаНазначения
    Если НЕ ЗначениеЗаполнено(ДокументНазначения) Тогда  
        Сообщить("Необходимо выбрать спецтехнику назначения!");
        Возврат;    
    КонецЕсли;
    // проверка на предмет наличия отмеченных флагом строк
    Если СтрокиДляПеремещения.Количество() = 0 Тогда   
        Сообщить("Необходимо выбрать строки для перемещения!");
        Возврат;   
    КонецЕсли;
    ДокОбъект = ДокументНазначения.ПолучитьОбъект();
    Для Каждого Строка Из СтрокиДляПеремещения Цикл   
        НоваяСтрока = ДокОбъект.ОборудованиеИКомплектующие.Добавить();    
        ЗаполнитьЗначенияСвойств(НоваяСтрока, Строка);    
        НоваяСтрока.Примечание = "Перемещено из документа №" + Объект.Номер +", спецтехника " + Объект.Спецтехника +", дата перемещения " +   Формат(ТекущаяДата(), "ДФ=dd.MM.yyyy") + ".";    
        НоваяСтрока.Флаг = Ложь;  // сбрасываем флаг в документе назначения 
    КонецЦикла;
    // в исходном документе оставляем строки, которые небыли отмечены для перемещения
    Объект.ОборудованиеИКомплектующие.Загрузить(ТабИсходная.Скопировать(Новый Структура("Флаг", Ложь)));
    Записать(Новый Структура("РежимЗаписи", РежимЗаписиДокумента.Проведение)); // проводим текущий документ
    ДокОбъект.Записать(РежимЗаписиДокумента.Проведение, РежимПроведенияДокумента.Неоперативный); // проводим документ назначения
    Сообщить("Перемещение выполнено!");
КонецПроцедуры
 
&НаКлиенте
Процедура ПеренестиСтроки(Команда)
    ПеренестиСтрокиНаСервере(); 
КонецПроцедуры