Скриптом создать архив 1.7z, внутри архива 1.7z файлы БЕЗ расширения

rar a Тест "D:\Users\Administrator\Desktop\Новая папка\Тест\*."

@REM 7zip maker script  v. 0.1 alpha
@ECHO OFF
CHCP 65001> NUL
 
 
 
SET EXCLUDE_LIST="EXCLUDE_LIST.TXT"
SET MANSEARCHFOLDERS=
SET EXCLUDE_FLAG=
 
 
:: имя создаваемого архива
SET Arc_FILE=BACKUP
 
:: файлы и папки этого директория будут помещены в архив
SET "DIR_2_Arc=TEMP X.1"
 
:: куда сохранить архив
SET "DIR_2_SAVE="
 
:: WRAPPER_FLAG=1 включит в архив и сам директорий, а не только его содержимое.
SET WRAPPER_FLAG=0
 
 
REM CALL :MAKE_Arc "%DIR_2_Arc%" "%DIR_2_SAVE%" "%Arc_FILE%" NOEXCL
CALL :MAKE_Arc "%DIR_2_Arc%" "%DIR_2_SAVE%" "%Arc_FILE%"
 
GOTO END
 
 
 
 
 
:MAKE_Arc
IF "%EXCLUDE_FLAG%"=="" SET EXCLUDE_FLAG=0
 
SET "DDFFILE1=%TEMP%\FILE_LIST.TXT"
 
 
IF "%DIR_2_Arc%"=="" GOTO ERRR
SET DIR_2_ArcW=
SET PATH_2_DIR=
SET DRIVE_OF_DIR=
SET FOLDER_2_CAB=
 
 
CALL :GET_DIRS "%DIR_2_Arc%" DIR_2_Arc DIR_2_ArcW PATH_2_DIR DRIVE_OF_DIR FOLDER_2_Arc
IF ERRORLEVEL 1 GOTO ERRR
 
SET "DIR_2_SAVE=%~2"
IF "%FOLDER_2_Arc%"=="" SET "FOLDER_2_Arc=%DRIVE_OF_DIR%\"
IF "%DIR_2_SAVE%"=="" SET "DIR_2_SAVE=%CD%"
 
 
 
IF EXIST "%DIR_2_Arc%\" (
FOR /F "usebackq" %%X IN ( `DIR /B "%DIR_2_Arc%"` ) DO GOTO EFOLDERS
IF "%DNE%"=="" ECHO DIRECTORY "%DIR_2_Arc%" IS EMPTY& GOTO ERRR
  ) ELSE (ECHO NO DIRECTORY "%DIR_2_Arc%"& GOTO ERRR)
 
 
:EFOLDERS
 
 
SET "DIR_2_Arc_BASE=%DIR_2_Arc%"
IF "%WRAPPER_FLAG%"=="" SET /A WRAPPER_FLAG=0
 
IF %WRAPPER_FLAG% GTR 0 (
SET "WRAPPERDIR=%FOLDER_2_Arc%\"
SET "DIR_2_Arc=%DIR_2_ArcW%\"
 )
IF EXIST %EXCLUDE_LIST% IF NOT "%~4"=="NOEXCL" CALL :CHEXCL "%WRAPPERDIR%"
 
SET /A C=0
SET _DIR=
BREAK> "%DDFFILE1%"
 
 
 
REM --------------------
REM ECHO Generate a FILE_LIST file via a recursive directory listingly:
REM --------------------
CALL :PROCESSING_FOLDERS "%DIR_2_Arc_BASE%"
 
 
 
ECHO+
REM --------------------
ECHO Run 7Zip against the file List
 
 
IF EXIST "%DIR_2_SAVE%\%~3.7z*" DEL "%DIR_2_SAVE%\%~3.7z*"
 
SET EXCLCMD=
IF %EXCLUDE_FLAG% GTR 0 SET EXCLCMD=-x@"%TEMP%\MYEXCLUDELIST.TXT"
 
 
"C:\Program Files\7-Zip\7z" a -t7z "%DIR_2_SAVE%\%~3" @"%DDFFILE1%" %EXCLCMD%
 
 
ECHO+
ECHO ----- off ----------
PAUSe
 
GOTO :EOF
 
 
:PROCESSING_FOLDERS
CALL :FRESEARCH "%DIR_2_Arc_BASE%"
CALL :PROC "%DIR_2_Arc_BASE%" C
CALL :PROC "%_DIR%" C CUR
GOTO:EOF
 
 
:FRESEARCH
SET "DIRTREE=%~1\"
 
IF %C% EQU 0 (
IF %WRAPPER_FLAG% GTR 0 (
ECHO "%DIRTREE%">> "%DDFFILE1%"
 )
 
FOR /F "usebackq tokens=* delims=" %%X IN (`DIR /AD /B "%DIRTREE%" 2^>NUL`) DO (
CALL :PROC "%DIRTREE%%%~X" C
CALL :FRESEARCH "%DIRTREE%%%~X"
 )
 )
GOTO :EOF
 
 
:PROC
(SET /A %~2+=1
SET "_DIR=%~1\"
SET "CUR_DIR=%~1"
 
CALL SET "DESTDIR=%%WRAPPERDIR%%%%_DIR:%DIR_2_Arc_BASE%\=%%"
 
IF %C% GTR 0 (
<NUL SET /P=">> %DESTDIR%"
IF %WRAPPER_FLAG% EQU 0 (
IF "%~3"=="" ECHO "%CUR_DIR%\">> "%DDFFILE1%"
IF NOT "%~3"=="" ECHO "%CUR_DIR%\*">> "%DDFFILE1%"
 )
 
  IF %EXCLUDE_FLAG% EQU 2 (
   FOR %%Z IN ( %MANSEARCHFOLDERS% ) DO (
    REM ECHO %WRAPPERDIR%%%Z -- ########## %DESTDIR%
REM PAUSE
    IF "%WRAPPERDIR%%%Z"=="%DESTDIR%" (
     FOR /F "usebackq tokens=* delims=" %%# IN (`DIR /A-D /B "%CUR_DIR%" 2^>NUL`) DO (
      IF "%%~x#"=="" ECHO "%DESTDIR%%%#">> "%TEMP%\MYEXCLUDELIST.TXT" ) )
 
    IF %WRAPPER_FLAG% EQU 0 IF "%%Z"=="\" IF "%DESTDIR%"=="" (
     FOR /F "usebackq tokens=* delims=" %%# IN (`DIR /A-D /B "%CUR_DIR%" 2^>NUL`) DO (
      IF "%%~x#"=="" ECHO "%DESTDIR%%%#">> "%TEMP%\MYEXCLUDELIST.TXT" ) )
 
    IF %WRAPPER_FLAG% GTR 0 IF "%WRAPPERDIR%%%Z"=="%WRAPPERDIR%\" IF "%DESTDIR%"=="%WRAPPERDIR%" (
     FOR /F "usebackq tokens=* delims=" %%# IN (`DIR /A-D /B "%CUR_DIR%" 2^>NUL`) DO (
      IF "%%~x#"=="" ECHO "%DESTDIR%%%#">> "%TEMP%\MYEXCLUDELIST.TXT" ) )
    )
   )
 
ECHO+
 )
REM - - - - - - -
 )
 
GOTO :EOF
 
 
 
:GET_DIRS
IF "%~1"=="" EXIT /B 1
SET "DNO=%~dpnx1"
SET DNO_2=
SET DNO_3=
CALL :RMESL "%DNO%" DNO
 
(SET "%~2=%DNO%"
SET "%~5=%~d1")
CALL :GET_PARENTF "%DNO%" DNO DNO_2 DNO_3
(SET "%~3=%DNO%"
SET "%~4=%DNO_2%"
SET "%~6=%DNO_3%")
GOTO :EOF
 
:GET_PARENTF
SET "TMPDNO=%~dp1"
CALL :RMESL "%TMPDNO%" TMPDNO
SET "%~2=%TMPDNO%"
IF "%TMPDNO%"=="%~1" (
ECHO %TMPDNO%| FINDSTR /RC:"^.:$"> NUL
IF NOT ERRORLEVEL 1 SET "%~2="
 )
CALL :GET_PARENTF2 "%~1" %~3 %~4
GOTO :EOF
 
:GET_PARENTF2
(SET "%2=%~pnx1"
SET "%3=%~nx1")
GOTO :EOF
 
 
:RMESL
SET "TMPDNO=%~dpnx1|?"
SET "TMPDNO=%TMPDNO:\\|?=%"
SET "TMPDNO=%TMPDNO:\|?=%"
SET "TMPDNO=%TMPDNO:|?=%"
SET "%~2=%TMPDNO%"
GOTO :EOF
 
 
 
:CHEXCL
SET EXCLUDE_FLAG=1
BREAK> "%TEMP%\MYEXCLUDELIST.TXT"
BREAK> %TEMP%\TMP.TXT
FOR /F "usebackq tokens=1* delims=\" %%A in (`TYPE EXCLUDE_LIST.TXT`) DO (
IF NOT "%%~B"=="" (
ECHO %%~A\%%~B| FINDSTR /E /LC:"*."> NUL
IF NOT ERRORLEVEL 1 (
<NUL SET /P="%%~A\ ">> %TEMP%\TMP.TXT
 ) ELSE (
ECHO "%~1%%~A\%%~B">> "%TEMP%\MYEXCLUDELIST.TXT"
 )
 ) ELSE (
IF "%%~A"=="*." (<NUL SET /P="\ ">> %TEMP%\TMP.TXT) ELSE (
ECHO "%~1%%~A">> "%TEMP%\MYEXCLUDELIST.TXT" )
 )
 )
IF EXIST "%TEMP%\TMP.TXT" SET /P MANSEARCHFOLDERS=<"%TEMP%\TMP.TXT" & SET EXCLUDE_FLAG=2
GOTO :EOF
 
 
:ERRR
ECHO SOME KIND OF ERROR!
ECHO Poke your rake to the keyboard...
PAUSE>NUL
 
 
:END