Отображение реквизитов в документе по условию и контроль их заполнения

&НаСервере
Процедура ПриСозданииНаСервере(Отказ, СтандартнаяОбработка)   
    ПоломкаТехники = ПредопределенноеЗначение("Справочник.ТипыСообщений.ПоломкаТехники");
    // Условие на предмет выбранного значения для реквизита "ТипСообщения"
    Если Объект.ТипСообщения = ПоломкаТехники Тогда    
        // Установка видимости реквизитов
        Элементы.Спецтехника.Видимость = Истина; 
        Элементы.Сотрудник.Видимость = Истина;    
        Элементы.Спецтехника.АвтоОтметкаНезаполненного = Истина;
        Элементы.Сотрудник.АвтоОтметкаНезаполненного = Истина;  
        // Выбор спецтехники
        // Если в документе-источнике указана одна спецтехника, устанавливаем её автоматически
        Если Объект.ЗаявкаНаРаботу.ТаблицаСпецтехники.Количество() = 1 Тогда   
            Объект.Спецтехника = Объект.ЗаявкаНаРаботу.ТаблицаСпецтехники[0].Спецтехника;
        // если более одной, то предоставляем право выбора пользователю
        ИначеЕсли Объект.ЗаявкаНаРаботу.ТаблицаСпецтехники.Количество() > 1 Тогда  
            Элементы.Спецтехника.РежимВыбораИзСписка = Истина;
            Массив = Объект.ЗаявкаНаРаботу.ТаблицаСпецтехники.ВыгрузитьКолонку("Спецтехника");
            Элементы.Спецтехника.СписокВыбора.ЗагрузитьЗначения(Массив); 
        КонецЕсли;     
        // Выбор сотрудника 
        // Если в документе-источнике указан один сотрудник, устанавливаем его автоматически
        Если Объект.ЗаявкаНаРаботу.ТаблицаСотрудников.Количество() = 1 Тогда   
            Объект.Сотрудник = Объект.ЗаявкаНаРаботу.ТаблицаСотрудников[0].Сотрудник;
        // если более одного, то предоставляем право выбора пользователю
        ИначеЕсли Объект.ЗаявкаНаРаботу.ТаблицаСотрудников.Количество() > 1 Тогда  
            Элементы.Сотрудник.РежимВыбораИзСписка = Истина;
            Массив = Объект.ЗаявкаНаРаботу.ТаблицаСотрудников.ВыгрузитьКолонку("Сотрудник");
            Элементы.Сотрудник.СписокВыбора.ЗагрузитьЗначения(Массив); 
        КонецЕсли; 
        // Сообщение о пустом результате
        Если Объект.ЗаявкаНаРаботу.ТаблицаСпецтехники.Количество() = 0
            И Объект.ЗаявкаНаРаботу.ТаблицаСотрудников.Количество() = 0 Тогда 
            Отказ = Истина;
            Сообщить("В заявке №"+Объект.ЗаявкаНаРаботу.Номер+" отсутствуют сотрудники и спецтехника!");  
        ИначеЕсли Объект.ЗаявкаНаРаботу.ТаблицаСпецтехники.Количество() = 0 Тогда
            Отказ = Истина;
            Сообщить("В заявке №"+Объект.ЗаявкаНаРаботу.Номер+" отсутствует спецтехника!");
        ИначеЕсли Объект.ЗаявкаНаРаботу.ТаблицаСотрудников.Количество() = 0 Тогда
            Отказ = Истина;
            Сообщить("В заявке №"+Объект.ЗаявкаНаРаботу.Номер+" отсутствуют сотрудники!");
        КонецЕсли; 
    Иначе
        // Установка видимости реквизитов
        Элементы.Спецтехника.Видимость = Ложь; 
        Элементы.Сотрудник.Видимость = Ложь;  
        Элементы.Спецтехника.АвтоОтметкаНезаполненного = Ложь;
        Элементы.Сотрудник.АвтоОтметкаНезаполненного = Ложь;
    КонецЕсли;
КонецПроцедуры
 
&НаКлиенте
Процедура ПередЗаписью(Отказ, ПараметрыЗаписи)
    // Проверка заполнения реквизитов
    ПоломкаТехники = ПредопределенноеЗначение("Справочник.ТипыСообщений.ПоломкаТехники");
    Если Объект.ТипСообщения = ПоломкаТехники Тогда
        Если Не ЗначениеЗаполнено(Объект.Спецтехника) Тогда
            Сообщение = Новый СообщениеПользователю;
            Сообщение.Текст = "Необходимо выбрать спецтехнику!";
            Сообщение.Поле = "Объект.Спецтехника";
            Сообщение.Сообщить(); 
            Отказ = Истина;  
        ИначеЕсли Не ЗначениеЗаполнено(Объект.Сотрудник) Тогда
            Сообщение = Новый СообщениеПользователю;
            Сообщение.Текст = "Необходимо выбрать сотрудника!";
            Сообщение.Поле = "Объект.Сотрудник";
            Сообщение.Сообщить(); 
            Отказ = Истина;  
        ИначеЕсли ЗначениеЗаполнено(Объект.Спецтехника) И ЗначениеЗаполнено(Объект.Сотрудник) И Объект.ТекстСообщения = "" Тогда
            Сообщение = Новый СообщениеПользователю;
            Сообщение.Текст = "Укажите описание поломки!";
            Сообщение.Поле = "Объект.ТекстСообщения";
            Сообщение.Сообщить(); 
            Отказ = Истина;          
        КонецЕсли; 
    КонецЕсли;  
КонецПроцедуры
 
&НаСервере
Процедура ПослеЗаписиНаСервере(ТекущийОбъект, ПараметрыЗаписи)   
    // Выполняем проверку реквизита 'ТипСообщения' на наличие значения 'ПоломкаТехники' 
    ПоломкаТехники = ПредопределенноеЗначение("Справочник.ТипыСообщений.ПоломкаТехники");
    Если Объект.ТипСообщения = ПоломкаТехники Тогда        
        // Проверяем наличие/отсутствие действующей заявки на ремонт спецтехники
        Запрос = Новый Запрос;
        Запрос.Текст = 
            "ВЫБРАТЬ
            |   СтатусРемонта.Спецтехника КАК Спецтехника,
            |   СтатусРемонта.Статус КАК Статус
            |ИЗ
            |   РегистрСведений.СтатусыРемонтаСпецтехники.СрезПоследних(&ДатаСреза, ) КАК СтатусРемонта
            |ГДЕ
            |   СтатусРемонта.Спецтехника = &Спецтехника
            |   И СтатусРемонта.Статус В (&Новая, &ВРаботе)";      
        Запрос.УстановитьПараметр("ДатаСреза", ТекущаяДата());
        Запрос.УстановитьПараметр("Спецтехника", ТекущийОбъект.Спецтехника);     
        Запрос.УстановитьПараметр("Новая", Перечисления.СтатусРемонтаСпецтехники.Новая);
        Запрос.УстановитьПараметр("ВРаботе", Перечисления.СтатусРемонтаСпецтехники.ВРаботе);  
        РезультатЗапроса = Запрос.Выполнить();   
        Если РезультатЗапроса.Пустой() Тогда
            // Создаем заявку на ремонт спецтехники
            ЗаявкаНаРемонтСпецтехники = Документы.ЗаявкаНаРемонтСпецтехники.СоздатьДокумент();
            ЗаявкаНаРемонтСпецтехники.Заполнить(ТекущийОбъект.Ссылка); 
            ЗаявкаНаРемонтСпецтехники.Записать(РежимЗаписиДокумента.Проведение,РежимПроведенияДокумента.Оперативный);  
        Иначе
            // Сообщаем, если заявка уже есть (во избежание дублей)
            Сообщить("Заявка на ремонт для выбранной спецтехники уже создана!");
        КонецЕсли;
    КонецЕсли;
КонецПроцедуры