Цветной вывод в консоли (обсуждение кода розы)

@echo off
<nul set /p x=;>file
findstr /v /a:cd "1" "fil*"
del file
<nul set /p x=;>file
findstr /v /a:f2 "1" "fil*"
del file
pause>nul

@echo off
:: Цветной вывод в консоли
:: Автора: Dragokas and FraidZZ
:: Часть кода (получение служебного символа BackSpace 0x08) заимствована у jeb (dostips.com)
 
:: Демонстрация работы с функцией окрашивания текста в консоли
 
:: Эти 6 строк оставляем как есть (это часть функции цвета - Инициализация)
  SetLocal
  md "%temp%\_ColorText" 2>nul 
  pushd "%temp%\_ColorText"
  if %errorlevel%==0 del /F /A /Q *.*
  set LastColorText=Default
  for /F "tokens=1,2 delims=#" %%a in ('"prompt #$H#$E# & echo on & for %%A in (1) do rem"') do set "DEL=%%a"& <nul set /p "x=%%a">Default
 
:: Настраиваю консоль по вкусу: по-шире - параметр cols. Высоту по-уже - параметр lines.
mode con cols=100 lines=40
Color 17
echo Выше по коду командой Color настраиваем цвет вывода консольных команд по-умолчанию.
echo Справка: Color /?
echo 17 - это белый шрифт на синем фоне.
echo.
 
:: Концевой пробел и спецсимволы запрещены
Call :ColorText 0B "Мой текст ярко-голубым цветом на черном фоне))"
Call :ColorText 0D " Печатаю в этой же строке розовым цветом"
Call :ColorText 0A ". Зеленым"
echo.
 
:: Однострочная многоцветная команда
Call :ColorText 0C "Каждый" 06 " охотник" 0E " желает" 0A " знать" 0B " где" 09 " сидит" 03 " фазан"
 
:: echo. - это переход на новую строку.
echo.&echo.
Call :ColorText 4B "Демонстрация завершена"
echo.&echo.
Call :ColorText 0E "Вывожу справку"
echo.&echo.
 
:: Это Вам не нужно и все, что ниже для работы функции тоже не нужно (кроме самой функции :ColorText, естественно :)
for /f "delims=] tokens=1*" %%a in ('color /?^| find /n /v ""^| findstr /R "\[[123456789]\]"') do echo.%%b
echo.
 
 
 
 
 
 
::Эти последние строки - служебные (не трогать!!!)
popd
::rd /s /q "%temp%\_ColorText" 2>nul
pause>nul
goto :eof
 
 
:ColorText
  :: Функция печати цветного текста
  :: %1-вх.параметр - Цвет в формате HEX
  :: %2-вх.параметр - Текст в цвете
  :: Концевой пробел, одиночная концевая точка, знаки \?:*"<>| не могут быть использованы в качестве текста
  ren "%LastColorText%" "%~2" 2>nul
  set "LastColorText=%~2"
  findstr /V /a:%~1 "Like color text? Just ask Dragokas and FraidZZ how it possible :)" "%~2*" 2>nul
  if "%~3"=="" Exit /B
shift& shift& goto ColorText

@Echo Off
SetLocal EnableDelayedExpansion
:: Inquisitor, 2013
:: Использованы следующие материалы:
:: Быстрое получение длины строки: CyberMuesli, [url]http://forum.oszone.net/showpost.php?p=2164186[/url]
:: Получение 0x08: jeb, [url]http://www.dostips.com/forum/viewtopic.php?p=6827#p6827[/url]
:: Идея передачи нескольких параметров: Diskretor, [url]http://forum.oszone.net/post-2201046-7.html[/url]
 
 
Echo.
Call :EchoColor 00 "        "
Call :EchoColor 0D "My Little Cmd" /n
Call :EchoColor 00 "       "
Call :EchoColor D0 "Coding is Magic" /n
Echo.
Echo          Simple demo:
Call :EchoColor 0A "  Text 0123 \>|</&^:;.,*-+=" /n
Call :EchoColor 08 "  -[" 6C " R " 2E " a " 1A " i " 5B " n " 79 " b " 3D " o " F4 " w " 08 "]-" /n
Pause&Exit
 
 
 
:EchoColor [%1=Color %2="Text" %3=/n (CRLF, optional)] (Support multiple arguments at once)
:: Вывод цветного текста. Ограничения - не выводится восклицательный знак, остальные спецсимволы разрешены.
:: Работа с более, чем одним набором параметров
If Not Defined multiple If Not "%~4"=="" (
    Call :EchoWrapper %*
    Set multiple=
    Exit /B
)
SetLocal EnableDelayedExpansion
If Not Defined BkSpace Call :EchoColorInit
:: Экранирование входящего текста от обратных и прямых слэшей, чистка некоторых символов.
Set "$Text=%~2"
Set "$Text=.%BkSpace%!$Text:\=.%BkSpace%\..\%BkSpace%%BkSpace%%BkSpace%!"
Set "$Text=!$Text:/=.%BkSpace%/..\%BkSpace%%BkSpace%%BkSpace%!"
Set "$Text=!$Text:"=\"!"
Set "$Text=!$Text:^^=^!"
:: Если XP, выводим обычный текст.
If "%isXP%"=="true" (
    <nul Set /P "=.!BkSpace!%~2"
    GoTo :unsupported
)
:: Подаем текст на stdout, не создавая временных файлов и используя трюк с путём.
:: В случае неудачи (проблемный\слишком длинный путь?) выводим текст as is, без расцветки.
:: Если результирующая длина строки (плюс уже имеющиеся там символы) превышает ширину консоли, то вывод тоже будет неудачным. Но получить текущую позицию каретки программно нельзя.
PushD "%~dp0"
2>nul FindStr /R /P /A:%~1 "^-" "%$Text%\..\%~nx0" nul
If !ErrorLevel! GTR 0 <nul Set /P "=.!BkSpace!%~2"
PopD
:: Убираем путь, имя файла и дефис с помощью рассчитаного ранее количества символов.
For /L %%A In (1,1,!BkSpaces!) Do <nul Set /P "=!BkSpace!"
:unsupported
:: Выводим CRLF, если указан третий аргумент.
If /I "%~3"=="/n" Echo.
EndLocal
GoTo :EOF
 
:EchoWrapper
:: Обработка аргументов поочерёдно
SetLocal EnableDelayedExpansion
:NextArg
Set multiple=true
:: Ох уж это удвоение "^" при передаче аргументов...
Set $Text=
Set $Text=%2
Set "$Text=!$Text:^^^^=^!"
If Not "%~3"=="" If /I Not "%~3"=="/n" (
    Shift&Shift
    Call :EchoColor %1 !$Text!
    GoTo :NextArg
) Else (
    Shift&Shift&Shift
    Call :EchoColor %1 !$Text! %3
    GoTo :NextArg
)
If "%~3"=="" Call :EchoColor %1 !$Text!
EndLocal
GoTo :EOF
 
 
:EchoColorInit
:: Отрабатывающая при первом запуске родительской функции инициализация нужных переменных
:: Важно! Под XP, в силу реализации тамошнего findstr, 0x08 в путях не работает, заменяясь на точку. Отключаем цветной вывод для XP.
For /F "tokens=2 delims=[]" %%A In ('Ver') Do (For /F "tokens=2,3 delims=. " %%B In ("%%A") Do (If "%%B"=="5" Set isXP=true))
:: Получаем комбинацию "0x08 0x20 0x08" с помощью prompt
For /F "tokens=1 delims=#" %%A In ('"Prompt #$H# & Echo On & For %%B In (1) Do rem"') Do Set "BkSpace=%%A"
:: Рассчитываем требуемое количество символов для подавления всего, кроме выводимого текста
Set ScriptFileName=%~nx0
Call :StrLen ScriptFileName
Set /A "BkSpaces=!strLen!+6"
GoTo :EOF
 
:StrLen [%1=VarName (not VALUE), ret !strLen!]
:: Получение длины строки
Set StrLen.S=A!%~1!
Set StrLen=0
For /L %%P In (12,-1,0) Do (
    Set /A "StrLen|=1<<%%P"
    For %%I In (!StrLen!) Do If "!StrLen.S:~%%I,1!"=="" Set /A "StrLen&=~1<<%%P"
)
GoTo :EOF
 
:: Эта строка должна быть последней и не оканчиваться на CRLF.
-

@ echo off
setlocal enabledelayedexpansion
 
call :write 0F "Random" 1
call :writeLn 0E " %random%"
 
echo.
 
set hex=0123456789ABCDEF
for /l %%j in (1, 1, 6) do (
  for /l %%i in (15, -1, 1) do (
    call :write !hex:~%%i,1!!hex:~%%i,1! "[---]"
  )
  echo.
)
 
echo.
 
call :writeLn 2C "   Hello, World   "
 
echo.
 
call :writeLn 0A "123456789012345678901234567890123456789012345678901234567890123456789012345678"
 
echo.
 
pause
color 0B
pause
 
exit /b 0
 
:write
:: Вывести цветную надпись без перевода строки
:: %1 - цвет
:: %2 - текст надписи
:: %3 - флаг, любое значение, если нужно двоеточие в конце строки
  setlocal
  pushd %TEMP%
  set tempFolder=~%time:~6,2%%time:~9,2%_%random%.tmp
  md "%tempFolder%"
  cd "%tempFolder%"
  set /p .=.<nul>"%~2"
  findstr /a:%~1 /c:"." /s "%~2"
  if "%~3"=="" (set /p .=  <nul) else set /p .= <nul
  cd ..
  rd /s /q "%tempFolder%"
  popd
endlocal & exit /b
 
:writeLn
:: Вывести цветную надпись с переводом строки
:: %1 - цвет
:: %2 - текст надписи
:: %3 - флаг, любое значение, если нужно двоеточие в конце строки
  call :write %1 "%~2" %3
  echo.
exit /b

@echo off
  setlocal enabledelayedexpansion
    for /F "tokens=1,2 delims=#" %%i in (^
      '"prompt #$H#$E# & echo on & for %%j in (1) do rem"'^
    ) do (
      set "n=%%i"
    )
    set /p .=.<nul>foo
    call:writeln 0d "colored string"
    del /f /q foo
  endlocal
pause
exit /b
 
:writeln
  set "regex=%~2" !
  set "regex=!regex:"=\"!"
  findstr /a:%1 /prc:"\." "!regex!\..\foo" nul
  set /p .=%n%%n%%n%%n%%n%%n%%n%%n%%n%<nul
exit /b