Написать батник, который выводит числа от 1 до 256, не используя команду FOR

:: Отключить вывод команд
@echo off
:: Начальное значение
set X=256
 
:start
:: Вывести текущее значение
echo %X%
:: Если текущее значение равно 1, то СТОП
if %X%==1 exit
:: Уменьшить текущее значение
call :minus1 0
:: Повторить вывод и уменьшение нового значения
goto :start
 
:: ПОДПРОГРАММА уменьшения трёх значного числа
:minus1
:: pos - позиция изменившейся цифры (от конца)
set pos=%1
:: Если изменяется 3 цифра справа (сотни), то запоминаем цифру и 2 знака после неё
if %pos%==2 (
  set prefix=
  set postfix=%X:~-2,2%
  set cifra=%X:~-3,1%
  set pos1=
)
:: Если изменяется 2 цифра справа (десятки), то запоминаем один знак до цифры, цифру, и 1 знак после неё
if %pos%==1 (
  set prefix=%X:~,-2%
  set postfix=%X:~-1,1%
  set cifra=%X:~-2,1%
  set pos1=2
)
:: Если изменяется 1 цифра справа (еденицы), то запоминаем два знака до цифры и цифру
if %pos%==0 (
  set prefix=%X:~,-1%
  set postfix=
  set cifra=%X:~-1,1%
  set pos1=1
)
:: Определяем какая цифра будет на месте изменившейся
if %cifra%==1 set cifra_=0
if %cifra%==2 set cifra_=1
if %cifra%==3 set cifra_=2
if %cifra%==4 set cifra_=3
if %cifra%==5 set cifra_=4
if %cifra%==6 set cifra_=5
if %cifra%==7 set cifra_=6
if %cifra%==8 set cifra_=7
if %cifra%==9 set cifra_=8
if %cifra%==0 set cifra_=9
:: Поставить новую цифру на место изменившейся
set X=%prefix%%cifra_%%postfix%
:: Если цифра сменила на 9, то изменить и соседнюю цифру
if %cifra_%==9 call :minus1 %pos1%
:: Добавить пробел перед числом
set X= %X%
:: Убрать из числа нули, перед которыми есть нули
set X=%X: 0=%
:: Убрать из числа пробелы
set X=%X: =%
:: Выйти из подпрограммы
exit /b

set cifra=%X:~-2,1%

::Отключить вывод команд
@echo off
:: Создать файл с одной пустой строкой
echo. >0.tmp
:start1
:: Сохранить число строк во второй файл
find /c /v ""<0.tmp >1.tmp
:: Поместить число из файла в переменную Number
set /p Number="" <1.tmp
:: Дописать перед числом три пробела
set Number=   %Number%
:: Оставить три последних знака числа
set Number=%Number:~-3%
:: Добавить число в первый файл к другим числам
echo %Number% >>0.tmp
:: Подсчитать число строк, и передать в следующаю команду,
:: которая ищет в числе строк, число 257 (256 чисел и одна пустая строка),
:: если строка не найдена, то переходим обработке следующего числа
find /c /v ""<0.tmp|find "257">nul||goto start1
:: Вывести отсортированный в обратном порядке файл
sort /r 0.tmp
:: Удалить не нужные уже файлы
del 0.tmp
del 1.tmp

103
102
101
100
10
1

102
101
100
 99
 98
 97