Сделать кнопку недоступной, если все поля в stringgrid не заполнены

type
  TForm1 = class(TForm)
    // ...
  private
    function CheckGrid(grid: TStringGrid): Boolean; // <--- Заголовок
  public
  end;
 
// Реализация
function TForm1.CheckGrid(grid: TStringGrid): Boolean;
var
  i, j: Integer;
begin
  Result := False;
  with grid do
    for i := FixedRows to RowCount - 1 do
      for j := FixedCols to ColCount - 1 do
        if Trim(Cells[j, i]) = '' then Exit;
  Result := True;
end;

procedure TForm1.StringGrid1SetEditText(Sender: TObject; ACol, ARow: Integer;
  const Value: string);
begin
  Button1.Enabled := CheckGrid(StringGrid1);
end;

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, Grids, StdCtrls;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    StringGrid1: TStringGrid;
    procedure FormCreate(Sender: TObject);
    procedure StringGrid1GetEditText(Sender: TObject; ACol, ARow: Integer;
      var Value: String);
    procedure StringGrid1SetEditText(Sender: TObject; ACol, ARow: Integer;
      const Value: String);
  private
    { Private declarations }
  public
    { Public declarations }
    FCntEmpty : Integer; //Количество пустых ячеек.
    FIsEmpty : Boolean;  //Была ли ячейка пустой перед началом ввода.
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
//После создания формы.
procedure TForm1.FormCreate(Sender: TObject);
var
  Sg : TStringGrid;
begin
  Sg := StringGrid1;
  FCntEmpty := (Sg.RowCount - Sg.FixedRows) * (Sg.ColCount - Sg.FixedCols);
  Button1.Enabled := False; //Button1.Enabled := FCntEmpty = 0;
end;
 
//Перед началом редактирования данных ячейки.
procedure TForm1.StringGrid1GetEditText(Sender: TObject; ACol,
  ARow: Integer; var Value: String);
begin
  FIsEmpty := Value = '';
end;
 
//При редактировании данных ячейки.
procedure TForm1.StringGrid1SetEditText(Sender: TObject; ACol,
  ARow: Integer; const Value: String);
begin
  {Если ячейка была пустой, а теперь стала непустой, значит количество
  пустых ячеек стало на 1 меньше.}
  if FIsEmpty and (Value <> '') then
    Dec(FCntEmpty)
  {Если ячейка была непустой, а теперь стала пустой, значит количество
  пустых ячеек стало на 1 больше.}
  else if not FIsEmpty and (Value = '') then
    Inc(FCntEmpty);
 
  FIsEmpty := Value = '';
  Button1.Enabled := FCntEmpty = 0;
end;
 
end.