Создание объемных изображений на С++

program letter;
uses crt, graph;
 
type
  TMatrix=array[0..3,0..3]of real;
  TVector=array[0..3]of real;
 
const
  maxVertexs=26;
  Vertexs:array[0..maxVertexs-1]of TVector=
(
(-20.000,0.000, -15.000,1),           {Koordinaty tochek}
(-80.000,90.000,  -15.000,1),
(-20.000,100.000,  -15.000,1),
( 0,35,  -15.000,1),
( 20,100,  -15.000,1),
(80,90,  -15.000,1),
(20,0,  -15.000,1),
(80,-90,  -15.000,1),
(20,-100, -15.000,1),
(0,-35, -15.000,1),
(-20,-100, -15.000,1),
( -80,-90, -15.000,1),
( -20,0, -15.000,1)
 
 
 
,(-20.000,0.000, 15.000,1),            {koordinaty s dobavleniem z(ob'em)}
(-80.000,90.000,  15.000,1),
(-20.000,100.000,  15.000,1),
( 0,35,  15.000,1),
( 20,100,  15.000,1),
(80,90,  15.000,1),
(20,0,  15.000,1),
(80,-90,  15.000,1),
(20,-100, 15.000,1),
(0,-35, 15.000,1),
(-20,-100, 15.000,1),
( -80,-90, 15.000,1),
( -20,0, 15.000,1)
 
 
);
  maxEdges=36;
Edges:array[0..maxEdges-1,0..1]of integer=
(
(0,1),              {soedinenie tochek}
(1,2),
(2,3),
(3,4),
(4,5),
(5,6),
(6,7),
(7,8),
(8,9),
(9,10),
(10,11),
(11,12),
 
(13,14),                   {soedenie s z (pri dvijenii)}
(14,15),
(15,16),
(16,17),
(17,18),
(18,19),
(19,20),
(20,21),
(21,22),
(22,23),
(23,24),
(24,13),
 
          {soed pereda figury s zadom }
 
(0,13),
(1,14),
(2,15),
(3,16),
(4,17),
(5,18),
(6,19),
(7,20),
(8,21),
(9,22),
(10,23),
(11,24)
);
 
 
const
  prMatrix:TMatrix=
(
(1,0,0,0),
(0,1,0,0),
(0,0,1,0),
(0,0,0,1)
);
 
var
   xc,yc,zc:real;
 
procedure VMMult(V:TVector;M:TMatrix;var Vr:TVector);
var
  i,j:integer;
begin
  for j:=0 to 3 do
    begin
      Vr[j]:=0;
      for i:=0 to 3 do
          Vr[j]:=Vr[j]+V[i]*M[i,j];
    end;
  if Vr[3]=0 then
     Vr[3]:=Vr[3];
  Vr[0]:=Vr[0]/Vr[3];
  Vr[1]:=Vr[1]/Vr[3];
  Vr[2]:=Vr[2]/Vr[3];
  Vr[3]:=1;
 
end;
 
procedure MMMult(A,B:TMatrix;var Mr:TMatrix);
var
  i,j,k:integer;
begin
  for i:=0 to 3 do
      for j:=0 to 3 do
        begin
          Mr[i,j]:=0;
          for k:=0 to 3 do
            Mr[i,j]:=Mr[i,j]+A[i,k]*B[k,j];
        end
end;
 
procedure MoveShape(dx,dy,dz:real);
var
  T:TMatrix;
  v:integer;
 
begin
  xc:=xc+dx;
  yc:=yc+dy;                            {matrica dvijeniya}
  zc:=zc+dz;
  T[0,0]:=1 ; T[0,1]:=0 ; T[0,2]:=0 ; T[0,3]:=0;
  T[1,0]:=0 ; T[1,1]:=1 ; T[1,2]:=0 ; T[1,3]:=0;
  T[2,0]:=0 ; T[2,1]:=0 ; T[2,2]:=1 ; T[2,3]:=0;
  T[3,0]:=dx; T[3,1]:=dy; T[3,2]:=dz; T[3,3]:=1;
 
  for v:=0 to maxVertexs-1 do
      VMMult(Vertexs[v],T,Vertexs[v]);
end;
 
procedure RotateShape(ax,ay,az:real);
var
  Rx,Ry,Rz,R:TMatrix;
  v:integer;
  cosa,sina,x,y,z:real;
begin                                   {Matrica vrasheniya}
  cosa:=cos(ax);
  sina:=sin(ax);
  Rx[0,0]:=1    ; Rx[0,1]:=0    ; Rx[0,2]:=0    ; Rx[0,3]:=0;
  Rx[1,0]:=0    ; Rx[1,1]:=cosa ; Rx[1,2]:=sina ; Rx[1,3]:=0;
  Rx[2,0]:=0    ; Rx[2,1]:=-sina; Rx[2,2]:=cosa ; Rx[2,3]:=0;
  Rx[3,0]:=0    ; Rx[3,1]:=0    ; Rx[3,2]:=0    ; Rx[3,3]:=1;
 
  cosa:=cos(ay);
  sina:=sin(ay);
  Ry[0,0]:=cosa ; Ry[0,1]:=0    ; Ry[0,2]:=-sina; Ry[0,3]:=0;
  Ry[1,0]:=0    ; Ry[1,1]:=1    ; Ry[1,2]:=0    ; Ry[1,3]:=0;
  Ry[2,0]:=sina ; Ry[2,1]:=0    ; Ry[2,2]:=cosa ; Ry[2,3]:=0;
  Ry[3,0]:=0    ; Ry[3,1]:=0    ; Ry[3,2]:=0    ; Ry[3,3]:=1;
 
  cosa:=cos(az);
  sina:=sin(az);
  Rz[0,0]:=cosa ; Rz[0,1]:=sina ; Rz[0,2]:=0    ; Rz[0,3]:=0;
  Rz[1,0]:=-sina; Rz[1,1]:=cosa ; Rz[1,2]:=0    ; Rz[1,3]:=0;
  Rz[2,0]:=0    ; Rz[2,1]:=0    ; Rz[2,2]:=1    ; Rz[2,3]:=0;
  Rz[3,0]:=0    ; Rz[3,1]:=0    ; Rz[3,2]:=0    ; Rz[3,3]:=1;
 
  MMMult(Rx,Ry,R);
  MMMult(R,Rz,R);
  x:=xc;y:=yc;z:=zc;
  MoveShape(-xc+50,-yc-50,-zc);       {izmenenie cntra vrascheniya}
  for v:=0 to maxVertexs-1 do
      VMMult(Vertexs[v],R,Vertexs[v]);
  MoveShape(x-50,y+50,z);
end;
 
function GetCoord(p:TVector;num:integer):integer;
begin
  if num=0 then GetCoord:=round(p[0]+320);
  if num=1 then GetCoord:=round(240-p[1]);
end;
 
procedure DrawWire;
var
  e:integer;
  p:TVector;
begin
  for e:=0 to maxEdges-1 do
    begin
      VMMult(Vertexs[Edges[e,0]],prMatrix,p);
      MoveTo(GetCoord(p,0),GetCoord(p,1));
 
      VMMult(Vertexs[Edges[e,1]],prMatrix,p);
      LineTo(GetCoord(p,0),GetCoord(p,1));
    end;
end;
 
Var
  gD,gM:Integer;
  ch:char;
  modeKey:integer;
 
 
begin
  gD:=Detect;
  InitGraph(gD, gM, '');
 
  If GraphResult <> grOk Then exit;
  modekey:=0;
  repeat
    cleardevice;
    if modekey=0 then outtextxy(0,0,'Dvijenie');
    if modekey=1 then outtextxy(0,0,'Vraschenie');
    DrawWire;
 
    ch:=readkey;
    if modekey=0 then
        case ch of
          's':MoveShape(0,-10,0);
          'w':MoveShape(0,10,0);
          'a':MoveShape(-10,0,0);
          'd':MoveShape(10,0,0);
          'q':MoveShape(0,0,-10);
          'e':MoveShape(0,0,10);
          'z':modekey:=1;
        end;
 
    if modekey=1 then
        case ch of
          'w':RotateShape(-pi/16,0,0);
          's':RotateShape(pi/16,0,0);
          'a':RotateShape(0,-pi/16,0);
          'd':RotateShape(0,pi/16,0);
          'q':RotateShape(0,0,-pi/16);
          'e':RotateShape(0,0,pi/16);
          'x':modekey:=0;
        end;
 
  until ch=#27;
  closegraph;
end.