Нужно чтобы цифры не выводились в консоль, как это реализовать?

program Project1;
 
{$APPTYPE CONSOLE}
 
uses
  SysUtils,
  Windows;
 
type
  //Сведения о слове.
  TWord = record
    //Само слово.
    SWord : String;
    //Количество обнаружений слова в тексте.
    Cnt : Integer;
  end;
  //Хранилище уникальных слов.
  TVault = record
    //Количество слов в хранилище. - Количество значимых элементов массива.
    Len : Integer;
    //Массив сведений о словах. Длина этого массива
    //может быть большей или равной Len.
    Arr : array of TWord;
  end;
 
//Добавляет слово в массив хранилища Vault. При этом, если добавляемое
//слово уже присутствует в массиве, тогда счётчик этого слова увеличивается
//на единицу. Если добавляемое слово пока не присутствует в массиве, тогда
//это слово записывается в массив и его счётчик устанавливается равным единице.
procedure AddToVault(var aVault : TVault; const aWord : String);
const
  //Величина приращения длины массива.
  Capacity = 20;
var
  i : Integer;
begin
  with aVault do begin
    //Просматриваем массив - проверяем,
    //есть ли уже в нём такое слово.
    i := 0;
    while i < Len do begin
      //Если такое же слово найдено, то увеличиваем
      //его счётчик на единицу и выходим из цикла.
      if Arr[i].SWord = aWord then begin
        Inc( Arr[i].Cnt );
        Break;
      end;
      Inc(i);
    end;
    //Если в предыдущем цикле слово не найдено, то при выходе
    //из цикла будем иметь равенство i = Len. В этом случае
    //добавляем слово в массив и устанавливаем счётчик этого
    //слова равным единице. Индекс добавляемого слова,
    //равен i.
    if i = Len then begin
      //Если количество значимых элементов массива в настоящий момент
      //равно длине массива, это означает, что в массиве нет места
      //для добавления нового элемента. Поэтому, в этом случае,
      //наращиваем длину массива. Длину массива увеличиваем
      //на велечину Capacity.
      if Len = Length(Arr) then
        SetLength(Arr, Len + Capacity)
      ;
      //Так как мы добавляем в массив новое слово, то количество значимых
      //элементов массива становится на единицу больше.
      Inc(Len);
      //Записываем в массив данные нового элемента (слова).
      Arr[i].SWord := aWord;
      Arr[i].Cnt := 1;
    end;
  end;
end;
 
const
  //Разделители слов.
  D = ['.', ',', ':', ';', '!', '?', '-', ' ', #9, #10, #13];
var
  S, SWord : String;
  i, Pos1, Len : Integer;
  Vault : TVault;
begin
  //Переключение консоли на кодовую страницу CP1251 (Win-1251).
  //Если после переключения русские буквы показываются неверно, следует
  //открыть системное меню консольного окна - слева вверху окна консоли.
  //И выбрать: Свойства - закладка "Шрифт" - выбрать шрифт: "Lucida Console".
  SetConsoleCP(1251);
  SetConsoleOutputCP(1251);
 
  repeat
    Writeln('Введите текст:');
    Readln(S);
 
    Vault.Len := 0;
 
    //Извлекаем слова и добавляем их в хранилище Vault.
    //Добавление слов в хранилище Vault производится через процедуру AddToVault().
    //Эта процедура спроектирована так, что при записи формируется массив
    //уникальных слов со сведениями о количестве обнаружений каждого слова.
    Len := Length(S);
    Pos1 := 0;
    for i := 1 to Len do begin
      //Пропускаем разделители.
      if S[i] in D then Continue;
      //Отслеживаем начало слова.
      if (i = 1) or (S[i - 1] in D) then Pos1 := i;
      //Отслеживаем конец слова.
      if (i = Len) or (S[i + 1] in D) then begin
        //Добавляем слово в массив.
        SWord := AnsiUpperCase( Copy(S, Pos1, i - Pos1 + 1) );
        AddToVault( Vault, SWord );
      end;
    end;
 
    Writeln('Перечень слов которые присутствуют по одному разу:');
    for i := 0 to Vault.Len - 1 do
      if Vault.Arr[i].Cnt = 1 then
        Writeln( Vault.Arr[i].SWord )
    ;
    //Удаляем из памяти массив слов.
    Finalize(Vault.Arr);
    Vault.Len := 0;
 
    Writeln('Повторить - Enter. Выход - любой символ + Enter.');
    Readln(S);
  until S <> '';
end.

uses
  SysUtils,Crt32;
 
var s:string;
    c:char;
begin
s:='';
repeat
c:=readkey;
if c in ['A'..'Z','a'..'z'] then
 begin
  write(c);
  s:=s+c;
 end;
if c=#13 then writeln;
until c=#13;
writeln(s);
readln;
end.