Программа поиска редко встречающегося слова в текстовом файле

procedure TForm1.Button1Click(Sender: TObject);
type
  //Сведения о слове.
  TWord = record
    SWord : String; //Само слово.
    Cnt : Integer;  //Количество обнаружений слова в тексте.
  end;
const
  //Разделители слов.
  D = ['.', ',', ':', ';', '!', '?', '-', ' ', #9, #10, #13];
  //Величина приращения длины динамического массива.
  Capacity = 100;
var
  S, Sw : String;
  Arr : array of TWord;
  Elem : TWord;
  i, j, k, Len, LenW : Integer;
begin
  S := Memo1.Text; //Исходный текст.
 
  Len := Length(S);
  LenW := 0; //Длина очередного слова.
  j := 0; //Количество значимых элементов в массиве.
  for i := 1 to Len do
    //Если очередной символ не является разделителем, значит он принадлежит слову.
    if not (S[i] in D) then begin
      //Учитываем символ в длине слова.
      Inc(LenW);
      //Отслеживаем конец слова.
      if (i = Len) or (S[i + 1] in D) then begin
        //Извлекаем слово и переводим его буквы в верхний регистр.
        Sw := Copy(S, i - LenW + 1, LenW);
        //Проверяем есть ли уже такое слово в массиве.
        k := 0;
        while (k < j) and (Sw <> Arr[k].SWord) do Inc(k);
        {Если k < j, значит слово в массиве найдено. В этом случае наращиваем
        его счётчик. В противном случае (если k = j) добавляем слово в массив.}
        if k < j then
          Inc(Arr[k].Cnt)
        else begin
          //Если требуется, увеличиваем длину массива.
          if j = Length(Arr) then SetLength(Arr, j + Capacity);
          Arr[k].SWord := Sw;
          Arr[k].Cnt := 1;
          //Количество значимых элементов в массиве стало на 1 больше.
          Inc(j);
        end;
        //Сброс длины слова.
        LenW := 0;
      end;
    end;
  //Устанавливаем длину массива в соответствие с количеством значимых элементов.
  if j < Length(Arr) then SetLength(Arr, j);
 
  //Сортировка массива по возрастанию значений Cnt методом вставок.
  for i := 0 + 1 to High(Arr) do begin
    j := i;
    Elem := Arr[i];
    while (j > 0) and (Arr[j - 1].Cnt > Elem.Cnt) do begin
      Arr[j] := Arr[j - 1];
      Dec(j);
    end;
    Arr[j] := Elem;
  end;
 
  //Ответ.
  if Length(Arr) = 0 then
    Memo2.Lines.Add('В тексте нет слов.')
  else begin
    Memo2.Lines.Add('Перечень различающихся слов в порядке возрастания их присутствий:');
    for i := 0 to High(Arr) do
      Memo2.Lines.Add('"' + Arr[i].SWord + '" :'#9 + IntToStr(Arr[i].Cnt));
  end;
end;

...
const
  Fn = 'MyFile.txt';
var
  FileName : String;
...
begin
  //Полный путь к файлу, который лежит в той же папке, где расположен исполняемый файл программы.
  FileName := ExtractFilePath(ParamStr(0)) + Fn;
  Memo1.Lines.LoadFromFile(FileName);
...