Поиск файлов

Option Explicit
Const Alg = "MD5" ' SHA1, SHA256, SHA386, SHA512
Const ES  = "es.exe"
Const Search = "Search.txt"
Const Result = "Result.txt"
' Формат строк в Search.txt: <расширение>|<размер>|<хэш>
'———————————————————————————————————————————————————————
Dim oWSS: Set oWSS = CreateObject("Wscript.Shell")
If Left(Right(LCase(WSH.FullName), 11), 1) = "w" Then oWSS.Run _
"%ComSpec% /c mode con cp select=65001|cscript.exe //NoLogo """ & WSH.ScriptFullName & """", 0: WSH.Quit
 
Dim oHash, oFSO, oLog, oCvt, oList, Str, Arr, Std, Line, ArrB, i, Sum, Find
Set oHash = CreateObject("System.Security.Cryptography." & Alg & "CryptoServiceProvider")
Set oFSO  = CreateObject("Scripting.FileSystemObject")
Set oCvt  = CreateObject("OlePrn.OleCvt")
Set oList = oFSO.OpenTextFile(Search)
 
Do: Str = oList.ReadLine
   If InStr(Str, "|") Then
      Arr = Split(Str, "|")
      Set Std = oWSS.Exec(ES & " -sort path-ascending file:*." & Arr(0) & " size:" & Arr(1)).StdOut
      Do: Line = oCvt.ToUnicode(Std.ReadLine, 65001)
         If oFSO.FileExists(Line) Then
            With CreateObject("SAPI.spFileStream")
               .Open Line, 0: .Read ArrB, Arr(1): .Close
            End With
            ArrB = oHash.ComputeHash_2((ArrB)): Sum = ""
            For i = 1 To LenB(ArrB)
               Sum = Sum & Right("0" & Hex(AscB(MidB(ArrB, i, 1))), 2)
            Next
            If StrComp(Sum, Arr(2), 1) = 0 Then Find = Find & vbCrLf & Arr(2) & " " & Line
         End If
      Loop Until Std.AtEndOfStream: Std.Close
   End If
Loop Until oList.AtEndOfStream: oList.Close
 
If IsEmpty(Find) Then
   MsgBox "Совпадений нет!", 4160, " Поиск файлов по " & Alg
Else
   With oFSO.CreateTextFile(Result, 1, 1) .Write Mid(Find, 3): .Close: End With
   oWSS.Run """" & Result & """"
End If
Set oList = Nothing: Set oLog = Nothing: Set oWSS = Nothing
Set oHash = Nothing: Set oFSO = Nothing: Set oCvt = Nothing