Сортировка файлов по расширению

@isebolit · Регистрация: 16.10.2012

Студворк — интернет-сервис помощи студентам

Здравствуйте, уважаемые пользователи, появилась проблема с написанием bat файла. Задание состоит в следующем: произвести сортировку всех файлов текущего каталога в папки, содержащие расширения файлов. Т.е. если у меня в каталоге имеются файлы с расширением .doc .cpp .dll то после запуска батника в текущем каталоге появятся папки doc cpp и dll, содержащие файлы соответствующих расширений. Имя текущего каталога должно передаваться в качестве параметра. Собственно я дошел до следующего решения, но работает оно только если его вручную прописывать в командной строке:

Windows Batch file
1
2
set /P path=%CD%
for %i in (*.*) do (md %~xi move *%~xi %~xi)

При запуске сего кода из bat файла в любом случае приходится вводить текущий каталог, после чего прописываю цикл до команды *%~xi после чего, в командной строке возникает вопрос: Продолжить? Если дописать *%~xi %~xi, то все выйдет корректно. У кого будут какие мысли?

@isebolit · 17.10.2012, 13:33 **[ТС]**

Попробовал сделать с записью в текстовый файл всех расширений, но не могу представить как потом исходя из этого организовать нужную мне вещь, если кого интересует код, вот он:

Windows Batch file
1
2
3
4
5
set %a% = 0
for /f %%i in ('dir /b') do (for /f %%v (res.txt) do if (%%~xi == %%v) %a% = 1
                if not %a% == 1 echo %%~xi >> res.txt
                %a% = 0)
for /f %%v (res.txt) do xcopy %%v

Неужели ни у кого нет идей?

Dragokas · 17.10.2012, 15:16

path - плохое имя для пользовательской переменной (в системе уже есть одна - проверьте через свойства моего компьютера, "переменные среды", что Вы ее не повредили).

например, > ... пишем c:\c++

Bash
1
2
3
4
5
6
7
8
9
10
@echo off
setlocal enabledelayedexpansion
set /P folder="%CD%> "
for /f "delims=" %%a in ('dir %folder% /b /a:-d') do (
  set newF=%%~xa
  rem урезаем левый символ (точку) расширения
  set newF=%folder%\!newF:~1!
  if not exist "!newF!" md "!newF!"
  copy /y "%folder%\%%~a" "!newF!\"
)

@isebolit · 17.10.2012, 17:15 **[ТС]**

Хм... немного исправил Ваш код под свои нужды:

Windows Batch file
1
2
3
4
5
6
7
8
9
10
@echo off
setlocal enabledelayedexpansion
set /P folder="%CD%> "
for /f "delims=" %%a in ('dir %folder% /b /a:-d') do (
  set newF=%%~xa
  rem урезаем левый символ (точку) расширения
  set newF=%folder%\!newF:~1!
  if not exist "!newF!" md "!newF!"
  move /y "%folder%\%%~a" "!newF!\"
)

Теперь у меня файлы не просто копируются, а переносятся в нужные каталоги (прошу прощения за неверно сформулированную задачу), но встала следующая проблема. Батник переносит сам себя. Пробовал сделать маску, но ведь получится что сделаю я её для всех файлов с расширением .bat, а нужно чтоб он в каталоге оставлял сам себя. Может быть есть другой путь? Можете дать направление, в котором стоит копать

Dragokas · 17.10.2012, 20:32

Bash
1
2
3
4
5
6
7
8
9
10
11
@echo off
setlocal enabledelayedexpansion
set /P folder="%CD%> "
for /f "delims=" %%a in ('dir %folder% /b /a:-d') do (
  if "%%~a" neq "%~0" (
    set newF=%%~xa
    rem урезаем левый символ (точку) расширения
    set newF=%folder%\!newF:~1!
    if not exist "!newF!" md "!newF!"
    move /y "%folder%\%%~a" "!newF!\"
))

@isebolit · 23.10.2012, 08:52 **[ТС]**

Windows Batch file
1
2
3
4
5
6
7
8
9
10
@echo off
setlocal enabledelayedexpansion
set /P folder="%CD%> "
for /f "delims=" %%a in ('dir %folder% /b /a:-d') do (
  if "%%~na" neq "%0" (
    set newF=%%~xa
    set newF=%folder%\!newF:~1!
    if not exist "!newF!" md "!newF!"
    move /y "%folder%\%%~a" "!newF!\"
))

Так будет правильнее

Dragokas · 23.10.2012, 13:17

Неа, вот так:

Bash
5
if "%%~a" neq "%~nx0" (

Имя может попасть одинаковое с батником, а вот расширение добавить нужно обязательно.

@Alex-Grey · 14.12.2019, 15:17

Как быть при совпадении имен?
Чтобы при сортировке, если перемещаемый файл уже есть в папке, к нему добавлялся нарастающий префикс или дата (лучше число с последующим увеличением.)

Конечно в идеале сверять по HESH-сумме, чтобы не плодить дубликатов.

@alpap · 14.12.2019, 16:11

Alex-Grey, а поискать ну никак, да?

@Alex-Grey · 14.12.2019, 16:25

Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
13
@rem echo off
cd/d %~dp0
pause
setlocal enabledelayedexpansion
set /P folder="%CD%>> "
for /f "delims=" %%a in ('dir %folder% /s/b/a:-d') do (
    if "%%~a" neq "%~0" (
        set newF=%%~xa
        set newF=!newF:~1!
        if not exist "!newF!" md "!newF!"
        move "%%~a" "!newF!"
))
pause

Я читал ту ветку и не особо силен в написании BAT.
Как бы добавить к этому коду вариант с перезаписью при совпадении?
Move - не работает со скрытыми файлами и папками (xcopy /h)

Dragokas · 14.12.2019, 20:08

Разберитесь, что вам нужно

это

Сообщение от Alex-Grey

вариант с перезаписью при совпадении?

или это

Сообщение от Alex-Grey

к нему добавлялся нарастающий префикс или дата (лучше число с последующим увеличением.)

@Alex-Grey · 14.12.2019, 21:09

Попытаюсь объяснить задачу.
Есть папка, в которой есть файлы и папки с файлами.
Нужно сделать сортировку всех файлов и тех, что лежат в папках.
Чтобы при нахождении файла бралось его расширение и создавалась папка с названием расширения при ее отсутствии.
Файл перемещался в соответствующую ему папку. Код, который написан выше - делает это, но если попадается файл с одинаковым расширением и именем, он заменяется удаляя тот, что в папке.
Во время перемещения, если попадается идентичный файл с одинаковым название, чтобы к его названию добавлялся нарастающий префикс.

Добавлено через 8 минут

Сообщение от Dragokas

к нему добавлялся нарастающий префикс или дата (лучше число с последующим увеличением.)

Это

Dragokas · 14.12.2019, 21:41

Всего лишь взял функцию из закреплённой темы готовых решений: Каталог простых примеров решенных задач BAT/CMD, с чего начать (■■■ основная тема ■■■)
Перемещение файлов с заданным расширением со всего логического диска в создаваемый каталог

Windows Batch file
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
@echo off
setlocal enabledelayedexpansion
set "folder=."
set /P folder="%CD%> "
for /f "delims=" %%a in ('dir %folder% /b /a:-d') do (
  if "%%~a" neq "%~nx0" (
    set "newF=%%~xa"
    set "newF=%folder%\!newF:~1!"
    if not exist "!newF!" md "!newF!"
    Call :GetEmptyName "!newF!" "%%~nxa" NewName
    move /y "%%~a" "!newF!\!NewName!"
))
pause
goto :eof
 
:GetEmptyName %1-Folder %2-FileName %3-Var.Return %4-Optional.System.Num
if "%~4"=="" (
    Set "NewFileName=%~2"
  ) else (
    Set "NewFileName=%~n2(%~4)%~x2"
)
if exist "%~1\%NewFileName%" (
    Set Num=%~4
    Set /A Num+=1
    Call :GetEmptyName "%~1" "%~2" "%~3" "!Num!"
  ) else (
    Set "%~3=%NewFileName%"
    Exit /B
)
Exit /B

@Alex-Grey · 14.12.2019, 23:02

Работает! Но только в текущем каталоге. В самой папке есть еще папки с множеством вложений и в них файлы.
И если файл имеет атрибут "скрытый" или "системный", то move его не переместит.

Новые блоги и статьи Все статьи Все блоги /
Отправка уведомления на почту при изменении наименования справочника Maks 24.03.2026 Программная отправка письма электронной почты на примере изменения наименования типового справочника "Склады" в конфигурации БП3. Перед реализацией необходимо выполнить настройку системной учетной. . .	модель ЗдравоСохранения 5. Меньше увольнений- больше дохода! anaschu 24.03.2026 Теперь система здравосохранения уменьшает количество увольнений. 9TO2GP2bpX4 a42b81fb172ffc12ca589c7898261ccb/ https:/ / rutube. ru/ video/ a42b81fb172ffc12ca589c7898261ccb/ Слева синяя линия -. . .	Midnight Chicago Blues kumehtar 24.03.2026 Такой Midnight Chicago Blues, знаешь?. . Когда вечерние улицы становятся ночными, а ты не можешь уснуть. Ты идёшь в любимый старый бар, и бармен наливает тебе виски. Ты смотришь на пролетающие. . .	Контроль уникальности заводского номера - вариант №2 Maks 24.03.2026 В отличие от предыдущего варианта добавлено прерывание циклов, также добавлены новые переменные для сохранения контекста ошибки перед прерыванием цикла: Процедура ПередЗаписью(Отказ, РежимЗаписи,. . .
SDL3 для Desktop (MinGW): Вывод текста со шрифтом TTF с помощью библиотеки SDL3_ttf на Си и C++ 8Observer8 24.03.2026 Содержание блога Финальные проекты на Си и на C++: finish-text-sdl3-c. zip finish-text-sdl3-cpp. zip	Жизнь в неопределённости kumehtar 23.03.2026 Жизнь — это постоянное существование в неопределённости. Например, даже если у тебя есть список дел, невозможно дойти до точки, где всё окончательно завершено и больше ничего не осталось. В принципе,. . .	Модель здравоСохранения: работники работают быстрее после её введения. anaschu 23.03.2026 geJalZw1fLo Корпорация до введения программа здравоохранения имела много невыполненных работниками заданий, после введения программы количество заданий выросло. Но на выплатах по больничным это. . .	Контроль уникальности заводского номера - вариант №1 Maks 23.03.2026 Алгоритм контроля уникальности заводского (или серийного) номера на примере нетипового документа выдачи шин для спецтехники с табличной частью, разработанного в конфигурации КА2. Данные берутся из. . .

@Alex-Grey 0 / 0 / 0 Регистрация: 14.12.2019 Сообщений: 4
	14.12.2019, 15:17
	Как быть при совпадении имен? Чтобы при сортировке, если перемещаемый файл уже есть в папке, к нему добавлялся нарастающий префикс или дата (лучше число с последующим увеличением.) Конечно в идеале сверять по HESH-сумме, чтобы не плодить дубликатов. 0

@alpap 4340 / 2130 / 661 Регистрация: 26.04.2015 Сообщений: 6,823
	14.12.2019, 16:11
	Alex-Grey, а поискать ну никак, да? 0

@Alex-Grey 0 / 0 / 0 Регистрация: 14.12.2019 Сообщений: 4
	14.12.2019, 23:02
	Работает! Но только в текущем каталоге. В самой папке есть еще папки с множеством вложений и в них файлы. И если файл имеет атрибут "скрытый" или "системный", то move его не переместит. 0