Как записать данные в файл MS Word

uses
  ComObj;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  wdApp, wdDocs, wdDoc, wdBms : OleVariant;
  Path : String;
begin
  //Полный путь папки, в которой лежат файлы шаблонов. Эта папка лежит
  //в том же директории, где находится исполняемый файл программы.
  Path := ExtractFilePath(ParamStr(0)) + 'Templates\';
  //Попытка запуска экземпляра MS Word и получения ссылки на интерфейс
  //его корневого объекта (Word.Application).
  try
    wdApp := CreateOleObject('Word.Application');
  except
    MessageBox(Handle, 'Не удалось запустить MS Word. Действие отменено.',
      'Внимание!', MB_OK + MB_ICONWARNING + MB_APPLMODAL);
    Exit;
  end;
 
  //Делаем видимым окно MS Word.
  wdApp.Visible := True;
  //Ссылка на интерфейс коллекции документов.
  wdDocs := wdApp.Documents;
  //Попытка открыть файл шаблона и получить ссылку на интерфейс документа.
  wdDoc := wdDocs.Open(FileName:=Path + 'template-01.doc');
  //Получаем ссылку на интерфейс коллекции закладок.
  wdBms := wdDoc.Bookmarks;
  
  //Далее работаем с закладками.
  //...
  //...
  //...
end;

uses
  ComObj;
 
{ Функция записывает новый текст aText для закладки с именем aBmName.
  aBmx - ссылка на интерфейс коллекции закладок: Word.Document.Bookmarks
  Функция возвращает значение True, если закладка найдена и её текст изменён
  и False - если закладка не найдена.
  Переустановка текста закладки выплоняется так:
  - Получаем ссылку на интерфейс объекта-диапазона, который содержит текст закладки.
  - Удаляем закладку.
  - Устанавливаем новый текст для объекта-диапазона.
  - Создаём новую закладку с диапазоном, который содержит новый текст.}
function SetBmText(var aBms : OleVariant; const aBmName, aText : String) : Boolean;
var
  Bm, Rng : OleVariant;
begin
  Result := aBms.Exists(aBmName); //Проверяем - существует ли закладка с заданным именем.
  if not Result then              //Если закладка не найдена - выходим.
    Exit;
 
  Bm := aBms.Item(aBmName); //Ссылка на интерфейс закладки.
  Rng := Bm.Range;          //Ссылка на интерфейс диапазона, связанного с закладкой.
  Bm.Delete;                //Удаление закладки.
  Rng.Text := aText;        //Заменяем текст в диапазоне.
  aBms.Add(aBmName, Rng);   //Добавляем новую закладку с таким же именем.
end;
 
procedure TForm1.Button1Click(Sender: TObject);
var
  wdApp, wdDocs, wdDoc, wdBms : OleVariant;
  Od : TOpenDialog;
begin
  //Диалог выбора файла.
  Od := OpenDialog1; //OpenDialog1 уже должен быть на форме.
  //ExtractFilePath(ParamStr(0)) - Полный путь директория, в котором лежит исполняемый файл программы.
  if Od.InitialDir = '' then
    Od.InitialDir := ExtractFilePath(ParamStr(0)) + 'Files\';
  Od.Title := 'Выберите файл шаблона для создания нового документа';
  if not Od.Execute then
    Exit;
  if not FileExists(Od.FileName) then
  begin
    MessageBox(Handle, 'Файл с заданным именем не найден. Действие отменено.',
      'Внимание!', MB_YESNO + MB_ICONEXCLAMATION + MB_APPLMODAL);
    Exit;
  end;
 
  //Попытка запустить экземпляр MS Word и получить ссылку на интерфейс его корневого объекта Word.Application.
  try
    wdApp := CreateOleObject('Word.Application');
  except
    ShowMessage('Не удалось запустить MS Word. Действие отменено.');
    Exit;
  end;
 
  wdApp.Visible := True;     //Делаем видимым окно MS Word.
  wdDocs := wdApp.Documents; //Ссылка на интерфейс коллекции документов.
  wdDoc := wdDocs.Open(FileName:=Od.FileName); //Открываем документ.
  wdBms := wdDoc.Bookmarks;      //Подключаемся к коллекции закладок.
  wdApp.ScreenUpdating := False; //Отключение перерисовки окна MS Word. - Для ускорения работы.
 
  //Ищем закладки с нужными именами и изменяем их содержимое в зависимости
  //от установленных переключателей (TCheckBox).
  if CheckBox1.Checked then
    SetBmText(wdBms, 'CHECK_01', 'CHECK_01 - ДА')
  else
    SetBmText(wdBms, 'CHECK_01', 'CHECK_01 - НЕТ');
 
  if CheckBox2.Checked then
    SetBmText(wdBms, 'CHECK_02', 'CHECK_02 - ДА')
  else
    SetBmText(wdBms, 'CHECK_02', 'CHECK_02 - НЕТ');
 
  wdApp.DisplayAlerts := False; //Запрет на показ предупреждений.
  try
    wdDoc.SaveAs(FileName:=Od.FileName + '-new.doc');
  finally
    wdApp.DisplayAlerts := True; //Разрешение на показ предупреждений.
  end;
  
  //wdDoc.Close; //Если требуется, закрываем документ.
  //wdApp.Quit;  //Если требуется, закрываем MS Word.
end;