Путь к БД

procedure TDataModule2.DataModuleCreate(Sender: TObject);
var
ini:Tinifile;
begin
ini:=Tinifile.Create(extractfilepath(paramstr(0))+'Data.ini');
ini.WriteString('Open','Properties',ADOConnection1.ConnectionString);
Ini.Free;
end;

procedure TDataModule2.DataModuleCreate(Sender: TObject);
var
ini:Tinifile;
begin
ini:=Tinifile.Create(extractfilepath(paramstr(0))+'Data.ini');
ADOConnection1.ConnectionString:=ini.ReadString('Open','Properties','default value');
ADOConnection1.Connected:=True;
Ini.Free;
end;

//Подключение к БД.
procedure TForm1.Button1Click(Sender: TObject);
const
  //Файл БД располагается в папке DB, которая в свою очередь расположена в той же папке,
  //где лежит исполняемый файл программы.
  Fn = 'DB\db1.mdb';
var
  S, FileName : String;
begin
  ADOConnection1.Close;
  //Получаем полный путь к файлу БД с учётом текущего расположения исполняемого файла программы.
  FileName := ExtractFilePath(ParamStr(0)) + Fn;
  //Формируем строку соединения с учётом нового пути в файлу БД.
  S :=
    'Provider=Microsoft.Jet.OLEDB.4.0;'
    + 'Data Source="' + FileName + '";'
    + 'Mode=Share Deny None;'
    + 'User Id=;'
    + 'Password=;';
  //Записываем новую строку соединения.
  ADOConnection1.ConnectionString := S;
  //Открываем БД.
  ADOConnection1.Open;
end;

//Подключение к БД.
procedure TForm1.Button1Click(Sender: TObject);
const
  //Файл БД располагается в папке DB, которая в свою очередь расположена в той же папке,
  //где лежит исполняемый файл программы.
  Fn = 'DB\db1.mdb';
var
  FileName : String;
  i : Integer;
  Sl : TStringList;
begin
  ADOConnection1.Close;
 
  //Настройка пути к файлу базы данных.
 
  //Получаем полный путь к файлу БД с учётом текущего расположения исполняемого файла программы.
  FileName := ExtractFilePath(ParamStr(0)) + Fn;
  //Получаем параметры подключения из ADOConnection1.ConnectionString в виде списка.
  Sl := TStringList.Create;
  try
    //Перед присвоением значения свойству Text, заменяем знаки ';' на пары знаков #13#10.
    Sl.Text := StringReplace(ADOConnection1.ConnectionString, ';', #13#10, [rfReplaceAll]);
    //Проверяем, присутствует ли параметр "Data Source".
    i := Sl.IndexOfName('Data Source');
    {Параметр "Data Source" должен иметь значение, равное полному пути к файлу
    базы данных. Если параметр "Data Source" уже присутствует, то устанавливаем
    его значение. Если такого параметра нет, то добавляем этот параметр вместе
    со значением.}
    if i > -1 then
      Sl.Values['Data Source'] := '"' +FileName + '"'
    else
      Sl.Add('Data Source="' + FileName + '"');
    //Перед присвоением значения свойству ConnectionString, заменяем пары знаков #13#10
    //на знак ';'.
    ADOConnection1.ConnectionString := StringReplace(Trim(Sl.Text), #13#10, ';', [rfReplaceAll]);
  finally  
    FreeAndNil(Sl);
  end;
  
  //Открываем БД.
  ADOConnection1.Open;
end;

//Подключение к БД.
procedure TForm1.Button1Click(Sender: TObject);
var
  i : Integer;
  Ext : String;
  Sl : TStringList;
  Od : TOpenDialog;
begin
  Od := OpenDialog1; //OpenDialog1 уже должен быть на форме.
  if Od.InitialDir = '' then
    Od.InitialDir := ExtractFilePath( ParamStr(0) );
  if not Od.Execute then Exit;
  if not FileExists(Od.FileName) then begin
    MessageBox(0, 'Файл с заданным именем не найден. Действие отменено.'
      ,'Файл не найден', MB_OK + MB_ICONEXCLAMATION + MB_APPLMODAL);
    Exit;
  end;
 
  ADOConnection1.Close;
 
  //Настройка пути к файлу базы данных.
 
  //Получаем параметры подключения из ADOConnection1.ConnectionString в виде списка.
  Sl := TStringList.Create;
  try
    //Перед присвоением значения свойству Text, заменяем знаки ';' на пары знаков #13#10.
    Sl.Text := StringReplace(ADOConnection1.ConnectionString, ';', #13#10, [rfReplaceAll]);
    //Проверяем, присутствует ли параметр "Data Source".
    i := Sl.IndexOfName('Data Source');
    {Параметр "Data Source" должен иметь значение, равное полному пути к файлу
    базы данных. Если параметр "Data Source" уже присутствует, то устанавливаем
    его значение. Если такого параметра нет, то добавляем этот параметр вместе
    со значением.}
    if i > -1 then
      Sl.Values['Data Source'] := '"' + Od.FileName + '"'
    else
      Sl.Add('Data Source="' + Od.FileName + '"');
 
    //Если открывается файл MS Excel, то следует добавить дополнительный параметр.
    Ext := AnsiUpperCase(ExtractFileExt(Od.FileName));
    if (Ext = '.XLS') or (Ext = '.XLSX') then begin
      i := Sl.IndexOfName('Extended Properties');
      if i > -1 then
        Sl.Values['Extended Properties'] := 'Excel 8.0'
      else
        Sl.Add('Extended Properties=Excel 8.0');
    end else begin
      //Если это не файл MS Excel, то следует убрать дополнительный параметр.
      i := Sl.IndexOfName('Extended Properties');
      if i > -1 then Sl.Delete(i);
    end;
 
    //Перед присвоением значения свойству ConnectionString, заменяем пары знаков #13#10
    //на знак ';'.
    ADOConnection1.ConnectionString := StringReplace(Trim(Sl.Text), #13#10, ';', [rfReplaceAll]);
  finally
    FreeAndNil(Sl);
  end;
 
  //Открываем БД.
  ADOConnection1.Open;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  OpenDialog1.Execute;
  ShowMessage('Текущая папка процесса: ' + GetCurrentDir);
end;

OpenDialog1.Options := OpenDialog1.Options + [ofNoChangeDir];