Выполнение задачи в нескольких потоках, основные принципы, синхронизация

unit UnitIntf;
 
interface
 
uses
  Vcl.StdCtrls, Vcl.ExtCtrls;
 
type
  // рабочий интерфейс
  IControl = interface
    procedure SetValue(const Value: string);
  end;
 
  // контейнер - элемент списка
  TContainer = class(TObject,IControl)
  private
    FControl: IControl;
    function GetControl: IControl;
  public
    constructor Create(Control: IControl);
    // можно имплементировать поддержку интерфейса только
    // одним свойством класса, а не всем классом
    property Control: IControl read GetControl implements IControl;
  end;
 
  TIEdit = class(TEdit,IControl)
  public
    procedure SetValue(const Value: string);
  end;
 
  TILabel = class(TLabel,IControl)
  public
    procedure SetValue(const Value: string);
  end;
 
  TIPanel = class(TPanel,IControl)
  public
    procedure SetValue(const Value: string);
  end;
 
  TIButton = class(TButton,IControl)
  public
    procedure SetValue(const Value: string);
  end;
 
implementation
 
{ TContainer }
 
constructor TContainer.Create(Control: IControl);
begin
  FControl:= Control;
end;
 
function TContainer.GetControl: IControl;
begin
  Result:= FControl;
end;
 
{ TIEdit }
 
procedure TIEdit.SetValue(const Value: string);
begin
  Self.Text:= Value;
end;
 
{ TILabel }
 
procedure TILabel.SetValue(const Value: string);
begin
  Self.Caption:= Value;
end;
 
{ TIPanel }
 
procedure TIPanel.SetValue(const Value: string);
begin
  Self.Caption:= Value;
end;
 
{ TIButton }
 
procedure TIButton.SetValue(const Value: string);
begin
  Self.Caption:= Value;
end;
 
end.

unit UnitMain;
 
interface
 
uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, System.Generics.Collections,
  Vcl.StdCtrls, UnitIntf, Vcl.ExtCtrls;
 
type
  // переопределение наследования
  // (подействует только в Ран-Тайм, что нам и нужно)
  TEdit = class(TIEdit);
  TLabel = class(TILabel);
  TButton = class(TIButton);
  TPanel = class(TIPanel);
 
  TfrmMain = class(TForm)
    Button1: TButton;
    Edit1: TEdit;
    Edit2: TEdit;
    Label1: TLabel;
    Label2: TLabel;
    Button2: TButton;
    Button3: TButton;
    Panel1: TPanel;
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure Button1Click(Sender: TObject);
  private
    procedure ItemNotify(Sender: TObject; const Item: TContainer;
                         Action: TCollectionNotification);
  end;
 
var
  frmMain: TfrmMain;
  myList: TList<TContainer>;
 
implementation
 
{$R *.dfm}
 
procedure TfrmMain.Button1Click(Sender: TObject);
var
  Item: TContainer;
begin
  // проход по списку
  for Item in myList do Item.Control.SetValue('TEST');
end;
 
procedure TfrmMain.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  myList.Free;
end;
 
procedure TfrmMain.FormCreate(Sender: TObject);
begin
  myList:= TList<TContainer>.Create;
  myList.OnNotify:= ItemNotify;
  // формируем список компонентов
  myList.Add(TContainer.Create(Edit1));
  myList.Add(TContainer.Create(Edit2));
  myList.Add(TContainer.Create(Label1));
  myList.Add(TContainer.Create(Label2));
  myList.Add(TContainer.Create(Button2));
  myList.Add(TContainer.Create(Button3));
  myList.Add(TContainer.Create(Panel1));
end;
 
procedure TfrmMain.ItemNotify(Sender: TObject; const Item: TContainer;
  Action: TCollectionNotification);
begin
  // уничтожение элемента списка (не компонента!)
  if Action <> cnAdded then Item.Free;
end;
 
end.