Считывание данных из текствого файла и запись в EXCEL по столбцам

uses
  ComObj;
 
procedure TForm1.Button1Click(Sender: TObject);
const
  //Имя файла с данными.
  Fn = 'data.txt';
  //Список разделителей полей. #9 - код знака горизонтальной табуляции.
  D = [',', ';', #9];
var
  F : TextFile;
  Str1, StrFld : String;
  i, Pos1, Pos2, Col, Row : Integer;
  EndRow : Boolean;
 
  //Ссылки на объекты OLE-автоматизации.
 
  //Excel.
  exApp : Variant;
  //Рабочая книга Excel.
  exBook : Variant;
  //Pабочий лист в книге Excel.
  exSheet : Variant;
begin
 
  try
 
    //Подключаемся к Excel и получаем ссылку на интересующий нас лист рабочей книги.
 
    //Подключаемся к Excel.
    exApp := CreateOleObject('Excel.Application');
    //Делаем видимым окно Excel.
    exApp.Visible := True;
    //Создаём раб. книгу Excel и подключаемся к ней.
    exBook := exApp.WorkBooks.Add;
    //Подключаемся к первому рабочему листу этой книги.
    exSheet := exBook.WorkSheets[1];
    //Если требуется, задаём называние листа.
    exSheet.Name := 'Данные. Лист 1';
 
    //Формируем шапку таблицы.
    for i := 1 to 10 do begin
      exSheet.Cells[1, i].Value := 'Fld' + IntToStr(i);
    end;
 
    //Читаем построчно данные из файла и записываем их на лист Excel.
 
    AssignFile(F, Fn);
    Reset(F);
    Pos1 := 0;
    Pos2 := 0;
    Col := 1;
    Row := 2; //2 - т. к. на строке 1 расположена шапка таблицы.
    EndRow := False;
    while not Eof(F) do begin
      //Чтение очередной строки из файла.
      Readln(F, Str1);
      //Обрабатываем очередную прочитанную строку.
      for i := 1 to Length(Str1) do begin
        //Отслеживаем начало данных поля.
        if i = 1 then
          Pos1 := i
        else if Str1[i - 1] in D then
          Pos1 := i
        ;
        //Отслеживаем конец данных поля (ячейки) и конец данных строки.
        if i = Length(Str1) then begin
          Pos2 := i;
          EndRow := True;
        end else if Str1[i + 1] in D then
          Pos2 := i
        ;
        //Если найден конец данных очередного поля, то обрабатываем их.
        if Pos2 > 0 then begin
          //Извлекаем строковое значение для очередной ячейки (Row, Col).
          StrFld := Copy(Str1, Pos1, Pos2 - Pos1 + 1);
 
          //Здесь мы имеем полную информацию о текущем состоянии загрузки:
          //Номер текущей строки = Row, номер столбца = Col, данные ячейки = StrFld.
          //Здесь следует добавить свой код обработки данных.
          //
          //Начало.
 
          //Записываем данные в ячейку на листе Excel.
          exSheet.Cells[Row, Col].Value := StrFld;
 
          //Конец.
 
          //Корректируем значения счётчиков и флагов.
          Pos2 := 0;
          Inc(Col);
          if EndRow then begin
            Inc(Row);
            Col := 1;
            EndRow := False;
          end;
        end;
      end;
    end;
  finally
    //Закрываем файл.
    try CloseFile(F) finally end;
 
    //Отключаемся от объектов OLE-автоматизации.
    exSheet := Unassigned;
    exBook := Unassigned;
    exApp := Unassigned;
  end;
end;

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Edit1: TEdit;
    Edit2: TEdit;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
uses
  ComObj;
 
type
  //Тип, задающий динамический массив, элементами которого являются строки.
  //Массив такого типа будем использовать для хранения данных о значениях полей,
  //взятых из строки файла.
  TArrVal = array of String;
 
function GetListVal(const aStr : String) : TArrVal;
const
  //Величина приращения длины динамического массива.
  Capacity = 10;
  //Список разделителей полей. #9 - код знака горизонтальной табуляции.
  D = [',', ';', #9];
var
  i, j, Pos1, Pos2 : Integer;
begin
  Finalize(Result);
 
  //Позиция начала поля.
  Pos1 := 0;
  //Позиция конца поля.
  Pos2 := 0;
  //Индекс элемента массива значений полей.
  j := 0;
  for i := 1 to Length(aStr) do begin
    //Отслеживаем начало поля.
    if i = 1 then
      Pos1 := i
    else if aStr[i - 1] in D then
      Pos1 := i
    ;
    //Отслеживаем конец поля.
    if i = Length(aStr) then
      Pos2 := i
    else if aStr[i + 1] in D then
      Pos2 := i
    ;
    //Если найден конец поля, то обрабатываем его.
    if Pos2 > 0 then begin
      //Увеличиваем длину массива, если требуется.
      if Length(Result) = j then SetLength(Result, j + Capacity);
      //Добавляем строковое значение поля в массив.
      Result[j] := Copy(aStr, Pos1, Pos2 - Pos1 + 1);
      //Сбрасываем флаг конца поля.
      Pos2 := 0;
      //Индекс следующего элемента массива - для следующей итерации.
      Inc(j);
    end;
  end;
  //Корректируем длину массива в соответствие с количеством добавленных в него элементов.
  if j < Length(Result) then SetLength(Result, j);
end;
 
procedure TForm1.Button1Click(Sender: TObject);
type
  //Тип, определяющий способ хранения данных о строковом формате даты.
  TDateFormat = record
    DateSeparator : Char;
    ShortDateFormat : String;
  end;
const
  //Имя файла с данными.
  Fn = 'data.txt';
var
  F : TextFile;
  Str1 : String;
  i, Col, Row : Integer;
  ArrVal : TArrVal;
  Date1, Date2, DateTmp : TDateTime;
  SaveDateFormat : TDateFormat;
 
  //Ссылки на объекты OLE-автоматизации.
 
  //Excel.
  exApp : Variant;
  //Рабочая книга Excel.
  exBook : Variant;
  //Pабочий лист в книге Excel.
  exSheet : Variant;
begin
  //Запоминаем текущий строковый формат даты.
  SaveDateFormat.DateSeparator := DateSeparator;
  SaveDateFormat.ShortDateFormat := ShortDateFormat;
  //Установка нового строкового формата даты.
  DateSeparator := '/';
  ShortDateFormat := 'dd/mm/yyyy';
 
  //Получаем сведения о фильтре по диапазону дат.
  //Внимание! Даты в Edit1 и в Edit2 следует задавать тоже в формате: 'dd/mm/yyyy'.
  Date1 := StrToDate( Edit1.Text );
  Date2 := StrToDate( Edit2.Text );
 
  try
    //Подключаемся к Excel и получаем ссылку на интересующий нас лист рабочей книги.
 
    //Подключаемся к Excel.
    exApp := CreateOleObject('Excel.Application');
    //Делаем видимым окно Excel.
    exApp.Visible := True;
    //Создаём раб. книгу Excel и подключаемся к ней.
    exBook := exApp.WorkBooks.Add;
    //Подключаемся к первому рабочему листу этой книги.
    exSheet := exBook.WorkSheets[1];
    //Если требуется, задаём называние листа.
    exSheet.Name := 'Данные. Лист 1';
 
    //Формируем шапку таблицы.
    for i := 1 to 10 do begin
      exSheet.Cells[1, i].Value := 'Fld' + IntToStr(i);
    end;
 
    //Читаем построчно данные из файла и записываем их на лист Excel.
 
    AssignFile(F, Fn);
    Reset(F);
    //Индекс верхней строки области данных в таблицы Excel.
    //2 - т. к. на строке 1 расположена шапка таблицы.
    Row := 2;
    while not Eof(F) do begin
      //Чтение очередной строки из файла.
      Readln(F, Str1);
      //Получаем из строки список значений полей.
      ArrVal := GetListVal(Str1);
 
      //Если меньше двух полей - пропускаем итерацию.
      if Length(ArrVal) < 2 then Continue;
      //Если второе поле содержит неверное представление даты - пропускаем итерацию.
      if not TryStrToDate(ArrVal[1], DateTmp) then Continue;
      //Если дата не принадлежит заданному диапазону - пропускаем итерацию.
      if not ( (DateTmp >= Date1) and (DateTmp <= Date2) ) then Continue;
 
      //Переписываем значения полей в строку таблицы на листе Excel.
      Col := 1;
      for i := 0 to High(ArrVal) do begin
        exSheet.Cells[Row, Col].Value := ArrVal[i];
        Inc(Col);
      end;
      //Переходим к следующей строке таблицы Excel.
      Inc(Row);
    end;
  finally
    //Закрываем файл.
    try CloseFile(F) finally end;
 
    //Отключаемся от объектов OLE-автоматизации.
    exSheet := Unassigned;
    exBook := Unassigned;
    exApp := Unassigned;
 
    //Освобождаем память, выделенную для динамического массива
    //и для его элементов - строк.
    Finalize(ArrVal);
 
    //Возвращем прежний формат строкового представления даты.
    DateSeparator := SaveDateFormat.DateSeparator;
    ShortDateFormat := SaveDateFormat.ShortDateFormat;
  end;
end;
 
end.