Функция, находящая наибольший элемент непустого бинарного дерева

program Project1;
 
{$APPTYPE CONSOLE}
 
uses
  SysUtils, Windows;
 
type
  //Тип ключа (тип основных данных) узла дерева.
  TData = Integer;
  //Тип указателя на узел.
  TPNode = ^TNode;
  //Тип узла дерева.
  TNode = record
    Data : TData;           //Ключ (основные данные) узла дерева.
    PLeft, PRight : TPNode; //Указатели на левый и правый узел.
  end;
 
//Процедура для освобождения памяти, занятой деревом. (Удаление дерева).
procedure TreeFree(var aPNode : TPNode);
begin
  if aPNode = nil then
    Exit;
  TreeFree(aPNode^.PLeft);  //Рекурсивный вызов для освобождения памяти в левой ветви.
  TreeFree(aPNode^.PRight); //Рекурсивный вызов для освобождения памяти в правой ветви.
  Dispose(aPNode);          //Освобождение памяти, занятой для текущего узла.
  aPNode := nil;            //Обнуление указателя на текущий узел.
end;
 
//Добавление узла с ключом aData в двоичное дерево поиска.
procedure AddNode(var aPNode : TPNode; const aData : TData);
begin
  if aPNode = nil then     //Вставка узла.
  begin
    New(aPNode);           //Выделяем память для узла.
    aPNode^.Data := aData; //Записываем в узел значение ключа.
    aPNode^.PLeft := nil;  //Обнуление указателя на левого потомка.
    aPNode^.PRight := nil; //Обнуление указателя на правого потомка.
  end
  else if aData <= aPNode^.Data then //Поиск места вставки в левой ветви.
    AddNode(aPNode^.PLeft, aData)
  else if aData > aPNode^.Data then //Поиск места вставки в правой ветви.
    AddNode(aPNode^.PRight, aData);
end;
 
{Процедура для распечатки структуры дерева и значений узлов. С обходом в прямом
направлении (узел - левое поддерево - правое поддерево).
Пример вызова: TreeWriteln(PTree, '0');
'0' - Обозначение узла, который является корнем дерева.
'1' - Обозначение левого потомка.
'2' - Обозначение правого потомка.
Если при создании дерева ввести значения узлов в следующем порядке:
5 -3 -8 -9 2 0 4 6 8 7 9
то будет создано дерево:
                              (0)
                               5
                    /                     \
                 (0-1)                   (0-2)
                  -3                       6
             /         \                      \
         (0-1-1)     (0-1-2)                (0-2-2)
           -8           2                      8
       /           /        \             /        \
  (0-1-2-1)   (0-1-2-1)  (0-1-2-2)   (0-2-2-1)  (0-2-2-2)
     -9           0          4           7          9
Распечатка этого дерева будет выглядеть так:
0: 5
0-1: -3
0-1-1: -8
0-1-1-1: -9
0-1-2: 2
0-1-2-1: 0
0-1-2-2: 4
0-2: 6
0-2-2: 8
0-2-2-1: 7
0-2-2-2: 9                                      }
procedure TreeWriteln(const aPNode : TPNode; const aName : String);
begin
  if aPNode <> nil then
  begin
    Writeln(aName, ': ', aPNode^.Data);        //Распечатка текущего узла.
    TreeWriteln(aPNode^.PLeft, aName + '-1');  //Рекурсивный вызов для левой ветви.
    TreeWriteln(aPNode^.PRight, aName + '-2'); //Рекурсивный вызов для правой ветви.
  end;
end;
 
{Если узел aPNode существует, то функция возвращает значение True, а через параметр
aDataMax возвращает наибольшее из значений узлов в дереве (поддереве) с корнем aPNode.
Есди узел aPNode не существует, то функция возвращает значение False, а поиск наибольшего
значения, в этом случае, не выполняется.}
function TreeMax(const aPNode : TPNode; out aDataMax : TData) : Boolean;
var
  Data : TData;
begin
  Result := aPNode <> nil;
  if Result then          
  begin
    aDataMax := aPNode^.Data;
    if TreeMax(aPNode^.PLeft, Data) and (Data > aDataMax) then //Поиск наибольшего в левой ветви.
      aDataMax := Data;
    if TreeMax(aPNode^.PRight, Data) and (Data > aDataMax) then //Поиск наибольшего в правой ветви.
      aDataMax := Data;
  end;
end;
 
var
  PTree : TPNode;
  Data : TData;
  Code : Integer;
  S : String;
begin
  {Переключение окна консоли на кодовую страницу CP1251 (Win-1251).
  Если после переключения русские буквы показываются неверно,
  следует открыть системное меню консольного окна - щелчком мыши в левом
  верхнем углу окна консоли и выбрать:
  Свойства - закладка "Шрифт" - выбрать шрифт: "Lucida Console" либо "Consolas".}
  SetConsoleCP(1251);
  SetConsoleOutputCP(1251);
 
  PTree := nil; //Начальная инициализация дерева.
 
  repeat
    Writeln('--------------------------------------------------');
    //Диалог создания дерева.
    Writeln('Добавление узлов в двоичное дерево поиска.');
    Writeln('Чтобы прекратить ввод, оставьте пустую строку и нажмите Enter.');
    repeat
      Write('Задайте ключ: ');
      Readln(S);
      if S <> '' then
      begin
        Val(S, Data, Code);
        if Code = 0 then
          AddNode(PTree, Data) //Добавляем узел в дерево.
        else
          Writeln('Неверный ввод! Должно быть задано целое число. Повторите.');
      end;
    until S = '';
    Write('Ввод дерева завершён.');
    //Распечатка дерева.
    Writeln('Создано дерево:');
    TreeWriteln(PTree, '0');
    //Поиск наибольшего.
    if TreeMax(PTree, Data) then
      Writeln('Наибольшее значение среди узлов дерева: ', Data)
    else
      Writeln('Дерево пустое. Действие отменено!');
    //Освобождение памяти, занятой для элементов дерева (очистка дерева).
    TreeFree(PTree);
    Writeln('Память, выделенная для дерева - освобождена.');
    Writeln('-----');
    Write('Повторить - Enter, выход - любой символ + Enter. ');
    Readln(S);
  until S <> '';
end.