Не могу найти ошибку: процедура считывает только последнюю запись в файле

procedure TfrmMain.LoadPersonalInfo;
var
  i: Integer;
  Data: array of TRecordPersona;
  FileOFPersonal: file of TRecordPersona;
  Persona: TRecordPersona;
 
const
  FName: String = 'personal.tbl';
 
begin
 
  i:=1;
 
  if not (FileExists(FName)) then
    begin
      AssignFile(FileOFPersonal, FName);
      Rewrite(FileOFPersonal);
      CloseFile(FileOFPersonal);
    end;
 
  AssignFile(FileOFPersonal, FName);
  Reset(FileOFPersonal);
 
  while not (Eof(FileOFPersonal)) do
    begin
      SetLength(Data, i);
      Read(FileOFPersonal, Persona);
      Data[i-1]:=Persona;
      Inc(i);
    end;
 
  for i:=0 to High(Data) do
    begin
      with Data[i] do
        begin
          sgOtpusk.RowCount:=sgOtpusk.RowCount+1;
          sgOtpusk.Cells[0, i+1]:=Persona.FIO;
          sgOtpusk.Cells[1, i+1]:=Persona.Mestonahozhdeniya;
          sgOtpusk.Cells[2, i+1]:=DateToStr(Persona.DateBegin);
          sgOtpusk.Cells[3, i+1]:=DateToStr(Persona.DateEnd);
        end;
    end;
end;

      with Data[i] do
        begin
          sgOtpusk.RowCount:=sgOtpusk.RowCount+1;
          sgOtpusk.Cells[0, i+1]:=Persona.FIO;
          sgOtpusk.Cells[1, i+1]:=Persona.Mestonahozhdeniya;
          sgOtpusk.Cells[2, i+1]:=DateToStr(Persona.DateBegin);
          sgOtpusk.Cells[3, i+1]:=DateToStr(Persona.DateEnd);
        end;

      with Data[i] do
        begin
          sgOtpusk.RowCount:=sgOtpusk.RowCount+1;
          sgOtpusk.Cells[0, i+1]:= FIO;
          sgOtpusk.Cells[1, i+1]:= Mestonahozhdeniya;
          sgOtpusk.Cells[2, i+1]:=DateToStr(DateBegin);
          sgOtpusk.Cells[3, i+1]:=DateToStr(DateEnd);
        end;

  i := 1;
  Reset(FileOFPersonal);
  while not (Eof(FileOFPersonal)) do
    begin
      SetLength(Data, i);
      Read(FileOFPersonal, Persona);
      Data[i-1]:=Persona;
      Inc(i);
    end;

  Reset(FileOFPersonal);
  SetLength(Data, FileSize(FileOFPersonal));
  i := 0;
  while not Eof(FileOFPersonal) do begin
    Read(FileOFPersonal, Data[i]);
    Inc(i);
  end;