Работа с несколькими листами книги Excel в Delphi

var Excel:Variant;
{...}
Excel.ActiveWorkBook.Sheets[1].Cells.Item[2,1]:='anything';

uses
  ComObj;
 
procedure TForm1.Button1Click(Sender: TObject);
const
  xlPasteValues = -4163;
  xlAdd = 2;
var
  exApp, exShs, exRng, exRngTrg : Variant;
  i : Integer;
  Od : TOpenDialog;
begin
  Od := OpenDialog1;
  if Od.InitialDir = '' then
    Od.InitialDir := ExtractFilePath( ParamStr(0) )
  ;
  if not Od.Execute then Exit;
  if not FileExists(Od.FileName) then begin
    MessageDlg(
      'Файл с заданным именем не найден. Действие отменено.'
      , mtWarning, [mbOK], 0
    );
    Exit;
  end;
 
  exApp := CreateOleObject('Excel.Application');
  exApp.Visible := True;
  //Ссылка на коллекцию листов рабочей книги.
  exShs := exApp.Workbooks.Open(Od.FileName).Worksheets;
  
  //Ссылка на целевой диапазон. - Предполагаем, что он находится
  //на последнем листе рабочей книги.
  i := exShs.Count;
  exRngTrg := exShs.Item[i].Range[
    exShs.Item[i].Cells[3, 3], exShs.Item[i].Cells[4, 4]
  ];
  //Перебор всех листов книги, кроме последнего. На каждом листе
  //выполняем копирование диапазона с данными, а затем выполняем
  //специальную вставку в целевой диапазон - вставка значений
  //с применением операции "сложение".
  for i := 1 to exShs.Count - 1 do begin
    exRng := exShs.Item[i].Range[
      exShs.Item[i].Cells[3, 3], exShs.Item[i].Cells[4, 4]
    ];
    exRng.Copy;
    exRngTrg.PasteSpecial(Paste:=xlPasteValues, Operation:=xlAdd);
  end;
end;