[Excel] скопировать/вырезать диапазон ячеек и вставить

uses
  ComObj;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  exApp, exBook, exSh, exRng : OleVariant;
  Od : TOpenDialog;
begin
  //Диалог выбора файла.
  Od := OpenDialog1; //OpenDialog1 уже должен быть на форме.
  if Od.InitialDir = '' then //Начальная папка в диалоге выбора файла.
    Od.InitialDir := ExtractFilePath(ParamStr(0)); //Папка, в которой лежит исполняемый файл программы.
  if not Od.Execute then
    Exit;
  if not FileExists(Od.FileName) then
  begin
    MessageBox(Handle, 'Файл с указанным именем не найден. Действие отменено.',
      'Внимание!', MB_OK + MB_ICONWARNING + MB_APPLMODAL);
    Exit;
  end;
 
  //Запуск экземпляра MS Excel и получение ссылки на интерфейс его корневого объекта 'Excel.Application'.
  exApp := CreateOleObject('Excel.Application');
  //Делаем видимым окно MS Excel.
  exApp.Visible := True;
  //Открытие рабочей книги и получение ссылки на её интерфейс.
  exBook := exApp.WorkBooks.Open(FileName:=Od.FileName);
  //Получаем ссылку на интерфейс первого рабочего листа в рабочей книге.
  exSh := exBook.WorkSheets[1];
 
  //Определяем копируемый диапазон. Пускай его адрес будет таким: 'B3:C6'.
  exRng := exSh.Range[exSh.Cells[3, 2], exSh.Cells[6, 3]]; //Или так: exRng := exSh.Range['B3:C6'];
  //Определяем место вставки - в виде верхней левой ячейки в области вставки.
  //Пускай это будет ячейка с адресом 'F5'.
  //Выполняем копирование и вставку.
  exRng.Copy(Destination:=exSh.Cells[5, 6]); //Или так: exRng.Copy(Destination:=exSh.Range['F5']);
 
  ShowMessage('Копирование выполнено.');
end;

exApp.ActiveWorkBook.WorkSheets[1].Range['A1:A10'].Copy;
exApp.ActiveWorkBook.WorkSheets[1].Range['B5:B15'].PasteSpecial;

procedure TForm1.Button1Click(Sender: TObject);
const
  //Группа констант XlPastType.
  xlPasteValues = -4163; //Вставить только значения.
var
  exApp, exBook, exSh, exRng : OleVariant;
  Od : TOpenDialog;
begin
  //Диалог выбора файла.
  Od := OpenDialog1; //OpenDialog1 уже должен быть на форме.
  if Od.InitialDir = '' then //Начальная папка в диалоге выбора файла.
    Od.InitialDir := ExtractFilePath(ParamStr(0)); //Папка, в которой лежит исполняемый файл программы.
  if not Od.Execute then
    Exit;
  if not FileExists(Od.FileName) then
  begin
    MessageBox(Handle, 'Файл с указанным именем не найден. Действие отменено.',
      'Внимание!', MB_OK + MB_ICONWARNING + MB_APPLMODAL);
    Exit;
  end;
 
  //Запуск экземпляра MS Excel и получение ссылки на интерфейс его корневого объекта 'Excel.Application'.
  exApp := CreateOleObject('Excel.Application');
  //Делаем видимым окно MS Excel.
  exApp.Visible := True;
  //Открытие рабочей книги и получение ссылки на её интерфейс.
  exBook := exApp.WorkBooks.Open(FileName:=Od.FileName);
  //Получаем ссылку на интерфейс первого рабочего листа в рабочей книге.
  exSh := exBook.WorkSheets[1];
 
  //Определяем копируемый диапазон. Пускай его адрес будет таким: 'B3:C6'.
  exRng := exSh.Range[exSh.Cells[3, 2], exSh.Cells[6, 3]]; //Или так: exRng := exSh.Range['B3:C6'];
  //Определяем место вставки - в виде верхней левой ячейки в области вставки.
  //Пускай это будет ячейка с адресом 'F5'.
  //Выполняем копирование и специальную вставку - вставка только значений (Paste:=xlPasteValues).
  exRng.Copy;
  exSh.Cells[5, 6].PasteSpecial(Paste:=xlPasteValues); //Или так: exSh.Range['F5'].PastSpecial(Paste:=xlPasteValues);
  //Если копируемый участок большой, то при закрытии книги MS Excel может
  //вывести диалог с сообщением о том, что в буфере обмена имеется большой
  //блок данных, возможно - изображение.
  //Чтобы этого избежать, можно заменить данные в буфере обмена путём копирования
  //небольшого объёма данных - например, данных одной ячейки. Например, так:
  exSh.Cells[1, 1].Copy;
 
  ShowMessage('Копирование выполнено.');
end;