Проблема жизни и смерти с StringGrid

unit Wrapgrid;
 
interface
 
uses
 
  SysUtils, WinTypes, WinProcs, Messages, Classes, Graphics, Controls,
  Forms, Dialogs, Grids;
 
type
 
  TWrapGrid = class(TStringGrid)
  private
    { Private declarations }
  protected
    { Protected declarations }
    { Процедура DrawCell осуществляет перенос текста в ячейке }
    procedure DrawCell(ACol, ARow: Longint; ARect: TRect;
      AState: TGridDrawState); override;
  public
    { Public declarations }
    { Процедура Create перекрывается для того, чтобы использовать процедуру DrawCell
    по умолчанию }
    constructor Create(AOwner: TComponent); override;
  published
    { Published declarations }
  end;
 
procedure Register;
 
implementation
 
constructor TWrapGrid.Create(AOwner: TComponent);
begin
 
  { Создаем TStringGrid }
  inherited Create(AOwner);
 
  { Заставляем компонент перерисовываться нашей процедурой по умолчанию DrawCell }
  DefaultDrawing := FALSE;
end;
 
{ Процедура DrawCell осуществляет перенос текста в ячейке }
 
procedure TWrapGrid.DrawCell(ACol, ARow: Longint; ARect: TRect;
 
  AState: TGridDrawState);
var
 
  Sentence, { Выводимый текст }
  CurWord: string; { Текущее выводимое слово }
  SpacePos, { Позиция первого пробела }
  CurX, { Х-координата 'курсора' }
  CurY: Integer; { Y-координата 'курсора' }
  EndOfSentence: Boolean; { Величина, указывающая на заполненность ячейки }
begin
 
  { Инициализируем шрифт, чтобы он был управляющим шрифтом }
  Canvas.Font := Font;
 
  with Canvas do
  begin
    { Если это фиксированная ячейка, тогда используем фиксированный цвет }
    if gdFixed in AState then
    begin
      Pen.Color := FixedColor;
      Brush.Color := FixedColor;
    end
      { в противном случае используем нормальный цвет }
    else
    begin
      Pen.Color := Color;
      Brush.Color := Color;
    end;
 
    { Рисуем подложку цветом ячейки }
    Rectangle(ARect.Left, ARect.Top, ARect.Right, ARect.Bottom);
  end;
 
  { Начинаем рисование с верхнего левого угла ячейки }
  CurX := ARect.Left;
  CurY := ARect.Top;
 
  { Здесь мы получаем содержание ячейки }
  Sentence := Cells[ACol, ARow];
 
  { для каждого слова ячейки }
  EndOfSentence := FALSE;
  while (not EndOfSentence) do
  begin
    { для получения следующего слова ищем пробел }
    SpacePos := Pos(' ', Sentence);
    if SpacePos > 0 then
    begin
      { получаем текущее слово плюс пробел }
      CurWord := Copy(Sentence, 0, SpacePos);
 
      { получаем остальную часть предложения }
      Sentence := Copy(Sentence, SpacePos + 1, Length(Sentence) - SpacePos);
    end
    else
    begin
      { это - последнее слово в предложении }
      EndOfSentence := TRUE;
      CurWord := Sentence;
    end;
 
    with Canvas do
    begin
      { если текст выходит за границы ячейки }
      if (TextWidth(CurWord) + CurX) > ARect.Right then
      begin
        { переносим на следующую строку }
        CurY := CurY + TextHeight(CurWord);
        CurX := ARect.Left;
      end;
 
      { выводим слово }
      TextOut(CurX, CurY, CurWord);
      { увеличиваем X-координату курсора }
      CurX := CurX + TextWidth(CurWord);
    end;
  end;
end;
 
procedure Register;
begin
 
  { Вы можете изменить закладку Samples на любую другую
  палитре компонентов Delphi }
  RegisterComponents('Samples', [TWrapGrid]);
end;
 
end.

Procedure TForm1.stringGrid1DrawCell(SEnder: TObject; ACol, ARow: Integer;
Rect: TRect; State: TGridDrawState);
var
i, x, y: Integer;
Begin
If gdFixed in State Then Exit;
If ARow > 1 Then Exit;
{Draw row 1 with text from cell 1,1 spanning all cells in the row}
with sEnder as TstringGrid do Begin
{ExtEnd rect to include grid line on right, If not last cell in row}
If aCol Then
Rect.Right := Rect.Right + GridlineWidth;
{Figure out where the text of the first cell would start relative to the
current cells rect}
y := Rect.Top + 2;
x := Rect.Left + 2;
For i:= 1 to aCol - 1 do
x := x - ColWidths[i] - GridlineWidth;
{Paint cell pale yellow}
Canvas.Brush.Color := $7FFFFF;
Canvas.Brush.Style := bsSolid;
Canvas.FillRect( Rect );
{Paint text of cell 1,1 clipped to current cell}
Canvas.TextRect( Rect, x, y, Cells[1, 1] );
End;
End;
Procedure TForm1.FormCreate(SEnder: TObject);
var
i, k: Integer;
Begin
with stringGrid1 do Begin
cells[1, 1] := 'A rather long line which will span cells';
For i:= 1 to colcount-1 do
For k:= 2 to rowcount -1 do
cells[i,k] := Format( 'Cell[%d, %d]', [i, k]);
End;
End;