Простейшее приложение на WinAPI

uses Windows;
var
Msg: TMsg;
  
Begin
while LongInt(GetMessage( Msg, 0, 0, 0))>0 do
begin
   TranslateMessage(msg);
   DispatchMessage(msg);
end;
end.

program Project1;
 
uses
  // функции Windows
  Windows,
  // сообщения Windows
  Messages;
 
const
  // название класса окна
  szMainWndClass: array [0..15] of Char = 'Project1MainWnd';
  // заголовок окна
  szCaption: array [0..6] of Char = 'WinAPI';
  // ошибки
  szErrClassReg: array [0..30] of Char = 'Ошибка регистрации класса окна';
  szErrCreateWnd: array [0..20] of Char = 'Ошибка создания окна';
 
var
  // дескриптор окна
  hMainWnd: HWND;
  // класс окна
  wc: WNDCLASS;
  // для обработки сообщений
  mess: MSG;
 
// функция окна
function MainWndProc(Wnd: HWND; uMsg: UINT; WPrm: WPARAM; LPrm: LPARAM): LRESULT; stdcall;
begin
  // успешное завершение обработки сообщения
  Result := 0;
  case uMsg of
    // если пришло сообщение о закрытии окна
    // его нужно удалить
    WM_CLOSE: DestroyWindow(Wnd);
    // если окно удаляется
    // отправим Windows код завершения приложения
    WM_DESTROY: PostQuitMessage(0)
  else
    // если пришло другое сообщение
    // обработаем его по умолчанию
    Result := DefWindowProc(Wnd, uMsg, WPrm, LPrm)
  end;
end;
 
begin
  // заполняем структуру класса окна
  // прорисовка при изменении размеров окна
  wc.style := CS_HREDRAW or CS_VREDRAW;
  // функция окна
  wc.lpfnWndProc := @MainWndProc;
  // дополнительный объем данных для класса
  wc.cbClsExtra := 0;
  // дополнительный объем данных для окна
  wc.cbWndExtra := 0;
  // дескриптор приложения
  wc.hInstance := HInstance;
  // стандартная иконка
  wc.hIcon := LoadIcon(0, IDI_APPLICATION);
  // стандартный указатель мыши
  wc.hCursor := LoadCursor(0, IDC_ARROW);
  // цвет окна
  wc.hbrBackground := COLOR_WINDOW;
  // ресурс главного меню
  wc.lpszMenuName := nil;
  // класс окна
  wc.lpszClassName := @szMainWndClass;
  // регистрация класса
  if RegisterClass(wc) = 0 then
    begin
      // если произошла ошибка регистрации класса
      // вывести сообщение
      MessageBox(0, @szErrClassReg, nil, MB_OK);
      Exit
    end;
  // создание окна
  hMainWnd := CreateWindow(@szMainWndClass, // класс окна
    @szCaption, // заголовок
    WS_OVERLAPPEDWINDOW, // один из стандартных стилей окна
    CW_USEDEFAULT, CW_USEDEFAULT, // положение по умолчанию
    CW_USEDEFAULT, CW_USEDEFAULT, // размеры по умолчанию
    GetDesktopWindow, // родительское окно (рабочий стол)
    0, // дескриптор главного меню
    HInstance, // дескриптор приложения
    nil); // параметр передающийся в функцию окна при создании
  if hMainWnd = 0 then
    begin
      // если окно не создано
      // вывести сообщение
      MessageBox(0, @szErrCreateWnd, nil, MB_OK);
      Exit
    end;
  // показать окно
  ShowWindow(hMainWnd, CmdShow);
  // обновить окно
  UpdateWindow(hMainWnd);
  // ожидание получения сообщения
  while GetMessage(mess, 0, 0, 0) do
    begin
      // обработка сообщения
      TranslateMessage(mess);
      // очистка сообщения
      DispatchMessage(mess)
    end;
end.