Всем добрый вечер. Мне нужно создать Новогоднюю анимационную открытку на Делфи

object frmMain: TfrmMain
  Left = 0
  Top = 0
  BorderStyle = bsSingle
  Caption = #1057' '#1085#1086#1074#1099#1084' 2017.'
  ClientHeight = 571
  ClientWidth = 794
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'Tahoma'
  Font.Style = []
  OldCreateOrder = False
  OnCreate = FormCreate
  PixelsPerInch = 96
  TextHeight = 13
  object img: TImage
    Left = 0
    Top = 0
    Width = 794
    Height = 571
    Align = alClient
    ExplicitLeft = 80
    ExplicitTop = 120
    ExplicitWidth = 105
    ExplicitHeight = 105
  end
  object tmr: TTimer
    Interval = 200
    OnTimer = tmrTimer
    Left = 16
    Top = 16
  end
end

unit thread1882202formMain;
 
interface
 
uses
  Windows, Messages,
 
  SysUtils, Variants, Classes, Contnrs,
 
  Graphics, Controls, Forms, Dialogs, ExtCtrls;
 
const
  TICKS_LIM = 10;
  IMG_MARGIN = 100;
  LIFE_TIME_RND = 50;
  LIFE_TIME_MIN = 10;
 
type
  TFirework = class;
 
  TFireworkItem = class(TObject)
  strict private
    FOwner : TFirework;
    FX, FY, FV, FA, FAngle : Extended;
    FColor : TColor;
 
  public
    constructor Create(const AOwner : TFirework; const AX, AY, AV, AA, AAngle : Extended; const AColor : TColor);
 
    procedure Paint(const ACanvas : TCanvas);
    procedure Erase(const ACanvas : TCanvas);
    procedure Move;
 
    property X : Extended  read FX;
    property Y : Extended  read FY;
    property V : Extended  read FV;
    property A : Extended  read FA;
    property Angle : Extended  read FAngle;
    property Color : TColor  read FColor;
  end;
 
  TFirework = class(TObject)
  strict private
    FX, FY, FLifetime : integer;
    FItems : TObjectList;
 
    function GetItems(const AIndex: integer): TFireworkItem;
    function GetItemsCount: integer;
 
    procedure GenerateItems(const ACount : integer);
 
  public
    constructor Create(const AX, AY, AFifeTime : integer);
    destructor Destroy; override;
 
    procedure Paint(const ACanvas : TCanvas);
    procedure Erase(const ACanvas : TCanvas);
    procedure Move;
 
    function DecLifeTime : boolean;
 
    property ItemsCount : integer read GetItemsCount;
    property Items[const AIndex : integer] : TFireworkItem read GetItems;
  end;
 
  TfrmMain = class(TForm)
    img: TImage;
    tmr: TTimer;
    procedure FormCreate(Sender: TObject);
    procedure tmrTimer(Sender: TObject);
 
  strict private
    FFireworks : TObjectList;
    FTicks : integer;
 
  public
    constructor Create(AOwner : TComponent); override;
    destructor Destroy; override;
 
  end;
 
var
  frmMain: TfrmMain;
 
implementation
 
{$R *.dfm}
 
{$REGION 'TFireworkItem'}
constructor TFireworkItem.Create(const AOwner: TFirework; const AX, AY, AV, AA, AAngle: Extended;
  const AColor: TColor);
begin
  inherited Create();
 
  FOwner := AOwner;
  FX := AX;
  FY := AY;
  FV := AV;
  FA := AA;
  FAngle := AAngle;
  FColor := AColor;
end;
 
procedure TFireworkItem.Erase(const ACanvas : TCanvas);
begin
  ACanvas.Pixels[ Round(FX), Round(FY) ] := clBlack;
end;
 
procedure TFireworkItem.Move;
begin
  FX := FX + FV*Cos(FAngle);
  FY := FY + FV*Sin(FAngle);
 
  FV := FV + FA;
  if FV < 0.0 then
    FV := 0.0;
end;
 
procedure TFireworkItem.Paint(const ACanvas : TCanvas);
begin
  ACanvas.Pixels[ Round(FX), Round(FY) ] := FColor;
end;
{$ENDREGION}
 
{$REGION 'TFirework'}
constructor TFirework.Create(const AX, AY, AFifeTime: integer);
begin
  inherited Create();
 
  FX := AX;
  FY := AY;
  FLifetime := AFifeTime;
 
  FItems := TObjectList.Create(True);
 
  GenerateItems(50 + Random(50));
end;
 
function TFirework.DecLifeTime: boolean;
begin
  Dec(FLifetime);
 
  Result := FLifetime <= 0;
end;
 
destructor TFirework.Destroy;
begin
  FreeAndNil(FItems);
  inherited;
end;
 
procedure TFirework.Erase(const ACanvas : TCanvas);
var
  i : integer;
begin
  for i := 0 to FItems.Count - 1 do
    Items[i].Erase(ACanvas);
end;
 
function TFirework.GetItems(const AIndex: integer): TFireworkItem;
begin
  Result := TFireworkItem(FItems[AIndex]);
end;
 
function TFirework.GetItemsCount: integer;
begin
  Result := FItems.Count;
end;
 
procedure TFirework.Move;
var
  i : integer;
begin
  for i := 0 to FItems.Count - 1 do
    Items[i].Move;
end;
 
procedure TFirework.Paint(const ACanvas : TCanvas);
var
  i : integer;
begin
  for i := 0 to FItems.Count - 1 do
    Items[i].Paint(ACanvas);
end;
 
procedure TFirework.GenerateItems(const ACount: integer);
var
  i : integer;
begin
  FItems.Count := ACount;
 
  for i := 0 to FItems.Count - 1 do
    FItems[i] := TFireworkItem.Create(Self, FX, FY, Random(50) / 10, (Random(20) - 1) / 10, 2*pi*Random(100)/100, RGB(Random(MAXBYTE), Random(MAXBYTE), Random(MAXBYTE)) );
end;
{$ENDREGION}
 
{$REGION 'TfrmMain'}
constructor TfrmMain.Create(AOwner: TComponent);
begin
  inherited;
 
  FFireworks := TObjectList.Create(True);
end;
 
destructor TfrmMain.Destroy;
begin
  FreeAndNil(FFireworks);
  inherited;
end;
 
procedure TfrmMain.FormCreate(Sender: TObject);
begin
  Application.Title := Caption;
 
  img.Canvas.Brush.Color := clBlack;
  img.Canvas.FillRect(img.Canvas.ClipRect);
 
  Randomize;
 
  FTicks := TICKS_LIM - 1;
end;
 
procedure TfrmMain.tmrTimer(Sender: TObject);
var
  i : integer;
  Firework : TFirework;
begin
  Inc(FTicks);
 
  if FTicks > TICKS_LIM then
  begin
    FTicks := 0;
 
    Firework := TFirework.Create(Random(img.Width - 2*IMG_MARGIN) + IMG_MARGIN, Random(img.Height - 2*IMG_MARGIN) + IMG_MARGIN, Random(LIFE_TIME_RND) + LIFE_TIME_MIN);
    FFireworks.Add(Firework)
  end;
 
  for i := FFireworks.Count - 1 downto 0 do
  begin
    Firework := TFirework(FFireworks[i]);
 
    Firework.Erase(img.Canvas);
 
    if Firework.DecLifeTime then
      FFireworks.Delete(i)
 
    else
    begin
      Firework.Move();
 
      Firework.Paint(img.Canvas);
    end;
  end;
 
end;
{$ENDREGION}
 
end.