Найти кратчайший путь

(def edges [["Владивосток" "Артем" 30]
            ["Владивосток" "Де-Фриз" 10]
            ["Артем" "Де-Фриз" 15]
            ["Артем" "Штыково" 50]
            ["Штыково" "Де-Фриз" 40]
            ["Штыково" "Шкотово" 20]])
 
(defn path-from-to
  "Dijkstra minimal path algorithm"
  [grid from to]
  (let [visits (loop [vertex from
                      visits {vertex {:cost 0}}]
                 (if (= vertex to) visits
                     (let [vertex-time (get-in visits [vertex :cost])
                           neighbors (->> vertex grid keys (remove #(get-in visits [% :processed?])))
                           visits* (reduce (fn [acc neighbor]
                                             (let [neighbor-time (+ vertex-time (get-in grid [vertex neighbor]))]
                                               (update acc neighbor (fn [{:keys [cost] :as val}]
                                                                      (if (and cost (< cost neighbor-time))
                                                                        val
                                                                        (assoc val :cost neighbor-time :prev vertex))))))
                                           (assoc-in visits [vertex :processed?] true)
                                           neighbors)
                           vertex* (->> visits*
                                        (remove (comp :processed? second))
                                        (safe-min-key (comp :cost second))
                                        first)]
                       (if vertex* (recur vertex* visits*) visits*))))]
    {:path-time (get-in visits [to :cost])
     :path (loop [vertex to
                  path (list vertex)]
             (if-let [prev (get-in visits [vertex :prev])]
               (recur prev (cons prev path))
               (-> path vec)))}))
 
(path-from-to (reduce (fn [acc [f t d]] (-> acc
                                            (assoc-in [f t] d)
                                            (assoc-in [t f] d))) {} edges)
              "Владивосток" "Шкотово")