Вывод сообщения в отдельном окне с информацией

@echo off
SetLocal EnableExtensions
 
set m.title=Заголовок
 
set m.msg=^
Многострочное ^&^
сообщение
 
set m.icon=I
::W - предупреждение
::Q - вопрос
::E - ошибка
::I - информация
 
set m.btn=YESNOCANCEL
::OK
::OKCANCEL
::YESNO
::YESNOCANCEL
::RETRYCANCEL
::ABORTRETRYIGNORE
 
::Распаковка скрипта msgbox.vbs
for /f "delims=[]" %%N in ('find /n ":msgbox.vbs" ^<"%~f0"') do set /a num=%%N
more +%num% >"%~dp0msgbox.vbs" <"%~f0"
 
::Запуск скрипта с аргументами, получение Errorlevel через FOR
for /f "delims=" %%a in (
  'cscript //nologo "%~dp0msgbox.vbs" "%m.msg%" "%m.title%" "%m.icon%" "%m.btn%"'
) do set err=%%a
 
del "%~dp0msgbox.vbs"
echo ErrorLevel=%err%
<nul set /p "x=Anser is: "
if "%err%"=="-1" echo Error in Msgbox function arguments!
if "%err%"=="1" echo OK
if "%err%"=="2" echo CANCEL
if "%err%"=="3" echo ABORT
if "%err%"=="4" echo RETRY
if "%err%"=="5" echo IGNORE
if "%err%"=="6" echo YES
if "%err%"=="7" echo NO
 
pause
goto :eof
 
:: Внешний VB-скрипт msgbox.vbs
:msgbox.vbs
on error resume next
msg = Wscript.Arguments(0)
Title = Wscript.Arguments(1)
Icon = Wscript.Arguments(2)
btn = Wscript.Arguments(3)
 
Select Case Icon
Case "E"
    Icon = vbCritical
Case "Q"
    Icon = vbQuestion
Case "I"
    Icon = vbInformation
Case "W"
    Icon = vbExclamation
End Select
 
Select Case btn
Case "OK"
    btn = vbOK
Case "OKCANCEL"
    btn = vbOKCancel
Case "YESNO"
    btn = vbYesNo
Case "YESNOCANCEL"
    btn = vbYesNoCancel
Case "RETRYCANCEL"
    btin = vbRetryCancel
Case "ABORTRETRYIGNORE"
    btn = vbAbortRetryIgnore
End Select
 
msg = replace(msg, "&", vbCrLF)
 
ret = Msgbox(msg, btn + Icon, title)
if err <> 0 then Wscript.Echo -1 else Wscript.Echo ret

@echo off
SetLocal
cscript //nologo popup.vbs "Сообщение" "Заголовок" 3
:: 3 - это кол-во секунд для отображения сообщения
pause