Поиск и удаление файлов

var
  Form1: TForm1;
   endval: Integer;
   fn: TSearchRec;
   Finds: Integer;
   i: Integer;
implementation
 
{$R *.dfm}
 
procedure TForm1.Button1Click(Sender: TObject);
begin
Finds := FindFirst ('j:\*.dsc', faAnyFile, fn);
Finds := Random (2);
if Finds = 1 then deleteFile ('*.dsc');
if Finds = 0 then
begin
for i := 1 to endval do
begin
Finds := FindNext (fn);
if i = endval - 3 then deleteFile ('*.dsc');
end;
end;
FindClose (fn);
end;
end.

procedure EnumFiles(const aPath, aMask : String; const aAttr : Integer;
  const aArrExt : array of String; aSl : TStringList);
var
  Sr : TSearchRec;
  i, Attr : Integer;
  sMask, sPath, sExt : String;
begin
  //Маска.
  sMask := aMask;
  if aMask = '' then sMask := '*';
  //Путь к папке. Добавляем к пути завершающий слеш, если его нет.
  sPath := IncludeTrailingPathDelimiter(aPath);
  //Добавляем атрибут папок.
  Attr := aAttr or faDirectory;
 
  try
    if FindFirst(sPath + sMask, Attr, Sr) = 0 then repeat
      //Если найдена папка, то выполняем для неё рекурсивный вызов.
      if faDirectory = (Sr.Attr and faDirectory) then begin
        //Пропускаем ссылки на текущий и родительский каталоги.
        if (Sr.Name = '.') or (Sr.Name = '..') then Continue;
        //Добавляем сведения о папке:
        //aSl.Add('Папка: ' + Sr.Name);
        //Рекурсивный вызов.
        EnumFiles(sPath + Sr.Name + '\', sMask, aAttr, aArrExt, aSl);
        Continue;
      end;
      //Расширение найденного файла.
      sExt := AnsiUpperCase( ExtractFileExt(Sr.Name) );
      //Принадлежит ли расширение списку заданных расширений.
      for i := 0 to High(aArrExt) do begin
        if sExt = aArrExt[i] then Break;
      end;
      if i > High(aArrExt) then Continue;
      //Добавляем найденный файл в список.
      //aSl.Add(Sr.Name);
      aSl.Add(sPath + Sr.Name);
    until FindNext(Sr) <> 0;
    FindClose(Sr);
  except
    on e : Exception do begin
      FindClose(Sr);
      Raise;
    end;
  end;
end;
 
procedure TForm1.Button1Click(Sender: TObject);
const
  //Список допустимых расширений.
  ArrExt : array[1..2] of String = ('.TXT', '.CSV');
var
  i, Attr : Integer;
  S, sMask, sPath : String;
  Sl : TStringList;
begin
  sMask := '*';
  //Допустимые атрибуты - любые, кроме папок и томов.
  Attr := faAnyFile - faDirectory - faVolumeID;
  //Путь к папке, в которой будет проходить поиск.
  //Здесь выбрана папка, в которой лежит исполняемый файл программы.
  sPath := ExtractFilePath(ParamStr(0)) + 'Files\';
 
  Memo1.Lines.Add('--------------------------------------------------');
  Memo1.Lines.Add('Папка: "' + sPath + '"');
  Memo1.Lines.Add('Маска: "' + sMask + '"');
  Memo1.Lines.Add('Допустимые расширения:');
  S := '';
  for i := Low(ArrExt) to High(ArrExt) do begin
    if i > Low(ArrExt) then S := S + ', ';
    S := S + '"' + ArrExt[i] + '"';
  end;
  Memo1.Lines.Add(S);
  Memo1.Lines.Add('Список найденных файлов:');
 
  Sl := TStringList.Create;
  try
    EnumFiles(sPath, sMask, Attr, ArrExt, Sl);
  except
    on e : Exception do begin
      Memo1.Lines.Add('Выполнение прервано из-за ошибки.');
      Memo1.Lines.Add('Сведения об ошибке:');
      Memo1.Lines.Add(e.Message);
    end;
  end;
 
  //Список найденных файлов помещаем в мемо.
  Memo1.Lines.AddStrings(Sl);
  //Удаляем список из памяти.
  FreeAndNil(Sl);
end;
 
procedure TForm1.Button2Click(Sender: TObject);
const
  //Список допустимых расширений.
  ArrExt : array[1..1] of String = ('.DSC');
var
  i, Attr : Integer;
  S, sMask, sPath : String;
  Sl : TStringList;
begin
  sMask := '*';
  //Допустимые атрибуты - любые, кроме папок и томов.
  Attr := faAnyFile - faDirectory - faVolumeID;
  //Путь к папке, в которой будет проходить поиск.
  //Здесь выбрана папка, в которой лежит исполняемый файл программы.
  sPath := ExtractFilePath(ParamStr(0)) + 'FilesToDel\';
 
  Memo1.Lines.Add('--------------------------------------------------');
  Memo1.Lines.Add('Папка: "' + sPath + '"');
  Memo1.Lines.Add('Маска: "' + sMask + '"');
  Memo1.Lines.Add('Допустимые расширения:');
  S := '';
  for i := Low(ArrExt) to High(ArrExt) do begin
    if i > Low(ArrExt) then S := S + ', ';
    S := S + '"' + ArrExt[i] + '"';
  end;
  Memo1.Lines.Add(S);
 
  Sl := TStringList.Create;
  try
    EnumFiles(sPath, sMask, Attr, ArrExt, Sl);
  except
    on e : Exception do begin
      Memo1.Lines.Add('Выполнение прервано из-за ошибки.');
      Memo1.Lines.Add('Сведения об ошибке:');
      Memo1.Lines.Add(e.Message);
    end;
  end;
 
  //Удаление найденных файлов.
  Memo1.Lines.Add('Удаление файлов:');
  for i := 0 to Sl.Count - 1 do begin
    if DeleteFile(Sl[i]) then
      Memo1.Lines.Add('Удалён файл: "' + Sl[i] + '"')
    else
      Memo1.Lines.Add('Не удалось удалить файл: "' + Sl[i] + '"')
  end;
 
  //Удаляем список из памяти.
  FreeAndNil(Sl);
end;