msWord как заменить текст по метке

uses
  ComObj;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  wdApp, wdDoc, wdBms, wdBm, wdRng : Variant;
  i : Integer;
  Fn, S, BmName : String;
begin
  //Путь к файлу.
  Fn := ExtractFilePath(Application.ExeName) + 'MyDocument.doc';
  //Проверка.
  if not FileExists(Fn) then begin
    ShowMessage(
      'Файл с именем: ' + #10
      + Fn + #10
      + 'не найден.' + #10
      + 'Действие отменено.'
    );
    Exit;
  end;
 
  //Очистка Мемо.
  Memo1.Clear;
 
  try
    //Запуск MS Word.
    wdApp := CreateOleObject('Word.Application');
    //Делаем видимым главное окно MS Word.
    wdApp.Visible := True;
    //Открываем файл документа.
    wdDoc := wdApp.Documents.Open(FileName := Fn);
    //Подключаемся к коллекции закладок.
    wdBms := wdDoc.Bookmarks;
 
    //Перебор всех закладок.
    Memo1.Lines.Add('Перечень закладок:');
    for i := 1 to wdBms.Count do begin
      Memo1.Lines.Add('N' + IntToStr(i) + ', текст: "' + wdBms.Item(i).Range.Text + '".');
    end;
    Memo1.Lines.Add('Всего закладок: ' + IntToStr(wdBms.Count));
 
    //Меняем тексты во всех закладках, добавляя в качестве префикса имя закладки
    //и выделяем этот текст оттенком красного.
    //При этом происходит следующее. При переопределении текста диапазона,
    //с которым связана закладка, происходит переопределение самого этого диапазона
    //и закладка автоматически удаляется. Поэтому, мы пересоздаём закладки.
    for i := wdBms.Count downto 1 do begin
      wdBm := wdBms.Item(i);
      BmName := wdBm.Name;
      wdRng := wdBm.Range;
      S := wdRng.Text;
      //В этот момент прежняя закладка уничтожается.
      wdRng.Text := wdBm.Name + ': ' + S;
      wdRng.Font.Color := RGB(255, 100, 100);
      //Создаём (пересоздаём) закладку с прежним именем.
      wdBms.Add(Name := bmName, Range := wdRng);
    end;
 
    //Если требуется, сохраняем документ.
    //wdDoc.Save;
    //Если требуется, закрываем MS Word.
    //wdDoc.Quit;
  finally
    //Отключаемся от объектов автоматизации.
    wdApp := Unassigned;
    wdDoc := Unassigned;
    wdBms := Unassigned;
    wdBm := Unassigned;
    wdRng := Unassigned;
  end;
end;