Напечатать в алфавитном порядке все гласные буквы, которые входят в каждое слово

program Project1;
 
{$APPTYPE CONSOLE}
 
uses
  SysUtils, Windows;
 
const
  //Множество разделителей слов.
  D = [' ', '.', ',', ':', ';', '!', '?', '-', #9, #10, #13];
  //Множество гласных букв.
  Da = [
    //Русские гласные буквы.
    'А', 'Е', 'Ё', 'И', 'О', 'У', 'Ы', 'Э', 'Ю', 'Я',
    //Английские гласные буквы.
    'A', 'E', 'I', 'O', 'U', 'Y' ];
var
  S : String;
  Dw, Dra : set of Char;
  Ch : Char;
  i, Len : Integer;
  F : Boolean;
begin
  {Переключение окна консоли на кодовую страницу CP1251 (Win-1251).
  Если после переключения русские буквы показываются неверно,
  следует открыть системное меню консольного окна - щелчком мыши в левом
  верхнем углу окна консоли и выбрать:
  Свойства - закладка "Шрифт" - выбрать шрифт: "Lucida Console".}
  SetConsoleCP(1251);
  SetConsoleOutputCP(1251);
 
  repeat
    Writeln('------------------------------');
    Writeln('Задайте текст:');
    Readln(S);
 
    //Решение.
    S := AnsiUpperCase(S); //Приводим буквы строки к верхнему регистру.
    Len := Length(S); //Длина строки.
    Dw := [];  //Множество букв, которые входят в текущее слово.
    Dra := []; //Множество гласных букв, которые входят в каждое слово.
    F := True; //True - найдено первое слово, иначе - False.
    for i := 1 to Len do
      if not (S[i] in D) then //Если символ не является разделителем, значит он принадлежит слову.
      begin
        Dw := Dw + [S[i]]; //Добавляем букву во множество букв текущего слова.
        if (i = Len) or (S[i + 1] in D) then //Отслеживаем конец слова.
        begin
          if F then //Если текущее слово является первым словом в тексте.
          begin
            Dra := Dw * Da; //Все гласные буквы текущего слова.
            F := False;
          end
          else //Если текущее слово не первое в тексте (второе, третье и т. д.)
            Dra := Dw * Da * Dra; //Гласные буквы текущего слова, которые входят в каждое из предыдущих слов.
          if Dra = [] then //Если искомое множество уже пусто, то прерываем обработку.
            Break;
          Dw := []; //Обнуление множества букв текущего слова.
        end;
      end;
 
    //Ответ.
    if Dra = [] then
      Writeln('Нет ни одной гласной буквы, которая бы входила в каждое слово.')
    else
    begin
      Writeln('Множество гласных букв, которые входят в каждое слово:');
      for Ch := #0 to #255 do
        if Ch in Dra then
          Write(Ch, ' ');
      Writeln;
    end;
 
    Write('Повторить - Enter. Выход - любой символ + Enter. ');
    Readln(S);
  until S <> '';
end.