Класс вектор. Комментарии к коду.

unit Unit2;
interface
uses
  SysUtils;
type
  TVector = class          // имя класса
    private
      FItems: array of Double; // поля класса-динамический массив
      function GetItem(Index: Integer): Double; // метод класса- с парматром
 
 
    public
      constructor Create(AItems: array of Double); //  конструктор 
      destructor Destroy; override;  //Зачем у деструктора  override; ?
      property Items[Index: Integer]: Double read GetItem; default; // В обычных свойствах  функция для чтения без параметра, но здесь массив свойств . Поэтому она с параметром. А вот зачем default ?
  end;
implementation
{ TVector }
constructor TVector.Create(AItems: array of Double); // Реализация конструктора
var
  i: Integer;
begin
  SetLength(FItems, Length(AItems)); // создание динамического массива FItems длинной AItems
  for i := Low(AItems) to High(AItems) do  // цикл от наименьшего индекса динамического массива до наибольшего
    FItems[i] := AItems[i]; //  Эту строчку я вообще не понимаю
end;
destructor TVector.Destroy; // реализация деструктора
begin
  SetLength(FItems, 0); //  Уничтожение динамического массива
  inherited; // унаследованый деструктор
end;
function TVector.GetItem(Index: Integer): Double; // Реализация метода GetItem
begin
  if Index in [Low(FItems)..High(FItems)] then  // если Index  лежит в интервале  от наименьшего до наибольшого индекса массива 
    Result := FItems[Index] // То что ? Строка тоже не понятна
  else  иначе
    raise Exception.Create('Index is not Valid!'); //  Вообще не понятно
end;
end.

unit UVector;
 
interface
 
type
  TArrItems = array of Extended;
 
  TVector = class(TObject)
  private
    FItems : TArrItems;
  protected
    function GetItem(aIndex : Integer) : Extended; virtual;
    procedure SetItem(aIndex : Integer; const aValue : Extended); virtual;
    function GetArrItems : TArrItems; virtual;
    procedure SetArrItems(const aArrItems : TArrItems); virtual;
    function GetItemsCount : Integer;
    procedure SetItemsCount(const aCount : Integer);
    property ArrItems : TArrItems read GetArrItems write SetArrItems;
  public
    constructor Create; overload;
    constructor Create(const aCount : Integer); overload;
    constructor Create(const aArrItems : TArrItems); overload;
    destructor Destroy; override;
    property Items[aIndex : Integer] : Extended read GetItem write SetItem; default;
    property ItemsCount : Integer read GetItemsCount write SetItemsCount;
 
    function ScalarMultiply(const aVector : TVector) : Extended; virtual;
    function ToString : String; virtual;
  end;
 
implementation
 
uses SysUtils;
 
{ TVector }
 
constructor TVector.Create;
begin
  inherited;
  FItems := nil;
end;
 
constructor TVector.Create(const aCount: Integer);
begin
  inherited Create;
  ItemsCount := aCount;
end;
 
constructor TVector.Create(const aArrItems : TArrItems);
begin
  inherited Create;
  FItems := aArrItems;
end;
 
destructor TVector.Destroy;
begin
  Finalize(FItems);
  inherited;
end;
 
function TVector.GetArrItems: TArrItems;
begin
  Result := FItems;
end;
 
function TVector.GetItem(aIndex: Integer): Extended;
const
  SelfName = 'TVector.GetItem()';
begin
  if ( aIndex < 0 ) and ( aIndex > High(FItems) ) then
    raise ERangeError.Create(SelfName + '. Ошибка! Недопустимый индекс.')
  ;
  Result := FItems[aIndex];
end;
 
function TVector.GetItemsCount: Integer;
begin
  Result := Length(FItems);
end;
 
procedure TVector.SetArrItems(const aArrItems: TArrItems);
begin
  FItems := aArrItems;
end;
 
procedure TVector.SetItem(aIndex: Integer; const aValue: Extended);
const
  SelfName = 'TVector.SetItem()';
begin
  if ( aIndex < 0 ) and ( aIndex > High(FItems) ) then
    raise ERangeError.Create(SelfName + '. Ошибка! Недопустимый индекс.')
  ;
  FItems[aIndex] := aValue;
end;
 
procedure TVector.SetItemsCount(const aCount: Integer);
const
  SelfName = 'TVector.SetItemsCount()';
begin
  if aCount < 0 then
    raise Exception.Create(SelfName + '. Ошибка! Вектор не может иметь отрицательную размерность.')
  ;
  SetLength(FItems, aCount);
end;
 
function TVector.ToString: String;
var
  i, h : Integer;
begin
  Result := '';
  h := High(FItems);
  for i := 0 to h do begin
    if Result <> '' then Result := Result + '; ';
    Result := Result + FloatToStr(FItems[i]);
  end;
  Result := '(' + Result + ')';
end;
 
function TVector.ScalarMultiply(const aVector: TVector): Extended;
const
  SelfName = 'TVector.ScalarMultiply()';
var
  i, h : Integer;
  ArrItems : TArrItems;
begin
  if (aVector = nil) then
    raise Exception.Create(SelfName + '. Ошибка! aVector = nil.')
  ;
  if ItemsCount <> aVector.ItemsCount then
    raise Exception.Create(SelfName + '. Ошибка! Размерности векторов различны.')
  ;
  ArrItems := aVector.ArrItems;
  h := High(ArrItems);
  Result := 0;
  for i := 0 to h do
    Result := Result + FItems[i] * ArrItems[i]
  ;
end;
 
end.

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
uses
  UVector;
 
procedure TForm1.Button1Click(Sender: TObject);
const
  M = 4;
var
  V1, V2 : TVector;
  i : Integer;
  ScalarMulti : Extended;
begin
  Memo1.Clear;
 
  V1 := TVector.Create(M);
  V2 := TVector.Create(M);
  for i := 0 to V1.ItemsCount - 1 do begin
    V1.Items[i] := i;
    V2.Items[i] := (M - 1) - i;
  end;
 
  Memo1.Lines.Add('Вектора:');
  Memo1.Lines.Add('V1 = ' + V1.ToString);
  Memo1.Lines.Add('V2 = ' + V2.ToString);
  Memo1.Lines.Add('');
 
  ScalarMulti := V1.ScalarMultiply(V2);
  Memo1.Lines.Add('Скалярное произведение векторов равно: ' + FloatToStr(ScalarMulti));
 
  FreeAndNil(V1);
  FreeAndNil(V2);
end;
 
end.

  for i := 0 to V1.ItemsCount - 1 do begin
    V1.Items[i] := i;
    V2.Items[i] := (M - 1) - i;
  end;

  for i := 0 to V1.ItemsCount - 1 do begin
    V1[i] := i;
    V2[i] := (M - 1) - i;
  end;

program Property_Array;
 
{$APPTYPE CONSOLE}
 
uses
  SysUtils;
 
{Пределы индексирования векторов}
const LOW = 0;
const LIMIT = 9;
 
{Определение типа элементов вектора}
Type VectorElements = array [LOW..LIMIT] of real;
 
{Определения класса "Вектор"}
type
  TVectorClass = class
  private
    {Место хранения элементов первого вектора}
    Mass1: VectorElements;
    {Место хранения элементов второго вектора}
    Mass2: VectorElements;
    {Место хранения элементов вектора-рузультата}
    ResultMass: VectorElements;
 
  protected
    {Объявление функции чтения элемента массива Mass1}
    function GetValue1(Index: integer): real;
    {Объявление процедуры записи элемента в массив Mass1}
    procedure SetValue1(Index: integer; Value: real);
    {Объявление функции чтения элемента массива Mass2}
    function GetValue2(Index: integer): real;
    {Объявление процедуры записи элемента в массив Mass2}
    procedure SetValue2(Index: integer; Value: real);
    {Объявление функции чтения элемента массива Result}
    function GetValue3(Index: integer): real;
    {Объявление процедуры записи элемента в массив Result}
    procedure SetValue3(Index: integer; Value: real);
 
  public
 
    {Длинна вектора результата}
    VectorLong: integer;
 
    {Результат умножения двух векторов}
    Multitude: real;
 
    {Процедура чтения вектора класса}
    procedure VectorRead(EnteringVector: string; var VectorMass: VectorElements;
    var VectorSize: integer);
 
    {Объявление конструктор создания объекта класса TVectorClass}
    constructor Create(EnteringVector1, EnteringVector2: string);
 
    {Объявление деструктора создания объекта класса TVectorClass}
    destructor Destroy;
 
    {Объявление свойства типа массив первого вектора класса TVectorClass}
    property Vector1[Index: integer]: real read GetValue1 write SetValue1;
 
    {Объявление свойства типа массив второго вектора класса TVectorClass}
    property Vector2[Index: integer]: real read GetValue2 write SetValue2;
 
    {Объявление свойства типа массив вектора-результата класса TVectorClass}
    property ResultVector[Index: integer]: real read GetValue3 write SetValue3;
 
    {Основные арифметические функции над векторами}
 
    {Объявление функции сложения двух векторов}
    procedure Add;
    {Объявление функции вычитания второго вектора из первого}
    procedure Subtraction;
    {Объявление функции скалярного умножения двух векторов}
    procedure ScaliarMultitude;
 
  end;
 
{Процедура чтения элемента из свойства-массива первого вектора}
function TVectorClass.GetValue1(Index: integer): real;
begin
  Result := Mass1[Index]
end;
 
{Процедура записи в элемен свойства-массива первого вектора}
procedure TVectorClass.SetValue1(Index: integer; Value: real);
begin
  Mass1[Index] := Value
end;
 
{Процедура чтения элемента из свойства-массива второго вектора}
function TVectorClass.GetValue2(Index: integer): real;
begin
  Result := Mass2[Index]
end;
 
{Процедура записи в элемен свойства-массива второго вектора}
procedure TVectorClass.SetValue2(Index: integer; Value: real);
begin
  Mass2[Index] := Value
end;
 
{Процедура чтения элемента из свойства-массива вектора-результата}
function TVectorClass.GetValue3(Index: integer): real;
begin
  Result := ResultMass[Index]
end;
 
{Процедура записи в элемен свойства-массива вектора-результата}
procedure TVectorClass.SetValue3(Index: integer; Value: real);
begin
  ResultMass[Index] := Value
end;
 
procedure TVectorClass.VectorRead(EnteringVector: string; var VectorMass:
VectorElements; var VectorSize: integer);
var
  {Флаг ввода числовых данных из буффера ввода}
  Entering: boolean;
 
  {Счётчик эллементов буфера ввода}
  Caunter1: integer;
 
  {Буфер итогового элемента вектора}
  Number: string;
 
begin
 
  {Наследование всех функций конструктора Create класса TObject}
  inherited Create;
 
  if EnteringVector <> '' then
  begin
    {Инициализация переменной размера вектора}
    VectorSize := LOW - 1;
    {Инициализация буфера итогового элемента вектора}
    Number := '';
    {Инициализация флага считывания значащих цифр и знаков}
    Entering := FALSE;
 
    {Цикл считывания данных из буффера ввода в вектор класса TVectorClass}
    for Caunter1 := 1 to Length(EnteringVector) do
    begin
      {Добавление знака к следующему элементу вектора}
      if (EnteringVector[Caunter1] = '-') or (EnteringVector[Caunter1] = '+')
      and (Entering = FALSE) then
      begin
        Number := EnteringVector[Caunter1]
      end;
 
      {Проверка на наличие значащей части элемента вектора}
      if (EnteringVector[Caunter1] >= '0') and (EnteringVector[Caunter1] <= '9')
      or ((EnteringVector[Caunter1] = '.') and (Entering = TRUE)) then
      begin
        {Накопление в буфере элемента значащих цифр и знаков}
        Number := Number + EnteringVector[Caunter1];
        {Начало считывания значащих знаков и цифр из буффера ввода}
        Entering := TRUE
      end
      else
      begin
        {Конец значащей последовательности цифр и знаков ввода}
        if Entering = TRUE then
        begin
          {Увеличение размера вектора на единицу}
          VectorSize := VectorSize + 1;
          {Сохранение полученной значащей части в эллемент вектора в массив Mass}
          VectorMass[VectorSize] := StrToFloat(Number);
 
          {Обнуление буфера итогового элемента массива}
          Number := '';
          {Флаг указывает на конец считывания значащих цифр и знаков}
          Entering := FALSE;
        end
      end
    end;
    {Последним символом была значащая цифра или знак ввода}
    if Entering = TRUE then
    begin
      {Увеличение размера вектора на единицу}
      VectorSize := VectorSize + 1;
 
      {Проверка на последние ненужные символы}
      if (Number <> '-') and (Number <> '+') then
      begin
        {Сохранение полученной значащей части в эллемент вектора в массив Mass}
        VectorMass[VectorSize] := StrToFloat(Number)
      end
    end
  end
end;
 
{Описание деструктора объекта (вектора) класса TVectorClass}
destructor TVectorClass.Destroy;
begin
  {Наследование всех функций деструктора Destroy класса TObject}
  inherited Destroy;
end;
 
{Описание конструктора вектора класса TVectorClass вместе с его инициализацией}
constructor TVectorClass.Create(EnteringVector1, EnteringVector2: string);
var
  {Переменные размеров первого и второго векторов}
  Limit1 {Первый вектор}, Limit2 {Второй вектор}: integer;
 
begin
  {Наследование всех функций конструктора Create класса TObject}
  inherited Create;
 
  {Инициализация векторов-аргументов}
  VectorRead(EnteringVector1, Mass1, Limit1);
  VectorRead(EnteringVector2, Mass2, Limit2);
 
  {Выбор оптимального размера вектора-рузультата арифметических дейсвтий,
  изходя из размеров векторов-аргументов}
  if Limit1 >= Limit2 then
  begin
    VectorLong := Limit1
  end
  else
  begin
    VectorLong := Limit2
  end
end;
 
 
{Описание функции сложения двух векторов}
procedure TVectorClass.Add;
var
  {Счётчик цикла попарного сложения элементов двух векторов}
  Caunter1: integer;
begin
  {Цикл попарного сложения элементов двух векторов}
  for Caunter1 := LOW to VectorLong do
  begin
    ResultMass[Caunter1] := Mass1[Caunter1] + Mass2[Caunter1]
  end
end;
 
{Описание функции вычитания второго вектора из первого}
procedure TVectorClass.Subtraction;
var
  {Счётчик цикла попарного вычитания элементов вторго вектора из первого}
  Caunter1: integer;
begin
  {Цикл попарного вычитания элементов второго вектора из первого}
  for Caunter1 := LOW to VectorLong do
  begin
    ResultMass[Caunter1] := Mass1[Caunter1] - Mass2[Caunter1]
  end
end;
 
{Описание функции скалярного умножения двух векторов}
procedure TVectorClass.ScaliarMultitude;
var
  {Счётчик цикла скалярного умножения двух векторов}
  Caunter1: integer;
begin
  {Инициализа результата функции}
  Multitude := 0;
  {Цикл скалярного умножения двух векторов}
  for Caunter1 := LOW to VectorLong do
  begin
    Multitude := Multitude + (Mass1[Caunter1] * Mass2[Caunter1])
  end
end;
 
 
 
var
  {Объявление объектов класса TVectorClass}
  VectorsMath: TVectorClass;
 
  {Создание буфферов ввода эллементов первого и второго массива}
  ParametrsString1, ParametrsString2: string;
 
  {Переменная результата скалярного умножения векторов}
  MultitudeResult: real;
 
  {Счётчик цикла вывод на экран результирующего вектора}
  Caunter1: integer;
 
  {Объявление буферной переменной для считывания команд пользователя}
  Value, ExitValue: char;
 
begin
  { TODO -oUser -cConsole Main : Insert code here }
 
  {Принудительно введения разделителя целой и дробной части в действительных
  числах}
  DecimalSeparator := '.';
 
  {Циклическое выполнение арифметических операций над двумя векторами}
  repeat
    {Приглашение к вводу элементов первого вектора}
    write('Pleas enter first vector: ');
    {Чтение строки ввода с элементами первого вектора}
    readln(ParametrsString1);
 
    {Пустая строка}
    writeln;
 
    {Приглашение к вводу элементов второго вектора}
    write('Pleas enter seckond vector: ');
    {Чтение строки ввода с элементами второго вектора}
    readln(ParametrsString2);
 
    {Создание объекта типа TVectorClass}
    VectorsMath := TVectorClass.Create(ParametrsString1, ParametrsString2);
 
    {Обнулени буфера ввода элементов первого вектора}
    ParametrsString1 := '';
 
    {Обнулени буфера ввода элементов второго вектора}
    ParametrsString2 := '';
 
    {Пустая строка}
    writeln;
 
    {Функции выполнения простых арифметических дейстий над векторами}
 
    {Функция выполнения сложения двух векторорв}
    VectorsMath.Add;
    {Вывод результатов сложения двух векторов на экран}
    write('result of adding First Vector + Seckond Vector : [');
    for Caunter1 := LOW to VectorsMath.VectorLong - 1 do
    begin
      write(VectorsMath.ResultVector[Caunter1]:3:3, ' ,')
    end;
    writeln(VectorsMath.ResultVector[VectorsMath.VectorLong]:3:3, ']');
 
    {Пустая строка}
    writeln;
 
    {Функция выполнения вычитания второго вектора из первого}
    VectorsMath.Subtraction;
    {Вывод результатов вычитания двух векторов на экран}
    write('result of subtraction (First Vector - Seckond Vector): [');
    for Caunter1 := LOW to VectorsMath.VectorLong - 1 do
    begin
      write(VectorsMath.ResultVector[Caunter1]:3:3, ' ,')
    end;
    writeln(VectorsMath.ResultVector[VectorsMath.VectorLong]:3:3, ']');
    {Пустая строка}
    writeln;
 
    {Функция скалярного умножения двух векторорв}
    VectorsMath.ScaliarMultitude;
    {Вывод результата скалярного умножения двух векторов на экран}
    writeln('result vector of vector''s sclaliar multitude: ',
    VectorsMath.Multitude:3:3);
 
    {Вопрос на продолжение аналогичных действий}
    writeln;
    writeln('Repeate or End: Y/N');
    writeln;
    {Чтение ответа пользователя}
    readLn(Value);
    writeln;
    {Инициализация признака выход из цикла}
    ExitValue := 'N';
    {Подтверждение отрицательного ответа ответа}
    if (Value = 'N') or (Value = 'n') then
    begin
      writeln('Are you shuer?: Y/N');
      writeln;
      readln(ExitValue)
    end;
    writeln
 
  until (ExitValue = 'Y') or (ExitValue = 'y');
 
  {Уничтожение объекта класса TVectorClass}
  VectorsMath.Destroy;
 
end.

unit UVector;
 
interface
 
type
  TArrNums = array of Extended;
 
  //Класс: вектор.
  TVector = class(TObject)
  private
    FItems : TArrNums;
  protected
    function GetItem(aIndex : Integer) : Extended; virtual;
    procedure SetItem(aIndex : Integer; const aValue : Extended); virtual;
    function GetArrItems : TArrNums; virtual;
    procedure SetArrItems(const aArrItems : TArrNums); virtual;
    function GetCount : Integer; virtual;
    procedure SetCount(const aCount : Integer); virtual;
    function ToString : String; virtual;
 
    property ArrItems : TArrNums read GetArrItems write SetArrItems;
  public
    constructor Create; overload;
    constructor Create(const aCount : Integer); overload;
    constructor Create(const aArrItems : TArrNums); overload;
    constructor Create(const aArrItems : array of Extended); overload;
    destructor Destroy; override;
 
    property Items[aIndex : Integer] : Extended read GetItem write SetItem; default;
    property Count : Integer read GetCount write SetCount;
    property AsString : String read ToString;
 
    function ScalarMultiply(const aVector : TVector) : Extended; virtual;
    function Plus(const aVector : TVector) : TVector; virtual;
    function Minus(const aVector : TVector) : TVector; virtual;
  end;
 
  TArrVectors = array of TVector;
 
  //Класс: коллекция векторов.
  TVectors = class(TObject)
  private
    FItems : TArrVectors;
  protected
    function GetItem(aIndex : Integer) : TVector; virtual;
    procedure SetItem(aIndex : Integer; const aVector : TVector); virtual;
    function GetArrItems : TArrVectors; virtual;
    procedure SetArrItems(const aArrItems : TArrVectors); virtual;
    function GetCount : Integer; virtual;
 
    property ArrItems : TArrVectors read GetArrItems write SetArrItems;
  public
    constructor Create; overload;
    destructor Destroy; override;
 
    property Items[aIndex : Integer] : TVector read GetItem write SetItem; default;
    property Count : Integer read GetCount;
 
    procedure Insert(aValue : TVector; const aIndex : Integer); virtual;
    function Add(aValue : TVector) : Integer; virtual;
    function Remove(const aIndex : Integer) : TVector; virtual;
  end;
 
implementation
 
uses SysUtils;
 
{ TVector }
 
constructor TVector.Create;
begin
  inherited;
  FItems := nil;
end;
 
constructor TVector.Create(const aCount: Integer);
const
  selfName = 'TVector.Create()';
begin
  if aCount < 0 then
    raise Exception.Create(SelfName + '. Ошибка! Вектор не может иметь отрицательную размерность.')
  ;
  inherited Create;
  SetLength(FItems, aCount);
end;
 
constructor TVector.Create(const aArrItems : TArrNums);
begin
  inherited Create;
  FItems := aArrItems;
end;
 
constructor TVector.Create(const aArrItems: array of Extended);
var
  i, Len : Integer;
begin
  Len := Length(aArrItems);
  SetLength(FItems, Len);
  for i := 0 to Len - 1 do FItems[i] := aArrItems[i];
end;
 
destructor TVector.Destroy;
begin
  Finalize(FItems);
  inherited;
end;
 
function TVector.GetArrItems: TArrNums;
begin
  Result := FItems;
end;
 
function TVector.GetItem(aIndex: Integer): Extended;
const
  SelfName = 'TVector.GetItem()';
begin
  if ( aIndex < 0 ) and ( aIndex > High(FItems) ) then
    raise Exception.Create(SelfName + '. Ошибка! Недопустимый индекс.')
  ;
  Result := FItems[aIndex];
end;
 
function TVector.GetCount: Integer;
begin
  Result := Length(FItems);
end;
 
procedure TVector.SetArrItems(const aArrItems: TArrNums);
begin
  FItems := aArrItems;
end;
 
procedure TVector.SetItem(aIndex: Integer; const aValue: Extended);
const
  SelfName = 'TVector.SetItem()';
begin
  if ( aIndex < 0 ) and ( aIndex > High(FItems) ) then
    raise Exception.Create(SelfName + '. Ошибка! Недопустимый индекс.')
  ;
  FItems[aIndex] := aValue;
end;
 
procedure TVector.SetCount(const aCount: Integer);
const
  SelfName = 'TVector.SetCount()';
begin
  if aCount < 0 then
    raise Exception.Create(SelfName + '. Ошибка! Вектор не может иметь отрицательную размерность.')
  ;
  SetLength(FItems, aCount);
end;
 
function TVector.ToString: String;
var
  i, Len : Integer;
begin
  Result := '';
  Len := Count;
  for i := 0 to Len - 1 do begin
    if Result <> '' then Result := Result + '; ';
    Result := Result + FloatToStr(Items[i]);
  end;
  Result := '(' + Result + ')';
end;
 
function TVector.ScalarMultiply(const aVector: TVector): Extended;
const
  SelfName = 'TVector.ScalarMultiply()';
var
  i, Len : Integer;
begin
  if (aVector = nil) then
    raise Exception.Create(SelfName + '. Ошибка! aVector = nil.')
  ;
  if Count <> aVector.Count then
    raise Exception.Create(SelfName + '. Ошибка! Размерности векторов различны.')
  ;
  Len := Count;
  Result := 0;
  for i := 0 to Len - 1 do
    Result := Result + Items[i] * aVector.Items[i]
  ;
end;
 
function TVector.Minus(const aVector: TVector): TVector;
const
  SelfName = 'TVector.Minus()';
var
  i, Len : Integer;
begin
  if (aVector = nil) then
    raise Exception.Create(SelfName + '. Ошибка! aVector = nil.')
  ;
  if Count <> aVector.Count then
    raise Exception.Create(SelfName + '. Ошибка! Размерности векторов различны.')
  ;
  Len := Count;
  Result := TVector.Create(Len);
  for i := 0 to Len - 1 do
    Result.Items[i] := Items[i] - aVector.Items[i]
  ;
end;
 
function TVector.Plus(const aVector: TVector): TVector;
const
  SelfName = 'TVector.Plus()';
var
  i, Len : Integer;
begin
  if (aVector = nil) then
    raise Exception.Create(SelfName + '. Ошибка! aVector = nil.')
  ;
  if Count <> aVector.Count then
    raise Exception.Create(SelfName + '. Ошибка! Размерности векторов различны.')
  ;
  Len := Count;
  Result := TVector.Create(Len);
  for i := 0 to Len - 1 do
    Result.Items[i] := Items[i] + aVector.Items[i]
  ;
end;
 
{ TVectors }
 
constructor TVectors.Create;
begin
  inherited;
  FItems := nil;
end;
 
destructor TVectors.Destroy;
begin
  Finalize(FItems);
  inherited;
end;
 
function TVectors.GetArrItems: TArrVectors;
begin
  Result := FItems;
end;
 
procedure TVectors.SetArrItems(const aArrItems: TArrVectors);
begin
  FItems := aArrItems;
end;
 
function TVectors.GetItem(aIndex: Integer): TVector;
const
  SelfName = 'TVectors.GetItem()';
begin
  if ( aIndex < 0 ) and ( aIndex > High(FItems) ) then
    raise Exception.Create(SelfName + '. Ошибка! Недопустимый индекс.')
  ;
  Result := FItems[aIndex];
end;
 
procedure TVectors.SetItem(aIndex: Integer; const aVector: TVector);
const
  SelfName = 'TVectors.SetItem()';
begin
  if ( aIndex < 0 ) and ( aIndex > High(FItems) ) then
    raise Exception.Create(SelfName + '. Ошибка! Недопустимый индекс.')
  ;
  FItems[aIndex] := aVector;
end;
 
function TVectors.GetCount: Integer;
begin
  Result := Length(FItems);
end;
 
procedure TVectors.Insert(aValue: TVector; const aIndex: Integer);
const
  SelfName = 'TVectors.Remove()';
var
  i, Len : Integer;
begin
  Len := Length(FItems);
  if (aIndex < 0) or (aIndex > Len ) then
    raise Exception.Create(SelfName + '. Ошибка! Неверный индекс.')
  ;
  SetLength(FItems, Len + 1);
  if aIndex < Len then begin
    for i := Len downto aIndex + 1 do FItems[i] := FItems[i - 1];
  end;
  FItems[aIndex] := aValue;
end;
 
function TVectors.Add(aValue: TVector): Integer;
begin
  Result := Length(FItems);
  Insert(aValue, Result);
end;
 
function TVectors.Remove(const aIndex : Integer): TVector;
const
  SelfName = 'TVectors.Remove()';
var
  i, Len : Integer;
begin
  Len := Length(FItems);
  if (aIndex < 0) or (aIndex >= Len ) then
    raise Exception.Create(SelfName + '. Ошибка! Неверный индекс.')
  ;
  Result := FItems[aIndex];
  for i := aIndex + 1 to Len - 1 do FItems[i - 1] := FItems[i];
  SetLength(FItems, Len - 1);
end;
 
end.

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TForm1 = class(TForm)
    Button1: TButton;
    Button2: TButton;
    Memo1: TMemo;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
uses
  UVector;
 
//Работа с классом TVector.
procedure TForm1.Button1Click(Sender: TObject);
const
  M = 4;
var
  V1, V2, V3, V4, VRes : TVector;
  ArrItems : TArrNums;
  i : Integer;
  ScalarMulti : Extended;
begin
  Memo1.Clear;
  Memo1.Lines.Add('Работа с классом: TVector.');
  Memo1.Lines.Add('');
 
  VRes := nil;
 
  V1 := TVector.Create;
  V1.Count := M;
  for i := 0 to V1.Count - 1 do V1[i] := i;
 
  V2 := TVector.Create(M);
  for i := 0 to V2.Count - 1 do V2[i] := i + 1;
 
  SetLength(ArrItems, M);
  for i := 0 to M - 1 do ArrItems[i] := i + 2;
  V3 := TVector.Create(ArrItems);
  ArrItems := nil;
 
  V4 := TVector.Create([3, 4, 5, 6]);
 
  Memo1.Lines.Add('Созданы вектора:');
  Memo1.Lines.Add('V1 = ' + V1.AsString);
  Memo1.Lines.Add('V2 = ' + V2.AsString);
  Memo1.Lines.Add('V3 = ' + V3.AsString);
  Memo1.Lines.Add('V4 = ' + V4.AsString);
  Memo1.Lines.Add('');
 
  ScalarMulti := V1.ScalarMultiply(V2);
  Memo1.Lines.Add('Скалярное произведение векторов V1 и V2 равно: ' + FloatToStr(ScalarMulti));
  Memo1.Lines.Add('');
 
  FreeAndNil(VRes);
  VRes := V4.Minus(V3);
  Memo1.Lines.Add('Вектор, равный разности векторов V4 и V3: ' + VRes.AsString);
  Memo1.Lines.Add('');
 
  FreeAndNil(VRes);
  VRes := V1.Plus(V2);
  Memo1.Lines.Add('Вектор, равный сумме векторов V1 и V2: ' + VRes.AsString);
  Memo1.Lines.Add('');
 
  FreeAndNil(V1);
  FreeAndNil(V2);
  FreeAndNil(V3);
  FreeAndNil(V4);
  FreeAndNil(VRes);
 
  Memo1.Lines.Add('Вектора удалены из памяти.');
end;
 
//Работа с классами: TVector и TVectors.
procedure TForm1.Button2Click(Sender: TObject);
const
  M = 4;
var
  Vecs : TVectors;
  ArrItems : TArrNums;
  i, Index : Integer;
  ScalarMulti : Extended;
begin
  Memo1.Clear;
  Memo1.Lines.Add('Работа с классами: TVector и TVectors.');
  Memo1.Lines.Add('');
 
  Vecs := TVectors.Create;
 
  Index := Vecs.Add( TVector.Create );
  Vecs[Index].Count := M;
  for i := 0 to Vecs[Index].Count - 1 do Vecs[Index][i] := i;
 
  Index := Vecs.Add( TVector.Create(M) );
  for i := 0 to Vecs[Index].Count - 1 do Vecs[Index][i] := i + 1;
 
  SetLength(ArrItems, M);
  for i := 0 to M - 1 do ArrItems[i] := i + 2;
  Vecs.Add( TVector.Create(ArrItems) );
  ArrItems := nil;
 
  Vecs.Add( TVector.Create([3, 4, 5, 6]) );
 
  Memo1.Lines.Add('Перечень векторов в коллекции:');
  for i := 0 to Vecs.Count - 1 do begin
    Memo1.Lines.Add('V' + IntToStr(i) + ' = ' + Vecs[i].AsString);
  end;
  Memo1.Lines.Add('');
 
  ScalarMulti := Vecs[0].ScalarMultiply(Vecs[1]);
  Memo1.Lines.Add('Скалярное произведение векторов V0 и V1 равно: ' + FloatToStr(ScalarMulti));
  Memo1.Lines.Add('');
 
  Index := Vecs.Add( Vecs[3].Minus(Vecs[2]) );
  Memo1.Lines.Add('Вектор, равный разности векторов V3 и V2: ' + Vecs[Index].AsString);
  Memo1.Lines.Add('');
 
  Index := Vecs.Add( Vecs[0].Plus(Vecs[1]) );
  Memo1.Lines.Add('Вектор, равный сумме векторов V0 и V1: ' + Vecs[Index].AsString);
  Memo1.Lines.Add('');
 
  Memo1.Lines.Add('Перечень векторов в коллекции:');
  for i := 0 to Vecs.Count - 1 do begin
    Memo1.Lines.Add('V' + IntToStr(i) + ' = ' + Vecs[i].AsString);
  end;
  Memo1.Lines.Add('');
 
  for i := 0 to Vecs.Count - 1 do Vecs[i].Free;
  Memo1.Lines.Add('Вектора удалены из памяти.');
  Vecs.Free;
  Memo1.Lines.Add('Коллекция удалена из памяти.');
end;
 
end.

procedure TVectorClass.VectorRead(...);
... 
begin
 
  {Наследование всех функций конструктора Create класса TObject}
  inherited Create;
...

    {Объявление деструктора создания объекта класса TVectorClass}
    destructor Destroy;

    {Объявление конструктор создания объекта класса TVectorClass}
    constructor Create(EnteringVector1, EnteringVector2: string);

    {Объявление функции сложения двух векторов}
    procedure Add;

{Описание деструктора объекта (вектора) класса TVectorClass}
destructor TVectorClass.Destroy;
begin
  {Наследование всех функций деструктора Destroy класса TObject}
  inherited Destroy;
end;

//Получить скалярное произведение векторов V1 и V2:
ScalarMulti := V1.ScalarMultiply(V2);
 
//Вычесть из вектора V4 вектор V3 - в результате получается новый вектор VRes:
VRes := V4.Minus(V3);
 
//Сложить вектор V1 с вектором V2 - в результате получается новый вектор VRes:
VRes := V1.Plus(V2);

constructor TVector.Create(const aArrItems : TArrNums);
begin
  inherited Create;
  FItems := aArrItems;
end;

  SetLength(ArrItems, M);
  for i := 0 to M - 1 do ArrItems[i] := i + 2;
  V3 := TVector.Create(ArrItems);
  //Вот здесь выполняется страховка - обнуляется внешняя ссылка на внутренние данные
  //вектора V3.
  ArrItems := nil;

constructor TVector.Create(const aArrItems : TArrNums);
var
  Len : Integer;
begin
  inherited Create;
  FItems := nil;
  Len := Length(aArrItems);
  if Len > 0 then FItems := Copy(aArrItems, 0, Len);
end;

type
  TVector = class
    private
      FItems: array of real ;
                   public
      constructor Create(AItems: array of real);
      destructor Destroy; override;
            function VectorMulty(const A:TVector ) :TVector ;
            end;
                  ...
 function TVector.VectorMulty(const A:TVector ) :TVector ;
     var
     i:integer;
   begin
   if High(FItems) <> High(A.FItems) then
    ShowMessage('Îøèáêà. Ðàçìåðíîñòè âåêòîðîâ ðàçëè÷íû.') ;
     for i := 0 to High(FItems) do
     A.FItems[i]: = A.FItems[i]*FItems[i];
     Result:=A; // ошибка тут
   end;

function TVector.VectorMulty(const A:TVector ) :TVector ;
var
  i:integer;
begin
  //При обнаружении несоответствия размерностей, код метода не будет прерван,
  //а пролжится. - Это приведёт, далее по коду, к ошибке чтения из памяти.
  if High(FItems) <> High(A.FItems) then
    ShowMessage('Ошибка. Размерности векторов различны.');
  
  //Код, представленный ниже, отработает. Но он введёт пользователя класса в заблуждение.
  //Параметр "A" в методе объявлен, как константа, поэтому ожидается, что вектор A не подвергнется
  //изменениям. Хотя это с технической точки зрения не так - потому что константой является только
  //ссылка на вектор, но не сами данные вектора, тем не менее, смысл этого метода подразумевает,
  //что параметр изменяться не будет ни в каких качествах.
  for i := 0 to High(FItems) do
    A.FItems[i]: = A.FItems[i]*FItems[i];
  
  //Вот здесь происходит следующее. Новый вектор не создаётся, вместо этого, ссылка
  //на уже существующий вектор, записывается в переменную Result, значение которой
  //затем будет возвращено в вызывающий код. Таким образом получается, что с одним
  //и тем же объектом связаны две переменные - A и Result. Причём, пользователь класса
  //не видит этого. Он, скорее всего, полагает, что метод ему вернул новый вектор.
  //Это в дальнейшем приведёт к ошибкам - если пользователь где-то вызовет деструктор
  //вектора, связанного через Result, то после этого попытка обратиться к данным
  //вектора, связанного через A приведёт к ошибке - т. к. этого вектора уже не существует.
  //Поэтому, надо создавать новый вектор, а не переприсваивать ссылки 
  Result:=A; // ошибка тут
end;

//Векторное произведение.
function TVector.VectorMulty(const A : TVector) : TVector;
var
  i, Len : Integer;
  Arr : array of real;
begin
  if (A = nil) then
    raise Exception.Create(SelfName + '. Ошибка! A = nil.')
  ;
  if Count <> A.Count then
    raise Exception.Create(SelfName + '. Ошибка! Размерности векторов различны.')
  ;
  //Размерность вектора (количество элементов вектора).
  Len := Length(FItems);
  //Создаём массив элементов для нового вектора.
  SetLength(Arr, Len);
  //Создаём новый вектор.
  Result := TVector.Create(Arr);
  //Вычисляем элементы и записываем их в новый вектор.
  for i := 0 to Len - 1 do
    Result.FItems[i] := FItems[i] * A.FItems[i]
  ;
end;

//Напомню - в классе вектора определён такой конструктор:
constructor TVector.Create(const aCount: Integer);
const
  selfName = 'TVector.Create()';
begin
  if aCount < 0 then
    raise Exception.Create(SelfName + '. Ошибка! Вектор не может иметь отрицательную размерность.')
  ;
  inherited Create;
  SetLength(FItems, aCount);
end;
 
//Векторное произведение.
function TVector.VectorMulty(const aVector : TVector) : TVector;
var
  i, Len : Integer;
begin
  if (aVector = nil) then
    raise Exception.Create(SelfName + '. Ошибка! aVector = nil.')
  ;
  if Count <> aVector.Count then
    raise Exception.Create(SelfName + '. Ошибка! Размерности векторов различны.')
  ;
  //Размерность вектора (количество элементов вектора).
  Len := Count;
  //Создаём новый вектор с размерностью, равной Len.
  Result := TVector.Create(Len);
  //Вычисляем элементы и записываем их в новый вектор.
  for i := 0 to Len - 1 do
    Result.Items[i] := Items[i] * aVector.Items[i]
  ;
end;

...
  VRes := V1.VectorMulty(V2);
  Memo1.Lines.Add('Векторное произведение векторов V1 и V2 равно: ' + VRes.AsString);
...

unit UVector;
 
interface
...
type
  TArrNums = array of Extended;
 
  //Класс: вектор.
  TVector = class(TObject)
  private
    FItems : TArrNums;
  protected
  ...
    function ToString : String; virtual;
  ...
  public
  ...
    property AsString : String read ToString;
  ...
  end;
...
implementation
...
function TVector.ToString: String;
var
  i, h : Integer;
begin
  Result := '';
  h := High(FItems);
  for i := 0 to h do begin
    if Result <> '' then Result := Result + '; ';
    Result := Result + FloatToStr(FItems[i]);
  end;
  Result := '(' + Result + ')';
end;
...
end.