Создание блок-схемы

#define ENCODER_A 2    
#define ENCODER_B 3    
#define ENCODER_SW 18  
 
#define LED_RED 4    
#define LED_GREEN 5  
#define DBOUNCE 180  
 
#include <SPI.h>
#include <Wire.h>
#include <Adafruit_GFX.h>
#include <Adafruit_SSD1306.h>
 
// Параметры дисплея
#define SCREEN_WIDTH 128
#define SCREEN_HEIGHT 64
#define OLED_RESET -1
 
Adafruit_SSD1306 display(SCREEN_WIDTH, SCREEN_HEIGHT, &Wire, OLED_RESET);
 
volatile unsigned long lastUpdateTime = 0;
volatile int encoderCount = 0;
volatile bool encoderStateA, lastEncoderStateA, encoderTurnFlag;
volatile int lastEncoderCount = 0;
volatile float timerValue = 0;
 
int menuPosition = 0;
bool isInMenu = true;
bool encoderButtonClicked = false;
bool isTimerRunning = false;
int menuShift = 0;
 
char availableSymbols[39] = {
  'A', 'B', 'C', 'D', 'E', 'F', 'G', 'H', 'I', 'J', 'K', 'L', 'M',
  'N', 'O', 'P', 'Q', 'R', 'S', 'T', 'U', 'V', 'W', 'X', 'Y', 'Z',
  ' ', '-', '/', '0', '1', '2', '3', '4', '5', '6', '7', '8', '9'
};
char inputString[128] = "";
int currentSymbolIndex = 0;
 
void setup() {
  display.begin(SSD1306_SWITCHCAPVCC, 0x3C);
  display.clearDisplay();
  pinMode(LED_RED, OUTPUT);
  pinMode(LED_GREEN, OUTPUT);
  pinMode(ENCODER_A, INPUT_PULLUP);
  pinMode(ENCODER_B, INPUT_PULLUP);
  pinMode(ENCODER_SW, INPUT_PULLUP);
  Serial.begin(9600);
  attachInterrupt(digitalPinToInterrupt(ENCODER_A), encoderISR, CHANGE);
  display.setTextSize(1);
  display.setTextColor(WHITE);
}
 
void loop() {
  processEncoderButton();
  if (isInMenu) {
    updateMenuPosition();
    drawMenu();
  } else {
    executeMenuFunction();
  }
}
 
void updateMenuPosition() {
  int newPosition = menuPosition + menuShift;
  if (newPosition >= 0 && newPosition <= 2) {
    menuPosition = newPosition;
  }
  menuShift = 0;
  if (encoderButtonClicked) {
    isInMenu = false;
    encoderButtonClicked = false;
    encoderCount = 0;
  }
}
 
void executeMenuFunction() {
  switch (menuPosition) {
    case 0:
      updateSpeedScreen();
      break;
    case 1:
      updateTimerScreen();
      break;
    case 2:
      updateInputScreen();
      break;
  }
}
 
void updateSpeedScreen() {
  unsigned long currentMillis = millis();
  if (currentMillis - lastUpdateTime >= 1000) {
    float rotationSpeed = abs(encoderCount - lastEncoderCount) * 0.05;
    lastEncoderCount = encoderCount;
    lastUpdateTime = currentMillis;
    drawSpeedScreen(rotationSpeed);
  }
}
 
void updateTimerScreen() {
  if (encoderButtonClicked) {
    isTimerRunning = !isTimerRunning;
    encoderButtonClicked = false;
  }
  if (!isTimerRunning) {
    digitalWrite(LED_RED, HIGH);
    digitalWrite(LED_GREEN, LOW);
    if (timerValue + (encoderCount - lastEncoderCount) >= 0) {
      timerValue += encoderCount - lastEncoderCount;
    }
    lastEncoderCount = encoderCount;
  } else {
    digitalWrite(LED_RED, LOW);
    digitalWrite(LED_GREEN, HIGH);
    unsigned long currentMillis = millis();
    if (currentMillis - lastUpdateTime >= 1000) {
      lastUpdateTime = currentMillis;
      timerValue -= 1;
      if (timerValue <= 0) {
        isTimerRunning = false;
      }
    }
  }
  drawTimerScreen(timerValue);
}
 
void updateInputScreen() {
  if (encoderButtonClicked) {
    currentSymbolIndex++;
    encoderButtonClicked = false;
    encoderCount = 0;
  }
  if (encoderCount >= 39 || encoderCount < 0) {
    encoderCount = 0;
  }
  inputString[currentSymbolIndex] = availableSymbols[encoderCount];
  drawInputScreen(inputString);
}
 
void drawMenu() {
  display.clearDisplay();
  display.setCursor(15, 0);
  display.print("Radial Speed");
  display.setCursor(15, 15);
  display.print("Timer");
  display.setCursor(15, 30);
  display.print("Enter Text");
  display.setCursor(0, 15 * menuPosition);
  display.print("->");
  display.display();
}
 
void drawSpeedScreen(float speed) {
  display.clearDisplay();
  display.setCursor(10, 0);
  display.println("Radial Speed:");
  display.setCursor(10, 15);
  display.print(speed);
  display.print(" RPM");
  display.display();
}
 
void drawTimerScreen(float time) {
  display.clearDisplay();
  display.setCursor(10, 0);
  display.println("Time:");
  display.setCursor(10, 15);
  display.print(time);
  display.print(" Sec.");
  display.display();
}
 
void drawInputScreen(const char* str) {
  display.clearDisplay();
  display.setCursor(10, 0);
  display.println(str);
  display.display();
}
 
void encoderISR() {
  encoderStateA = digitalRead(ENCODER_A);
  if (encoderStateA != lastEncoderStateA) {
    encoderTurnFlag = !encoderTurnFlag;
    if (encoderTurnFlag) {
      menuShift = (digitalRead(ENCODER_B) != encoderStateA) ? -1 : 1;
      encoderCount += menuShift;
    }
    lastEncoderStateA = encoderStateA;
  }
}
 
void processEncoderButton() {
  static unsigned long lastButtonPressTime = 0;
  static bool isButtonPressed = false;
  static unsigned long buttonPressDuration = 0;
 
  int buttonState = !digitalRead(ENCODER_SW);
  unsigned long currentMillis = millis();
 
  if (buttonState && !isButtonPressed && (currentMillis - lastButtonPressTime > DBOUNCE)) {
    isButtonPressed = true;
    buttonPressDuration = currentMillis;
  }
 
  if (!buttonState && isButtonPressed) {
    isButtonPressed = false;
    if ((currentMillis - buttonPressDuration) < 1500) {
      encoderButtonClicked = true;
    } else {
      isInMenu = true;
    }
    lastButtonPressTime = currentMillis;
  }
}