Отображение данных из Excel в TStringGrid.

uses
  ComObj;
 
procedure TForm1.Button1Click(Sender: TObject);
const
  BookName = 'Книга1.xls';
var
  ExApp, ExBook, ExSheet : Variant;
  Col, Col1, Col2, Row, Row1, Row2 : Integer;
  FileName, S : String;
begin
  try
    //Запуск Excel и подключение к корневому объекту.
    ExApp := CreateOleObject('Excel.Application');
    //Если требуется, делаем окно Excel видимым.
    ExApp.Visible := True;
    //Открываем рабочую книгу и получаем на неё ссылку.
    FileName := ExtractFilePath(Application.ExeName) + BookName;
    ExBook := ExApp.WorkBooks.Open(FileName:=FileName);
    //Получаем ссылку на первый рабочий лист в рабочей книге.
    ExSheet := ExBook.WorkSheets[1];
 
    //Перебор строк таблицы, расположенной на листе рабочей книги.
    //Предположим, таблица имеет 8 столбцов с номерами 1..8.
    //Данные таблицы расположены, начиная с 3 строки и до конца
    //используемого диапазона на этом листе.
    Row1 := 3;
    Col1 := 1;
    Row2 := ExSheet.UsedRange.Row + ExSheet.UsedRange.Rows.Count - 1;
    Col2 := 8;
    for Row := Row1 to Row2 do begin
      for Col := Col1 to Col2 do begin
        //Читаем данные очередной ячейки.
        S := ExSheet.Cells[Row, Col].Value;
        //Как-то обрабатываем полученные данные.
        //...
        //...
        //...
      end;
    end;
    //Если требуется, закрываем рабочую книгу.
    //ExBook.Close;
    //Если требуется, выходим из Excel.
    //ExApp.Quit;
  finally
    //Отключаемся от объектов OLE-автоматизации.
    ExApp := Unassigned;
    ExBook := Unassigned;
    ExSheet := Unassigned;
  end;
end;

uses
  ComObj;
 
procedure TForm1.Button1Click(Sender: TObject);
const
  BookName = 'Книга1.xls';
var
  ExApp, ExBook, ExSheet : Variant;
  C, R, Col, Col1, Col2, Row, Row1, Row2 : Integer;
  FileName, S : String;
  Sg : TStringGrid;
begin
  Sg := StringGrid1;
  try
    //Запуск Excel и подключение к корневому объекту.
    ExApp := CreateOleObject('Excel.Application');
    //Если требуется, делаем окно Excel видимым.
    ExApp.Visible := True;
    //Открываем рабочую книгу и получаем на неё ссылку.
    FileName := ExtractFilePath(Application.ExeName) + BookName;
    ExBook := ExApp.WorkBooks.Open(FileName:=FileName);
    //Получаем ссылку на первый рабочий лист в рабочей книге.
    ExSheet := ExBook.WorkSheets[1];
 
    //Определяем границы таблицы на листе Excel.
    Row1 := 3;
    Col1 := 1;
    Row2 := ExSheet.UsedRange.Row + ExSheet.UsedRange.Rows.Count - 1;
    Col2 := ExSheet.UsedRange.Column + ExSheet.UsedRange.Columns.Count - 1;
 
    //Задаём размер таблицы StringGrid1 в соответствие с размером
    //таблицы на листе Excel.
    Sg.RowCount := Row2 - Row1 + 1;
    Sg.ColCount := Col2 - Col1 + 1;
    R := 0;
    for Row := Row1 to Row2 do begin
      C := 0;
      for Col := Col1 to Col2 do begin
        //Читаем данные очередной ячейки на листе Excel
        //и записываем их в ячейку в StringGrid1.
        Sg.Cells[C, R] := ExSheet.Cells[Row, Col].Value;
        //Переход к следующему столбцу StringGrid1.
        Inc(C);
      end;
      //Переход к следующей строке StringGrid1.
      Inc(R);
    end;
    //Если требуется, закрываем рабочую книгу.
    //ExBook.Close;
    //Если требуется, выходим из Excel.
    //ExApp.Quit;
  finally
    //Отключаемся от объектов OLE-автоматизации.
    ExApp := Unassigned;
    ExBook := Unassigned;
    ExSheet := Unassigned;
  end;
end;

ExApp.Visible := False; //True - на время отладки.

uses
  ComObj;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  ExApp, ExBook, ExSheet : Variant;
  C, R, Col, Col1, Col2, Row, Row1, Row2 : Integer;
  FileName : String;
  Sg : TStringGrid;
begin
  if OpenDialog1.InitialDir = '' then
    OpenDialog1.InitialDir := ExtractFilePath(Application.ExeName)
  ;
  if not OpenDialog1.Execute then Exit;
  FileName := OpenDialog1.FileName;
  if not FileExists(FileName) then begin
    ShowMessage('Внимание! Файл с указанным именем не существует. Действие отменено.');
    Exit;
  end;
 
  Sg := StringGrid1;
  try
    //Запуск Excel и подключение к корневому объекту.
    ExApp := CreateOleObject('Excel.Application');
    //Если требуется, делаем окно Excel видимым.
    ExApp.Visible := True;
    //Открываем рабочую книгу и получаем на неё ссылку.
    ExBook := ExApp.WorkBooks.Open(FileName:=FileName);
    //Получаем ссылку на первый рабочий лист в рабочей книге.
    ExSheet := ExBook.WorkSheets[1];
 
    //Определяем границы таблицы на листе Excel.
    Row1 := 3;
    Col1 := 1;
    Row2 := ExSheet.UsedRange.Row + ExSheet.UsedRange.Rows.Count - 1;
    Col2 := ExSheet.UsedRange.Column + ExSheet.UsedRange.Columns.Count - 1;
 
    //Задаём размер таблицы StringGrid1 в соответствие с размером
    //таблицы на листе Excel.
    //Предусматриваем случай, если на листе нет данных.
    if (Row2 - Row1 + 1) <= Sg.FixedRows then
      Sg.RowCount := Sg.FixedRows + 1
    else
      Sg.RowCount := Row2 - Row1 + 1
    ;
    if (Col2 - Col1 + 1) <= 0 then
      Sg.ColCount := 1
    else
      Sg.ColCount := Col2 - Col1 + 1
    ;
    //Читаем данные с листа Excel.
    R := 0;
    for Row := Row1 to Row2 do begin
      C := 0;
      for Col := Col1 to Col2 do begin
        //Читаем данные очередной ячейки на листе Excel
        //и записываем их в ячейку в StringGrid1.
        Sg.Cells[C, R] := ExSheet.Cells[Row, Col].Value;
        //Переход к следующему столбцу StringGrid1.
        Inc(C);
      end;
      //Переход к следующей строке StringGrid1.
      Inc(R);
    end;
    //Если требуется, закрываем рабочую книгу.
    //ExBook.Close;
    //Если требуется, выходим из Excel.
    //ExApp.Quit;
  finally
    //Отключаемся от объектов OLE-автоматизации.
    ExApp := Unassigned;
    ExBook := Unassigned;
    ExSheet := Unassigned;
  end;
end;