Не могу присвоить OnClick для динамического объекта

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
 
  TOnTestEvent = procedure(Sender: TObject; AValue: Integer) of Object;
  TTestClass = class
    private
      FValue: Integer;
      FOnTestEvent: TOnTestEvent;
    public
      constructor Create;
      destructor Destroy; override;
 
      procedure AddValue(AValue: Integer);
 
      property OnTestEvent: TOnTestEvent read FOnTestEvent write FOnTestEvent;
  end;
 
  TForm1 = class(TForm)
    Button1: TButton;
    procedure FormCreate(Sender: TObject);
    procedure Button1Click(Sender: TObject);
    procedure FormDestroy(Sender: TObject);
  private
    FTest: TTestClass;
 
    procedure OnTestEvent(Sender: TObject; AValue: Integer);
  public
    { Public-Deklarationen }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
constructor TTestClass.Create;
begin
  FValue := 0;
end;
 
destructor TTestClass.Destroy;
begin
  inherited;
end;
 
procedure TTestClass.AddValue(AValue: Integer);
begin
  if (AValue < 0) and Assigned(FOnTestEvent) then
    FOnTestEvent(Self, AValue);
end;
 
procedure TForm1.Button1Click(Sender: TObject);
begin
  FTest.AddValue(-5);
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  FTest := TTestClass.Create;
  FTest.OnTestEvent := OnTestEvent;
end;
 
procedure TForm1.FormDestroy(Sender: TObject);
begin
  FreeAndNil(FTest);
end;
 
procedure TForm1.OnTestEvent(Sender: TObject; AValue: Integer);
begin
  ShowMessage(IntToStr(AValue));
end;
 
end.