Нарисуйте, пожалуйста, машину получше, чем получилось

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ExtCtrls, StdCtrls, MMSystem, Jpeg;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Timer1: TTimer;
    Image_Red: TImage;
    Image_Green: TImage;
    Timer_svet: TTimer;
    procedure FormCreate(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
    procedure FormPaint(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure Timer1Timer(Sender: TObject);
    procedure Timer_svetTimer(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
    Jpg : TJpegImage;
    Car, BkGnd : TBitmap;
    Engine : TResourceStream;
 
    procedure DrawCar;
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
const
  dx = 5;
  dy = 5;
 
var
  X, Y  : Integer; //координаты базовой точки грузовика
  Light : Integer;
 
procedure TForm1.FormCreate(Sender: TObject);
var
  RS : TResourceStream;
begin
  DoubleBuffered := True;
 
  Jpg   := TJpegImage.Create;
  BkGnd := TBitmap.Create;
  Car   := TBitmap.Create;
  Car.Width  := 200;
  Car.Height := 150;
  Car.PixelFormat := pf24Bit;
  Car.Transparent := True;
  Car.TransparentColor := clFuchsia;
 
  RS := TResourceStream.Create(hInstance, 'BkGnd', RT_RCDATA);
  try
    Jpg.LoadFromStream(RS);
  finally
    RS.Free;
  end;
 
  Form1.ClientWidth  := Jpg.Width;                                      // ширина формы
  Form1.ClientHeight := Jpg.Height;                                     // высота формы
  BkGnd.Width  := Jpg.Width;
  BkGnd.Height := Jpg.Height;
  BkGnd.Canvas.Draw(0, 0, Jpg);
 
  Engine := TResourceStream.Create(hInstance, 'Engine', 'WAVE');
 
  X := -35 * dx;                                                        // начальная координата х грузовика
  Y := 300;                                                             // начальная координата y грузовика
  DrawCar;
end;
 
procedure TForm1.FormDestroy(Sender: TObject);
begin
  Engine.Free;
  Jpg.Free;
  Car.Free;
  BkGnd.Free;
end;
 
procedure TForm1.FormPaint(Sender: TObject);
begin
  Canvas.Draw(0, 0, BkGnd);
end;
 
// процедура вычерчивает грузовик
procedure TForm1.DrawCar;
var
  p : array[1..6] of TPoint;                                            // координаты точек кабины
begin
  with Car.Canvas do
  begin
    Brush.Color := clFuchsia;
    FillRect(Rect(0, 0, Car.Width, Car.Height));
 
    Pen.Width := 2;
    Pen.Color := clBlack;
    // кузов грузовика
    Brush.Color := clTeal;
    Rectangle(0, 100 - 10 * dy, 20 * dx, 100);
    // кабина грузовика
    p[1].X := 22 * dx; p[1].Y := 100;
    p[2].X := 22 * dx; p[2].Y := 100 - 20 * dy;
    p[3].X := 27 * dx; p[3].Y := 100 - 20 * dy;
    p[4].X := 32 * dx; p[4].Y := 100 - 12 * dy;
    p[5].X := 35 * dx; p[5].Y := 100 - 12 * dy;
    p[6].X := 35 * dx; p[6].Y := 100;
    Polygon(p);
    // окно кабины
    MoveTo(27 * dx, 100 - 20 * dy);
    LineTo(27 * dx, 100 - 12 * dy);
    LineTo(32 * dx, 100 - 12 * dy);
    Brush.Color := clWhite;
    FloodFill(28 * dx, 100 - 13 * dy, clBlack, fsBorder);
    // колеса грузовика
    Brush.Color := clGray;
    Ellipse(3  * dx, 100, 12 * dx, 100 + 9 * dy);
    Ellipse(23 * dx, 100, 32 * dx, 100 + 9 * dy);
    // рама грузовика
    Brush.Color := $002B7399;
    Rectangle(0, 100, 35 * dx, 100 + dy);
  end;
end;
 
// Загрузка формы
// Процедура нажатия на кнопку
procedure TForm1.Button1Click(Sender: TObject);
const
  btnCaption : array[Boolean] of String = ('Пуск', 'Стоп');
begin
  Timer1.Enabled      := not Timer1.Enabled;
  Timer_svet.Enabled  := not Timer_svet.Enabled;
  Button1.Caption     := btnCaption[Timer1.Enabled];
  Image_Green.Visible := Timer1.Enabled;
  Image_Red.Visible   := not Timer1.Enabled;
  if Timer1.Enabled then
    PlaySound(Engine.Memory, 0, SND_MEMORY or SND_ASYNC or SND_LOOP or SND_NOWAIT)
  else
    PlaySound(NIL, 0, SND_MEMORY or SND_ASYNC or SND_LOOP or SND_NOWAIT);
end;
 
// Таймер автомобиля
procedure TForm1.Timer1Timer(Sender: TObject);
begin
  BkGnd.Canvas.Draw(0, 0, Jpg);
  BkGnd.Canvas.Draw(X, Y, Car);
  Refresh;
 
  // определить новую точку появления грузовика
  if X > ClientWidth then
    X := -35 * dx                                                         // начальная координата х грузовика
  else if Image_Red.Visible and ((X > 290) and (X < 300)) then
    Exit
  else
    inc(X, 2);
end;
 
procedure TForm1.Timer_svetTimer(Sender: TObject);
begin
  inc(Light);
  if Light > 5 then
    Light := 0;
 
  Image_Green.Visible := Light in [0..2];
  Image_Red.Visible   := Light in [3..5];
end;
 
end.