Вертикальная ориентация текста

procedure TForm4.strngrd1DrawCell(Sender: TObject; ACol, ARow: Integer;
  Rect: TRect; State: TGridDrawState);
var
LFont: TLogFont;
hOldFont, hNewFont: HFont;
begin
if (ACol>0) and (ARow=0) then
  begin
    strngrd1.Canvas.FillRect(Rect);
    GetObject(strngrd1.Canvas.Font.Handle,SizeOf(LFont),Addr(LFont));
    LFont.lfEscapement := 900;
    LFont.lfheight := 15;
    LFont.lfwidth := 6;
    LFont.lfweight := 900;
    LFont.lfcharset := 1;
    LFont.lfoutprecision := out_tt_precis;
    LFont.lfquality := draft_quality;
    LFont.lfpitchandfamily := FF_Modern;
    hNewFont := CreateFontIndirect(LFont);
    hOldFont := SelectObject(strngrd1.Canvas.Handle,hNewFont);
//    SetTextColor(strngrd1.Canvas.Handle,clBlack);
    strngrd1.Canvas.TextOut(Rect.Left+2,Rect.Top+295,strngrd1.Cells[ACol,ARow]);
    hNewFont := SelectObject(strngrd1.Canvas.Handle,hOldFont);
    DeleteObject(hNewFont);
  end;
end;

type
  TStringGrid = class (Vcl.Grids.TStringGrid)
  protected
    procedure DrawCell(ACol: Integer; ARow: Integer; ARect: TRect; AState: TGridDrawState); override;
  public
    constructor Create(AOwner: TComponent); override;
  end;
 
  TForm1 = class(TForm)
  ...

constructor TStringGrid.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  DefaultDrawing:= false;
end;

procedure TStringGrid.DrawCell(ACol, ARow: Integer; ARect: TRect; AState: TGridDrawState);
var
  LFont: TLogFont;
  hOldFont, hNewFont: HFONT;
begin
  Canvas.Font:= Font;                                      // читаем шрифт из настроек Грида
  // фиксированная ячейка
  if (gdFixed in AState) then
  begin
    DrawCellBackground(ARect,FixedColor,AState,ACol,ARow);   // рисуем фон
    if (ARow = 0) then                   // верхний ряд фиксированных ячеек, рисуем вертикально
    begin
      GetObject(Canvas.Font.Handle,SizeOf(LFont),Addr(LFont));
      LFont.lfEscapement:= 900;
      LFont.lfHeight:= 15;
      LFont.lfWidth:= 6;
      LFont.lfWeight:= 900;
      LFont.lfCharSet:= 1;
      LFont.lfOutPrecision:= OUT_TT_PRECIS;
      LFont.lfQuality:= DRAFT_QUALITY;
      LFont.lfPitchAndFamily:= FF_MODERN;
      hNewFont:= CreateFontIndirect(LFont);
      hOldFont:= SelectObject(Canvas.Handle,hNewFont);
      Canvas.TextOut(ARect.Left+2,ARect.Top+ARect.Height-3,Cells[ACol,ARow]);
      hNewFont:= SelectObject(Canvas.Handle,hOldFont);
      DeleteObject(hNewFont);
    end else
      Canvas.TextOut(ARect.Left+2,ARect.Top+2,Cells[ACol,ARow]);
  end else
  begin
    if (gdSelected in AState) then DrawCellHighlight(ARect,AState,ACol,ARow) // выделенная ячейка
    else DrawCellBackground(ARect,Color,AState,ACol,ARow);                   // обычная ячейка
    Canvas.TextOut(ARect.Left+2,ARect.Top+2,Cells[ACol,ARow]);
  end;
end;

procedure TForm1.FormCreate(Sender: TObject);
begin
  with StringGrid1 do
  begin
    RowHeights[0]:= 150;
    ColWidths[0]:= 150;
    Cells[1,0]:= 'Hello';
    Cells[2,0]:= 'World';
    Cells[0,1]:= 'Hello';
    Cells[0,2]:= 'World';
    Cells[1,1]:= 'H';
    Cells[2,2]:= 'W';
  end;
end;