Составить командный файл, предлагающий выполнить действия по выбору

@echo off
setlocal enabledelayedexpansion
chcp 1251>nul
:d
cls
echo.Введите букву дискеты
set /p disk=
if not exist %disk%:\ (echo.Нет такого диска&goto d)
:s
cls
echo.Выберите действие
echo.1 - Форматировать дискету
echo.2 - Открыть текстовый файл
echo.3 - Удалить файл
echo.4 - Просмотреть каталог
echo.5 - Выход
set /p solut=
if "%solut%"=="5" (exit /b)
if "%solut%"=="" (goto :s)
set /a solut=%solut%+0
if %solut% GTR 4 (goto :s)
if %solut% LSS 1 (goto :s)
if %solut%==1 (format %disk%:)
if %solut%==2 (
 set /p file=Введите имя файла    ^>%disk%:\
 start "" "notepad" "%disk%:\!file!"
)
if %solut%==3 (
 set /p file=Введите имя удаляемого файла      ^>%disk%:\
 set /p yes=Действительно удалить %disk%:\!file! ? y/[n]
 if /I "!yes!"=="y" (erase "%disk%:\!file!")
)
if %solut%==4 (
 set /p dir=Введите имя каталога ^>%disk%:\
 if exist "%disk%:\!dir!\" (
  echo.-----Файлы:
  for %%A IN (%disk%:\!dir!\*) DO (echo.%%~nxA)
  echo.-----Папки:
  for /f "usebackq tokens=*" %%A IN (`dir "%disk%:\!dir!" /B /A:D`) DO (echo.%%A)
  pause>nul
 ) else (
  echo.Каталог не существует.
  pause>nul
 )
)
goto :s