При запуске программы на форме появляется линия

unit ULine;
 
interface
 
uses
  System.Classes, System.Math, Vcl.Graphics,
 
  System.Types;
 
type
  TLine = class
  private
    FX1,FY1,FX2,FY2: integer;
    FColor: TColor;
    FStyle: TPenStyle;
    FWidth: byte;
    FLength: Extended;
    FOnChange: TNotifyEvent;
    procedure DoChange;
    function Catet(I1,I2: integer): integer;
    procedure CalcLength;
    function GetRect(const X,Y: integer): TRect;
    procedure SetColor(const Value: TColor);
    procedure SetStyle(const Value: TPenStyle);
    procedure SetWidth(const Value: byte);
  public
    constructor Create(const X1,Y1,X2,Y2: integer); reintroduce;
    procedure Draw(Canvas: TCanvas);
    function CaptureStart(const X,Y: integer): boolean;
    function CaptureEnd(const X,Y: integer): boolean;
    procedure MoveStart(const X,Y: integer);
    procedure MoveEnd(const X,Y: integer);
    procedure Offset(const dX,dY: integer);
    function PointIn(const X,Y: integer): boolean;
    property Color: TColor read FColor write SetColor;
    property Style: TPenStyle read FStyle write SetStyle;
    property Width: byte read FWidth write SetWidth;
    property OnChange: TNotifyEvent read FOnChange write FOnChange;
    end;
 
var
  Line: TLine;
 
implementation
 
{ TLine }
 
procedure TLine.CalcLength;
begin
  // вычисление длины нашей прямой (по теореме Пифагора)
  FLength:= Sqrt(Sqr(Catet(FX1,FX2)) + Sqr(Catet(FY1,FY2)));
end;
 
function TLine.CaptureEnd(const X, Y: integer): boolean;
begin
  // определение, совпадает ли точка с конечной точкой линии
  Result:= PtInRect(GetRect(FX2,FY2),Point(X,Y));
end;
 
function TLine.CaptureStart(const X, Y: integer): boolean;
begin
  // определение, совпадает ли точка с начальной точкой линии
  Result:= PtInRect(GetRect(FX1,FY1),Point(X,Y));
end;
 
function TLine.Catet(I1, I2: integer): integer;
begin
  // вычисление длины катета
  Result:= Abs(I1 - I2);
end;
 
constructor TLine.Create(const X1,Y1,X2,Y2: integer);
begin
  FX1:= X1;  FY1:= Y1;
  FX2:= X2;  FY2:= Y2;
  CalcLength;
  // начальные параметры линии
  FStyle:= psSolid;
  FWidth:= 2;
  FColor:= clNavy;
end;
 
procedure TLine.DoChange;
begin
  if Assigned(FOnChange) then FOnChange(Self);
end;
 
procedure TLine.Draw(Canvas: TCanvas);
var
  OldBrush: TColor;
begin
  // рисование линии
  Canvas.Pen.Style:= FStyle;
  Canvas.Pen.Width:= IfThen(FStyle = psSolid,FWidth,1);
  Canvas.Pen.Color:= FColor;
  Canvas.MoveTo(FX1,FY1);
  Canvas.LineTo(FX2,FY2);
  // рисование конечных точек (для красоты)
  OldBrush:= Canvas.Brush.Color;
  Canvas.Brush.Color:= clLime;
  Canvas.Pen.Width:= 1;
  Canvas.Pen.Style:= psSolid;
  Canvas.Pen.Color:= clGray;
  Canvas.Rectangle(GetRect(FX1,FY1));
  Canvas.Rectangle(GetRect(FX2,FY2));
  Canvas.Brush.Color:= OldBrush;
end;
 
function TLine.GetRect(const X, Y: integer): TRect;
begin
  // вычисление "обрамляющего" точку прямоугольника
  Result:= Bounds(X-3,Y-3,6,6);
end;
 
procedure TLine.Offset(const dX, dY: integer);
begin
  // смещение всей линии
  Inc(FX1,dX);  Inc(FX2,dX);
  Inc(FY1,dY);  Inc(FY2,dY);
  DoChange;
end;
 
function TLine.PointIn(const X, Y: integer): boolean;
var
  B,C: Extended;
begin
  // вычисление, находится ли точка "над" линией, по алгоритму
  // "если сумма расстояний от точки до концов отрезка не превышает
  // длины отрезка - точка принадлежит прямой"
 
  // вычисление растояния от точки до начальной точки линии
  B:= Sqrt(Sqr(Catet(FX1,X)) + Sqr(Catet(FY1,Y)));
  // вычисление растояния от точки до конечной точки линии
  C:= Sqrt(Sqr(Catet(FX2,X)) + Sqr(Catet(FY2,Y)));
 
  // вычисление принадлежности точки отрезку
  Result:= Abs(FLength - B - C) <= 0.1;
end;
 
procedure TLine.MoveEnd(const X, Y: integer);
begin
  // новые координаты конечной точки
  FX2:= X;
  FY2:= Y;
  CalcLength;
  DoChange;
end;
 
procedure TLine.MoveStart(const X,Y: integer);
begin
  // новые координаты начальной точки
  FX1:= X;
  FY1:= Y;
  CalcLength;
  DoChange;
end;
 
procedure TLine.SetColor(const Value: TColor);
begin
  if FColor <> Value then
  begin
    FColor:= Value;
    DoChange;
  end;
end;
 
procedure TLine.SetStyle(const Value: TPenStyle);
begin
  if FStyle <> Value then
  begin
    FStyle:= Value;
    DoChange;
  end;
end;
 
procedure TLine.SetWidth(const Value: byte);
begin
  if FWidth <> Value then
  begin
    FWidth:= Value;
    DoChange;
  end;
end;
 
initialization
 
Line:= TLine.Create(50,50,200,100);
finalization
  Line.Free;
end.

unit UMain;
 
interface
 
uses
  Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
  Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls;
 
type
  TfrmMain = class(TForm)
    procedure FormPaint(Sender: TObject);
    procedure FormCreate(Sender: TObject);
    procedure FormMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
    procedure FormMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X,
      Y: Integer);
    procedure FormMouseUp(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X, Y: Integer);
  end;
 
  TJobStatus = (jsDefault,jsMoveLine,jsMoveStart,jsMoveEnd);
 
var
  frmMain: TfrmMain;
  JobStatus: TJobStatus = jsDefault;      // текущий статус задачи
  aX,aY: integer;  // позиция курсора, сохранённая при зажатии мыши на линии
 
implementation
 
{$R *.dfm}
 
uses ULine, System.Math;
 
procedure TfrmMain.FormCreate(Sender: TObject);
begin
  // подписка на события линии
  Line.OnChange:= FormPaint;
end;
 
procedure TfrmMain.FormMouseDown(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X,
  Y: Integer);
begin
  if JobStatus <> jsDefault then Exit;
  // захват начальной точки
  if Line.CaptureStart(X,Y) then
  begin
    JobStatus:= jsMoveStart;
    Line.Style:= psDot;
  end else
  // захват конечной точки
  if Line.CaptureEnd(X,Y) then
  begin
    JobStatus:= jsMoveEnd;
    Line.Style:= psDot;
  end else
  // захват всей линии
  if Line.PointIn(X,Y) then
  begin
    JobStatus:= jsMoveLine;
    aX:= X;
    aY:= Y;
  end;
end;
 
procedure TfrmMain.FormMouseMove(Sender: TObject; Shift: TShiftState; X, Y: Integer);
var
  flag: boolean;
begin
  case JobStatus of
  // выделение линии
  jsDefault:   begin
                 flag:= (Line.PointIn(X,Y) or Line.CaptureStart(X,Y) or Line.CaptureEnd(X,Y));
                 Line.Width:= IfThen(flag,4,2);
                 Line.Color:= IfThen(flag,clRed,clNavy);
                 if not flag then Cursor:= crDefault else
                 if Line.PointIn(X,Y) then Cursor:= crSizeAll
                 else Cursor:= crDrag;
               end;
  // движение всей линии
  jsMoveLine:  begin
                 Line.Offset(X-aX,Y-aY);
                 aX:= X;
                 aY:= Y;
               end;
  // перемещение начальной точки
  jsMoveStart: Line.MoveStart(X,Y);
  // перемещение конечной точки
  jsMoveEnd:   Line.MoveEnd(X,Y);
  end;
end;
 
procedure TfrmMain.FormMouseUp(Sender: TObject; Button: TMouseButton; Shift: TShiftState; X,
  Y: Integer);
begin
  JobStatus:= jsDefault;
  Line.Style:= psSolid;
end;
 
procedure TfrmMain.FormPaint(Sender: TObject);
begin
  // вызов при перерисовке формы, либо изменении состояния линии (подписка на событие)
  Canvas.FillRect(ClientRect);
  Line.Draw(Canvas);
end;
 
end.