Как отобразить габаритный рисунок?

unit TestRgn1;
 
interface
 
uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
  private
    { Private declarations }
    hr:hrgn;
  public
    { Public declarations }
    procedure WMNCHitTest(var M:TWMNCHitTest);message wm_NCHitTest;
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.DFM}
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  hr:=0;
end;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  ho, vo, r1: integer;
begin
  if hr <> 0 then
    exit;
  ho := (Width  - ClientWidth ) div 2;
  vo :=  Height - ClientHeight - ho;
  // Создать регион по размеру ClentArea
  hr := CreateRectRgn(ho, vo, ho + ClientWidth , vo + ClientHeight);
  // Создать регион на 4 пикселя меньше, чем ClientArea
  r1 := CreateRectRgn(ho + 4, vo + 4, ho + ClientWidth  - 4, vo + ClientHeight - 4);
  // Объединить регионы так, чтобы осталась только рамка
  CombineRgn(hr, hr, r1, rgn_xor);
  // Удалить второй регион
  DeleteObject(r1);
  // Создать эллипсовидный регион по размерам клиентской области
  r1 := CreateEllipticRgn(ho, vo, ho + ClientWidth , vo + ClientHeight);
  // Объеденить с уже существующим регионом
  CombineRgn(hr, hr, r1, rgn_or);
  // Удалить эллипсовидный регион
  DeleteObject(r1);
  // Установить регион на форму
  SetWindowRgn(handle, hr, true);
end;
 
procedure TForm1.Button2Click(Sender: TObject);
begin
  if hr = 0 then
    exit;
  // Удалить регион с формы
  SetWindowRgn(handle, 0, true);
  // Удалить сам регион
  DeleteObject(hr);
  hr := 0;
end;
 
procedure TForm1. WMNCHitTest(var M: TWMNCHitTest);
begin
  inherited;
  if M.Result = htClient then
    M.Result := htCaption;
end;
 
end.