Проверка правильности ввода Email адреса

//------------------------------------------------------------------------------
// Verifies is the given string valid email address or not. Domain names without
// dots (user@localhost) are acceptable if AllowRootDomain is True.
 
function IsValidEmail(const Value: string; AllowRootDomain: Boolean = False): Boolean;
 
//-------------------------------------
 
  function _Verify(const S: string): Boolean;
  var
    i: Integer;
  begin
    Result := False;
    for i := 1 to Length(S) do
      if not (S[i] in ['a'..'z' ,'A'..'Z', '0'..'9', '_', '-', '.']) then Exit;
    Result := True;
  end;{Internal _Verify}
 
//-------------------------------------
 
var
  i: Integer;
  User, Domain: string;
begin
  Result:= False;
// @ is must, but not first
  i := Pos('@', Value);
  if i < 2 then Exit;
 
  User := Copy(Value, 1, i - 1);
  if User = '' then Exit;
 
  Domain := Copy(Value, i + 1, MaxInt);
  if Domain = '' then Exit;
 
  if not AllowRootDomain then
  begin
  // Dot is must, but not first
    i := Pos('.', Domain);
    if i < 2 then Exit;
  end;
 
// Dot should not be first and the last
  if (Domain[1] = '.') or (Domain[Length(Domain)] = '.') then Exit;
 
// Verify each char of User and Domain
  Result:= _Verify(User) and _Verify(Domain);
end;