Имитация нажатий клавиш клавиатуры

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Button1: TButton;
    Button2: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    { Private declarations }
 
    //Флаг, показывающий, участвует ли наше окно в цепочке наблюдателей.
    FInChain : Boolean;
    //Хэндл окна, которое в цепочке наблюдателей стоит за нами.
    FNextViewer : HWND;
  public
    { Public declarations }
 
    //Вызывается в случае, если изменяется цепочка наблюдателей за буфером обмена.
    procedure WMChangeCBChain(var Msg: TWMChangeCBChain); message WM_CHANGECBCHAIN;
 
    //Вызывается в случае, если содержимое буфера обмена изменилось.
    procedure WMDrawClipboard(var Msg: TWMDrawClipboard); message WM_DRAWCLIPBOARD;
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
uses
  Clipbrd;
 
{ TForm1 }
 
//Вызывается в случае, если из цепочки удаляется какой-то наблюдатель.
procedure TForm1.WMChangeCBChain(var Msg: TWMChangeCBChain);
begin
  //Цепочка наблюдателей за буфером обмена: БУФЕР ОБМЕНА - А1 - А2 - А3 - А4 - А5 - А6
  //А1...А6 - это окна, зарегистрированные как наблюдатели.
  //Предположим, мы - это А3, тот кто прикреплён
  //за нами - это А4 - на него ссылается FNextViewer
  //А тот кто прикреплён за А4 - это А5.
  //Msg.Remove - хэндл (системный идентификатор Windows) удаляемого окна
  //Msg.Next - хэндл того окна, которое прикреплено за удаляемым окном
 
  //Если оказалось, что из цепочки наблюдателей удаляется А4, то мы должны прикрепить
  //к себе А5. В результате получится: БУФЕР ОБМЕНА - А1 - А2 - А3 - А5 - А6
  if Msg.Remove = FNextViewer then
    FNextViewer := Msg.Next
  //Если из цепочки наблюдателей удаляется некто не равный А4, то мы просто должны
  //переслать сообщение следующему в цепочке - т. е. А4.
  else
    SendMessage(FNextViewer, WM_CHANGECBCHAIN, Msg.Remove, Msg.Next)
  ;
 
  //Новые окна в цепочку добавляются в начало цепи - т. е. перед А1. Поэтому
  //членам цепочки не надо обрабатывать ситуации с добавлением.
end;
 
//Вызывается в случае, если содержимое буфера обмена изменилось.
procedure TForm1.WMDrawClipboard(var Msg: TWMDrawClipboard);
var
  i : Integer;
  IsMod : Boolean;
begin
  //Оповещаем об изменениях следующего за нами наблюдателя.
  if FNextViewer <> 0 then begin
    SendMessage(FNextViewer, WM_DRAWCLIPBOARD, 0, 0);
    Msg.Result:=0;
  end;
 
  //Далее идёт код работы с буфером обмена.
 
  Memo1.Lines.Add('--------------------------------------------------');
  Memo1.Lines.Add('Содержимое буфера обмена изменилось.');
 
  //Проверяем, есть ли в буфере данные в интересующем нас формате.
  IsMod := False;
  for i := 0 to Clipboard.FormatCount - 1 do begin
    if Clipboard.HasFormat(CF_TEXT) then begin
      IsMod := True;
      Break;
    end;
  end;
 
  //Если данные в требуемом формате есть, то обрабатываем их.
  if IsMod then begin
    //...
    //Например копируем текст в Memo.
    Memo1.Lines.Add('Данные типа CF_TEXT:');
    Memo1.Lines.Add(Clipboard.AsText);
    //...
  end else begin
    Memo1.Lines.Add('Буфер обмена не содержит данных типа CF_TEXT.');
  end;
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  FInChain := False;
  FNextViewer := 0;
end;
 
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  if FInChain then begin
    ChangeClipboardChain(Handle, FNextViewer);
    FInChain := False;
  end;
end;
 
//Встраиваем наше окно в цепочку наблюдателей за буфером обмена.
procedure TForm1.Button1Click(Sender: TObject);
begin
  //FNextViewer - хэндл следующего за нами наблюдателя. Может быть = 0, если
  //наше окно последнее в цепи.
  FNextViewer := SetClipboardViewer(Handle);
  FInChain := True;
 
  Memo1.Lines.Add('--------------------------------------------------');
  Memo1.Lines.Add('Выполнена регистрация в качестве наблюдателя за буфером обмена.');
end;
 
//Удаляем наше окно из цепочки наблюдателей за буфером обмена.
procedure TForm1.Button2Click(Sender: TObject);
begin
  ChangeClipboardChain(Handle, FNextViewer);
  FInChain := False;
 
  Memo1.Lines.Add('--------------------------------------------------');
  Memo1.Lines.Add('Выполнен выход из цепочки наблюдателй за буфером обмена.');
end;
 
end.

unit Unit1;
 
interface
 
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;
 
type
  TForm1 = class(TForm)
    Memo1: TMemo;
    Button1: TButton;
    Button2: TButton;
    procedure FormCreate(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
  private
    { Private declarations }
 
    //Флаг, показывающий, участвует ли наше окно в цепочке наблюдателей.
    FInChain : Boolean;
    //Флаг, показывающий, следует ли реагировать на изменения в буфере обмена.
    FIsEnableAction : Boolean;
    //Хэндл окна, которое в цепочке наблюдателей стоит за нами.
    FNextViewer : HWND;
  public
    { Public declarations }
 
    //Вызывается в случае, если изменяется цепочка наблюдателей за буфером обмена.
    procedure WMChangeCBChain(var Msg: TWMChangeCBChain); message WM_CHANGECBCHAIN;
    //Вызывается в случае, если содержимое буфера обмена изменилось.
    procedure WMDrawClipboard(var Msg: TWMDrawClipboard); message WM_DRAWCLIPBOARD;
 
    //Зарегистрироваться в цепочке наблюдателей за буфером обмена.
    procedure EnableView;
    //Выйти из цепочки наблюдателей за буфером обмена.
    procedure DisableView;
  end;
 
var
  Form1: TForm1;
 
implementation
 
{$R *.dfm}
 
uses
  Clipbrd;
 
{ TForm1 }
 
//Вызывается в случае, если из цепочки удаляется какой-то наблюдатель.
procedure TForm1.WMChangeCBChain(var Msg: TWMChangeCBChain);
begin
  //Цепочка наблюдателей за буфером обмена: БУФЕР ОБМЕНА - А1 - А2 - А3 - А4 - А5 - А6
  //А1...А6 - это окна, зарегистрированные как наблюдатели.
  //Предположим, мы - это А3, тот кто прикреплён
  //за нами - это А4 - на него ссылается FNextViewer
  //А тот кто прикреплён за А4 - это А5.
  //Msg.Remove - хэндл (системный идентификатор Windows) удаляемого окна
  //Msg.Next - хэндл того окна, которое прикреплено за удаляемым окном
 
  //Если оказалось, что из цепочки наблюдателей удаляется А4, то мы должны прикрепить
  //к себе А5. В результате получится: БУФЕР ОБМЕНА - А1 - А2 - А3 - А5 - А6
  if Msg.Remove = FNextViewer then
    FNextViewer := Msg.Next
  //Если из цепочки наблюдателей удаляется некто не равный А4, то мы просто должны
  //переслать сообщение следующему в цепочке - т. е. А4.
  else
    SendMessage(FNextViewer, WM_CHANGECBCHAIN, Msg.Remove, Msg.Next)
  ;
 
  //Новые окна в цепочку добавляются в начало цепи - т. е. перед А1. Поэтому
  //членам цепочки не надо обрабатывать ситуации с добавлением.
end;
 
//Вызывается в случае, если содержимое буфера обмена изменилось.
procedure TForm1.WMDrawClipboard(var Msg: TWMDrawClipboard);
var
  i : Integer;
  IsMod : Boolean;
begin
  //Оповещаем об изменениях следующего за нами наблюдателя.
  if FNextViewer <> 0 then begin
    SendMessage(FNextViewer, WM_DRAWCLIPBOARD, 0, 0);
    Msg.Result:=0;
  end;
 
  //Далее идёт код работы с буфером обмена.
 
  //Если режим реагирования выключен - выходим.
  if not FIsEnableAction then Exit;
 
  Memo1.Lines.Add('--------------------------------------------------');
  Memo1.Lines.Add('Данные буфера обмена изменились.');
 
  //Проверяем, есть ли в буфере данные в интересующем нас формате.
  IsMod := False;
  for i := 0 to Clipboard.FormatCount - 1 do begin
    if Clipboard.HasFormat(CF_TEXT) then begin
      IsMod := True;
      Break;
    end;
  end;
 
  //Если данные в требуемом формате есть, то обрабатываем их.
  if IsMod then begin
    //Копируем текст в Memo.
    Memo1.Lines.Add('Данные типа CF_TEXT:');
    Memo1.Lines.Add('--------------------------------------------------');
    Memo1.Lines.Add(Clipboard.AsText);
  end else begin
    Memo1.Lines.Add('Буфер обмена не содержит данных типа CF_TEXT.');
  end;
 
  //Отключаем режим реагирования.
  FIsEnableAction := False;
  Memo1.Lines.Add('--------------------------------------------------');
  Memo1.Lines.Add('Режим реагирования отключен.');
end;
 
//Подключение к цепочке наблюдателей за буфером обмена.
procedure TForm1.EnableView;
begin
  //Если мы уже подключены к цепочке - выходим.
  if FInChain then Exit;
  FNextViewer := SetClipboardViewer(Handle);
  FInChain := True;
end;
 
//Отключение от цепочки наблюдателей за буфером обмена.
procedure TForm1.DisableView;
begin
  //Если мы уже отключены от цепочки - выходим.
  if not FInChain then Exit;
  ChangeClipboardChain(Handle, FNextViewer);
  FInChain := False;
end;
 
procedure TForm1.FormCreate(Sender: TObject);
begin
  FInChain := False;
  FIsEnableAction := False;
  FNextViewer := 0;
end;
 
procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  DisableView;
end;
 
//Встраиваем наше окно в цепочку наблюдателей за буфером обмена.
//Включаем режим реагирования и выполняем действия по копированию
//текста из целевого окна в буфер обмена.
procedure TForm1.Button1Click(Sender: TObject);
var
  HWin : HWND;
begin
  //Ищем окно Блокнота.
  HWin := FindWindow(nil, PChar('Безымянный - Блокнот'));
  if HWin = 0 then begin
    ShowMessage('Окно блокнота не найдено. Действие отменено.');
    Exit;
  end;
 
  //Подключаемся к цепочке наблюдателей.
  EnableView;
  Memo1.Lines.Add('--------------------------------------------------');
  Memo1.Lines.Add('Произведено подключение к цепочке наблюдателей.');
 
  //Переводим фокус ввода на окно Блокнота.
  SetForegroundWindow(HWin);
  //Небольшая задержка - ожидаем, когда активация нужного
  //окна завершится.
  Sleep(200);
 
  //Включаем режим реагирования.
  FIsEnableAction := True;
  Memo1.Lines.Add('--------------------------------------------------');
  Memo1.Lines.Add('Режим реагирования включен.');
 
  //Ctrl+A.
  keybd_event(VK_LCONTROL,0,0,0);
  keybd_event(Ord('A'),0,0,0);
  keybd_event(Ord('A'),0,KEYEVENTF_KEYUP,0);
  keybd_event(VK_LCONTROL,0,KEYEVENTF_KEYUP,0);
 
  //Ctrl+C.
  keybd_event(VK_LCONTROL,0,0,0);
  keybd_event(Ord('C'),0,0,0);
  keybd_event(Ord('C'),0,KEYEVENTF_KEYUP,0);
  keybd_event(VK_LCONTROL,0,KEYEVENTF_KEYUP,0);
end;
 
procedure TForm1.Button2Click(Sender: TObject);
begin
  Memo1.Clear;
end;
 
end.

procedure TForm1.Timer1Timer(Sender: TObject);
begin
keybd_event(VK_F7, 0, 0, 0); //нажатие F5
keybd_event(VK_F7, 0, KEYEVENTF_KEYUP, 0); //отпускание F5
end;

  keybd_event(VK_LSHIFT, 0, 0, 0); 
    keybd_event(Ord(39), 0, 0, 0); 
    keybd_event(Ord(39), 0, KEYEVENTF_KEYUP, 0);
  keybd_event(VK_LSHIFT, 0, KEYEVENTF_KEYUP, 0);

  keybd_event(VK_LSHIFT, 0, 0, 0); 
    sleep(3000);
    keybd_event(Ord(39), 0, 0, 0); 
    keybd_event(Ord(39), 0, KEYEVENTF_KEYUP, 0);
    sleep(3000);
  keybd_event(VK_LSHIFT, 0, KEYEVENTF_KEYUP, 0);

Keybd_event(VK_RSHIFT,0,0,0);
Keybd_event(VK_INSERT,0,0,0);
Keybd_event(VK_INSERT,0,2,0); 
Keybd_Event(VK_RSHIFT, 0, 3, 0);
Keybd_Event(VK_SHIFT, 0, 0, 0);
Keybd_Event(VK_SHIFT, 0, 2, 0);

keybd_event(VK_CONTROL, MapVirtualKey(VK_CONTROL, 0), 0, 0);
keybd_event(Ord('V'), MapVirtualKey(Ord('V'), 0), 0, 0);
keybd_event(Ord('V'), MapVirtualKey(Ord('V'), 0), KEYEVENTF_KEYUP, 0);
keybd_event(VK_CONTROL, MapVirtualKey(VK_CONTROL, 0), KEYEVENTF_KEYUP, 0);

pause(strtoint(form1.Edit7.Text));
clic(strtoint(form1.Edit3.Text),strtoint(form1.Edit4.Text));
{}
  AssignFile(f, ExtractFilePath(ParamStr(0))+'patch.txt'); 
   Reset(f); 
   str:='';
   Readln(f,sad);
   Closefile(f); {Closes file F}
   Application.ProcessMessages;
  {}
clipboard.Open;
Clipboard.Clear;
CopyStringToClipboard(sad);
Application.ProcessMessages;
pause(strtoint(form1.Edit7.Text));
{1}
Keybd_event(VK_RSHIFT,0,0,0);
Keybd_event(VK_INSERT,0,0,0);
Keybd_event(VK_INSERT,0,2,0);
Keybd_Event(VK_RSHIFT, 0, 3, 0);
Keybd_Event(VK_SHIFT, 0, 0, 0);
Keybd_Event(VK_SHIFT, 0, 2, 0);
{2}
Application.ProcessMessages;
{keybd_event(VK_CONTROL, MapVirtualKey(VK_CONTROL, 0), 0, 0);
keybd_event(Ord('V'), MapVirtualKey(Ord('V'), 0), 0, 0);
keybd_event(Ord('V'), MapVirtualKey(Ord('V'), 0), KEYEVENTF_KEYUP, 0);
keybd_event(VK_CONTROL, MapVirtualKey(VK_CONTROL, 0), KEYEVENTF_KEYUP, 0);}
clipboard.Close;
pause(strtoint(form1.Edit7.Text));
clic(strtoint(form1.Edit5.Text),strtoint(form1.Edit6.Text));
form1.close;
end;

Procedure TForm1.WMHotKey(var Msg: TWMHotKey);
var
 h: HWND;
begin
 if Msg.HotKey = id1 then //id1 в FormCreate определён как id1:=GlobalAddAtom('HotKey1');RegisterHotKey(Handle, id1, 0, VK_F1)
 begin
   h:=FindWindow('Notepad', nil);
  PostMessage(h, WM_IME_KEYDOWN, VK_F5, MapVirtualKey(VK_F5, 0));
  ShowMessage('F1 pressed.');
 end;
end;