Выделить подстроку, которая соответствует записи вещественного числа

function FindFloatNum(aStrSrc : String; var aStrRes : String) : Boolean;
var
  //Позиция на которой находится запятая.
  PosPnt : Integer;
  //Позиция на которой находится первая цифра искомого числа.
  Pos1 : Integer;
  //Позиция на котой расположена последняя цифра искомого числа.
  Pos2 : Integer;
begin
 
  aStrRes := '';
 
  //Ищем дясятичную точку - это знак запятая: ','
  PosPnt := Pos(',', aStrSrc);
 
  //Если не нашли.
  if PosPnt = 0 then begin
    Result := False;
    Exit;
  end;
 
  //Если нашли.
 
  //Определяем есть ли целая часть.
  //Для этого "шагаем" влево от запятой. И шагаем до тех пор, пока не встретим
  //первую "не цифру", либо пока не дойдём до начала строки.
 
  Pos1 := PosPnt; //Это позиция на которой находится запятая.
 
  while Pos1 > 1 do begin //Т. е. перед очередным шагом слева должен быть хотябы один символ.
    //Шаг влево.
    Pos1 := Pos1 - 1;
    if not (aStrSrc[Pos1] in ['0'..'9']) then begin
      //Раз нашли не цифру, то проверяем, не является ли символ "+" или "-"
      if aStrSrc[Pos1] in ['+', '-'] then begin
        //Раз этот символ обозначет знак числа, то позиция на которой этот
        //символ расположен и будет являться началом самого числа.
        //Pos1 не изменяем.
      end else begin
        //Значит этот символ уже не относится к числу.
        //Возвращаемся на шаг правее.
        Pos1 := Pos1 + 1;
      end;
      //И выходим из цикла.
      Break;
    end;
  end;
 
  //Еcли цифры левее запятой не нашлись, то полагаем, что число не найдено.
  if Pos1 = PosPnt then begin
    Result := False;
    Exit;
  end;
 
  //Раз цифры левее запятой обнаружились, то они принадлежат целой части.
  //При этом номер позиции, на которой расположена первая цифра искомого числа, равна Pos1.
 
  //Теперь определяем есть ли дробная часть.
  //Начинаем шагать вправо от запятой. Шагаем до тех пор, пока не встретим
  //первую "не цифру", либо пока не дойдем до конца строки.
 
  Pos2 := PosPnt; //Это позиция на которой находится запятая.
 
  while Pos2 < Length(aStrSrc) do begin //Т. е. перед очередным шагом справа должен быть хотябы один символ.
    //Шаг вправо.
    Pos2 := Pos2 + 1;
    if not (aStrSrc[Pos2] in ['0'..'9']) then begin
      //Раз нашли не цифру, то возвращаемся на шаг левее.
      Pos2 := Pos2 - 1;
      //И выходим из цикла.
      Break;
    end;
  end;
 
  //Еcли цифры правее запятой не нашлись, то полагаем, что число не найдено.
  if Pos2 = PosPnt then begin
    Result := False;
    Exit;
  end;
 
  //Раз цифры правее запятой обнаружены, то они принадлежат дробной части.
  //При этом номер позиции, на которой расположена последняя цифра искомого числа, равна Pos2.
 
  //Теперь выделяем обнаруженное число.
 
  aStrRes := Copy(aStrSrc, Pos1, Pos2 - Pos1 + 1);
  Result := True;
 
end;

unit uMain;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TfrmMain = class(TForm)
    edStrSrc: TEdit;
    Label1: TLabel;
    btnFind: TButton;
    edStrRes: TEdit;
    Label2: TLabel;
    procedure btnFindClick(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;
 
var
  frmMain: TfrmMain;
 
implementation
 
uses StrUtils;
 
{$R *.dfm}
 
function FindFloatNum(aStrSrc : String; var aPos : Longword; var aStrRes : String) : Boolean;
var
  //Позиция на которой находится запятая.
  PosPnt : Integer;
  //Позиция на которой находится первая цифра искомого числа.
  Pos1 : Integer;
  //Позиция на котой расположена последняя цифра искомого числа.
  Pos2 : Integer;
begin
 
  aStrRes := '';
 
  //Ищем дясятичную точку - это знак запятая: ','. Поиск ведем, начиная
  //с позиции aPos.
  PosPnt := PosEx(',', aStrSrc, aPos);
 
  //Если не нашли.
  if PosPnt = 0 then begin
    Result := False;
    Exit;
  end;
 
  //Если нашли.
 
  //Определяем есть ли целая часть.
  //Для этого "шагаем" влево от запятой. И шагаем до тех пор, пока не встретим
  //первую "не цифру", либо пока не дойдём до метки начала - до aPos.
 
  Pos1 := PosPnt; //Это позиция на которой находится запятая.
 
  while Pos1 > aPos + 1 do begin //Т. е. перед очередным шагом слева должен оставаться хотябы один символ до позиции aPos.
    //Шаг влево.
    Pos1 := Pos1 - 1;
    if not (aStrSrc[Pos1] in ['0'..'9']) then begin
      //Раз нашли не цифру, то проверяем, не является ли символ "+" или "-"
      if aStrSrc[Pos1] in ['+', '-'] then begin
        //Раз этот символ обозначет знак числа, то позиция на которой этот
        //символ расположен и будет являться началом самого числа.
        //Pos1 не изменяем.
      end else begin
        //Значит этот символ уже не относится к числу.
        //Возвращаемся на шаг правее.
        Pos1 := Pos1 + 1;
      end;
      //И выходим из цикла.
      Break;
    end;
  end;
 
  //Еcли цифры левее запятой не нашлись, то полагаем, что число не найдено.
  if Pos1 = PosPnt then begin
    Result := False;
    Exit;
  end;
 
  //Раз цифры левее запятой обнаружились, то они принадлежат целой части.
  //При этом номер позиции, на которой расположена первая цифра искомого числа, равна Pos1.
 
  //Теперь определяем есть ли дробная часть.
  //Начинаем шагать вправо от запятой. Шагаем до тех пор, пока не встретим
  //первую "не цифру", либо пока не дойдем до конца строки.
 
  Pos2 := PosPnt; //Это позиция на которой находится запятая.
 
  while Pos2 < Length(aStrSrc) do begin //Т. е. перед очередным шагом справа должен быть хотябы один символ.
    //Шаг вправо.
    Pos2 := Pos2 + 1;
    if not (aStrSrc[Pos2] in ['0'..'9']) then begin
      //Раз нашли не цифру, то возвращаемся на шаг левее.
      Pos2 := Pos2 - 1;
      //И выходим из цикла.
      Break;
    end;
  end;
 
  //Еcли цифры правее запятой не нашлись, то полагаем, что число не найдено.
  if Pos2 = PosPnt then begin
    Result := False;
    Exit;
  end;
 
  //Раз цифры правее запятой обнаружены, то они принадлежат дробной части.
  //При этом номер позиции, на которой расположена последняя цифра искомого числа, равна Pos2.
 
  //Теперь выделяем обнаруженное число.
  aStrRes := Copy(aStrSrc, Pos1, Pos2 - Pos1 + 1);
  //И обозначаем позицию (справа) на которой мы остановились.
  aPos := Pos2;
  Result := True;
 
end;
 
//Эта процедура находит все дробные числа, представленные в строке.
function FindAllFloatNum(aStrSrc : String) : String;
var
  Pos1 : Longword;
  StrRes : String;
begin
  Pos1 := 0;
  Result := '';
  while Pos1 < Length(aStrSrc) do begin //Делаем до тех пор, пока, остаётся хотябы 1 символ перед концом строки.
    //1 шаг вправо.
    Pos1 := Pos1 + 1;
    //Ищем число, начиная с позиции Pos1.
    if FindFloatNum(aStrSrc, Pos1, StrRes) then begin
      //Раз число найдено, то Pos1 теперь содержит номер позиции в которой
      //расположена последняя цифра найденного числа. А StrRes содержит само представление числа.
 
      //Если результирующая строка не пуста, то дописываем разделитель: ';'
      if Result <> '' then begin
        Result := Result + '; ';
      end;
      //Добавляем найденное число к результату.
      Result := Result + StrRes;
    end;
  end;
end;
 
procedure TfrmMain.btnFindClick(Sender: TObject);
var
  StrRes : String;
begin
  StrRes := FindAllFloatNum(edStrSrc.Text);
  if StrRes <> '' then begin
    edStrRes.Text := StrRes;
  end else begin
    edStrRes.Text := 'Не обнаружено';
  end;
end;
 
end.