Перевести код программм из Pascal в Delphi 7

@Parkervans · Регистрация: 19.04.2017

Author24 — интернет-сервис помощи студентам

Добрый день! Необходимо перевести код из Pascal в Delphi 7.

Pascal

uses crt;
const s1:array[1..4] of string[6]=('пики','трефы','бубны','червы');
      s2:array[1..9] of string[6]=('6','7','8','9','10','валет','дама',
                                   'король','туз');
type mast=(pk,tr,bb,ch);
     dost=(k6,k7,k8,k9,k10,vl,dm,kr,tz);
     karta=record
           m:mast;
           d:dost;
           end;
          
function Kick(k1,k2:karta;km:mast):boolean;
var i:mast;
    j:dost;
begin
Kick:=((k1.m=km)and(k2.m<>km)){первая козырная, вторая не козырная}
or((k1.m=k2.m)and(k1.d>k2.d));{или одной масти и первая старше}
end;
 
var k1,k2:karta;
    km:mast;
    i,j:byte;
    s:string[6];
    f:boolean;
begin
clrscr;
f:=false;
 
 
repeat
writeln('Введите масть первой карты (пики,трефи,бубны,червы)');
readln(s);
i:=1;
while(i<=4)and not f do
if s=s1[i] then
 begin
  k1.m:=mast(i-1);
  f:=true;
 end
else i:=i+1;
if not f then writeln('Такой масти нет, повторите ввод')
until f;
 
 
 
f:=false;
repeat
writeln('Введите достоинство первой карты (6,7,8,9,10,валет,дама, король,туз)');
readln(s);
i:=1;
while(i<=9)and not f do
if s=s2[i] then
 begin
  k1.d:=dost(i-1);
  f:=true;
 end
else i:=i+1;
if not f then writeln('Такого достоинства нет, повторите ввод')
until f;
 
 
f:=false;
repeat
writeln('Введите масть второй карты (пики,трефи,бубны,червы)');
readln(s);
i:=1;
while(i<=4) and not f do
if s=s1[i] then
 begin
  k2.m:=mast(i-1);
  f:=true;
 end
else i:=i+1;
if not f then writeln('Такой масти нет, повторите ввод')
until f;
 
 
f:=false;
repeat
writeln('Введите достоинство второй карты (6,7,8,9,10,валет,дама, король,туз)');
readln(s);
i:=1;
while(i<=9)and not f do
if s=s2[i] then
 begin
  k2.d:=dost(i-1);
  f:=true;
 end
else i:=i+1;
if not f then writeln('Такого достоинства нет, повторите ввод')
until f;
 
 
f:=false;
repeat
writeln('Введите козырную масть(пики,трефи,бубны,червы)');
readln(s);
i:=1;
while(i<=4)and not f do
if s=s1[i] then
 begin
  km:=mast(i-1);
  f:=true;
 end
else i:=i+1;
if not f then writeln('Такой масти нет, повторите ввод')
until f;
 
 
writeln('Бьет ли первая карта вторую?');
write(Kick(k1,k2,km));
readln
end.

@Puporev · 29.05.2018, 19:00

Delphi

type
  TForm1 = class(TForm)
    Label1: TLabel;
    RadioGroup1: TRadioGroup;
    RadioGroup2: TRadioGroup;
    Label2: TLabel;
    RadioGroup3: TRadioGroup;
    RadioGroup4: TRadioGroup;
    RadioGroup5: TRadioGroup;
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
type mast=(pk,tr,bb,ch);
     dost=(k6,k7,k8,k9,k10,vl,dm,kr,tz);
     karta=record
           m:mast;
           d:dost;
           end;
          
function Kick(k1,k2:karta;km:mast):boolean;
begin
Kick:=((k1.m=km)and(k2.m<>km)){первая козырная, вторая не козырная}
or((k1.m=k2.m)and(k1.d>k2.d));{или одной масти и первая старше}
end;
procedure TForm1.Button1Click(Sender: TObject);
var k1,k2:karta;
    km:mast;
begin
if RadioGroup1.ItemIndex=-1 then
 begin
  ShowMessage('Вы не выбрали масть 1 карты');
  exit;
 end;
k1.m:=mast(RadioGroup1.ItemIndex);
if RadioGroup2.ItemIndex=-1 then
 begin
  ShowMessage('Вы не выбрали достоинство 1 карты');
  exit;
 end;
k1.d:=dost(RadioGroup2.ItemIndex);
if RadioGroup3.ItemIndex=-1 then
 begin
  ShowMessage('Вы не выбрали масть 2 карты');
  exit;
 end;
k2.m:=mast(RadioGroup3.ItemIndex);
if RadioGroup4.ItemIndex=-1 then
 begin
  ShowMessage('Вы не выбрали достоинство 2 карты');
  exit;
 end;
k2.d:=dost(RadioGroup4.ItemIndex);
if RadioGroup5.ItemIndex=-1 then
 begin
  ShowMessage('Вы не выбрали козырную масть');
  exit;
 end;
km:=mast(RadioGroup5.ItemIndex);
ShowMessage('Бьет ли первая карта вторую?'+#13#10
+booltostr(Kick(k1,k2,km),true));
end;

@Parkervans · 29.05.2018, 20:15 **[ТС]**

Спасибо большое

@Parkervans 4 / 4 / 3 Регистрация: 19.04.2017 Сообщений: 66
	29.05.2018, 20:15 [ТС]	3
	Спасибо большое 0

Перевести код программм из Pascal в Delphi 7

Решение