Вывод нового окна чужой программы

unit uElements;
 
interface
 
uses Types, Classes, Windows, Messages, Generics.Collections, Dialogs;
 
type
 
  TElemRec = record
    kind: string;
    number: Integer;
    text: string;
    R: TRect;
    wnd: HWND;
  end;
 
  TElemList = class(TList<TElemRec>)
  private
    ClassOfElement: string;
    function GetItem(Index: Integer): TElemRec;
    procedure SetItem(Index: Integer; const Value: TElemRec);
    procedure Fill(AWnd: HWND; AClass: string); // заполнить список элементами
    function IsElementActive(AWnd: HWND): Boolean;
  public
    function Find(const AWnd: HWND; const AText, AClass: string; const ANumber: Integer): HWND;
    property Items[Index: Integer]: TElemRec read GetItem write SetItem; default;
  strict private
    type
      PInternalEnumArgs = ^TInternalEnumArgs;
      TInternalEnumArgs = record
        Self: TElemList;
        Data: Pointer;
      end;
    // функция обёртка через которую вызывается Callback
    class function InternalCallback(AWnd: HWND; lpData: LPARAM): Bool; stdcall; static;
  protected
    function Callback(const AWnd: HWND; const lpData: Pointer): Boolean; virtual;
  end;
 
  TElem = class
  public
    class function IsElementActive(AWnd: HWND): Boolean;
    class function Element(const AClass: string; const ANumber: Integer): TElemRec;
    class function Get(const AParentWnd: HWND; const AClass: string; const ANumber: Integer): HWND; overload;
    class function Get(const AParentWnd: HWND; const AElement: TElemRec): HWND; overload;
    class function Exist(const AParentWnd: HWND; const AElement: TElemRec): Boolean; overload;
    class function Exist(AParentWnd: HWND; const AElement: TElemRec; size: TPoint; rangeWI, rangeHE: Integer): Boolean; overload;
    class function Max(const AParentWnd: HWND; const AClass: string): Integer;
// получение имени элемента в виде "имя+номер"
    class function GetName(const AParentWnd, AElementWnd: HWND): string;
 
    class procedure ClickControl(const AWnd: HWND; const AKind: string; const ANumber: Integer);
    class function GetTextFromEditbox(AWnd: HWND; Len: Integer = 255): string;
    class procedure SetTextInEditbox(AWnd: HWND; const AStr: string);
  end;
 
{==============================}
 
implementation
 
uses uStrings, uNumbers, SysUtils, Math, uWindows, uInputEmulation;
 
{==============================}
 
// получить номер последнего элемента списка заданного типа 
class function TElem.Max(const AParentWnd: HWND; const AClass: string): Integer;
var
  ListOfElements: TElemList;
begin
  ListOfElements := TElemList.Create;
  try
    ListOfElements.Fill(AParentWnd, AClass);
    Result := ListOfElements.Count;
  finally
    ListOfElements.Free;
  end;
end;
 
procedure TElemList.Fill(AWnd: HWND; AClass: string);
var
  Args: TInternalEnumArgs;
begin
  Args.Self := Self;
  Args.Data := nil;
 
  Self.Clear;
 
  ClassOfElement := AClass;
 
  EnumChildWindows(AWnd, @InternalCallback, LParam(@Args));
end;
 
function TElemList.Find(const AWnd: HWND; const AText, AClass: string; const ANumber: Integer): HWND;
var
  i: Integer;
begin
  Result := 0;
  Fill(AWnd, AClass);
 
  for i := 0 to Self.Count-1 do
    if IsElementActive(Self[i].wnd)
       and TStr.MatchPattern(AText, Self[i].Text)
       and ((ANumber = 0) or (Self[i].number = ANumber))
    then Exit(Self[i].wnd);
end;
 
class function TElemList.InternalCallback(AWnd: HWND; lpData: LPARAM): Bool;
var
  Args: PInternalEnumArgs;
begin
  Args := Pointer(lpData);
  Result := Args.Self.Callback(AWnd, Args.Data);
end;
 
function TElemList.IsElementActive(AWnd: HWND): Boolean;
begin
  Result := IsWindowEnabled(AWnd) {and IsWindowVisible(AWnd)};
end;
 
function TElemList.Callback(const AWnd: HWND; const lpData: Pointer): Boolean;
var
  StrBuf: array[0..255] of Char;
  ER: TElemRec;
  ClassFromGetClassName: string;
begin
  GetClassName(AWnd, @StrBuf, Length(StrBuf));
  ClassFromGetClassName := string(StrBuf);
 
  if ClassOfElement = ClassFromGetClassName then
  begin
    GetWindowText(AWnd, @StrBuf, Length(StrBuf));
 
    ER.kind := ClassFromGetClassName;
    ER.text := string(StrBuf);
    ER.number := Self.Count+1;
    ER.wnd := AWnd;
    Self.Add(ER);
  end;
 
  Result := True;
end;
 
function TElemList.GetItem(Index: Integer): TElemRec;
begin
  Result := FItems[Index];
end;
 
procedure TElemList.SetItem(Index: Integer; const Value: TElemRec);
begin
  FItems[Index] := Value;
end;
 
class procedure TElem.ClickControl(const AWnd: HWND; const AKind: string; const ANumber: Integer);
var
  h, wi, he: Integer;
  R: TRect;
begin
  h := Get(AWnd, AKind, ANumber);
  if h = 0 then Exit;
 
  R := TWnd.GetRect(h);
  wi := R.Right - R.Left;
  he := R.Bottom - R.Top;
  if he > wi then he := wi;
  TMouseEm.Click(h, he div 2, he div 2);
end;
 
class function TElem.Element(const AClass: string; const ANumber: Integer): TElemRec;
begin
  Result.kind := AClass;
  Result.number := ANumber;
  Result.text := '';
  Result.wnd := 0;
  Result.R := Rect(0,0,0,0);
end;
 
class function TElem.Get(const AParentWnd: HWND; const AClass: string; const ANumber: Integer): HWND;
var
  i: Integer;
  ListOfElements: TElemList;
begin
  Result := 0;
 
  ListOfElements := TElemList.Create;
  try
    ListOfElements.Fill(AParentWnd, AClass);
 
    for i := 0 to ListOfElements.Count-1 do
    begin
      if ListOfElements.IsElementActive(ListOfElements[i].wnd)
         and ( (ANumber = 0) or (ListOfElements[i].number = ANumber) )
      then
      begin
         Result := ListOfElements[i].wnd;
         Break;
      end;
    end;
  finally
    ListOfElements.Free;
  end;
end;
 
class function TElem.Exist(const AParentWnd: HWND; const AElement: TElemRec): Boolean;
begin
  Result := Self.Get(AParentWnd, AElement) <> 0;
end;
 
class function TElem.Exist(AParentWnd: HWND; const AElement: TElemRec; size: TPoint; rangeWI, rangeHE: Integer): Boolean;
var
  wnd, wi, he: Integer;
  R: TRect;
begin
  Result := False;
 
  wnd := Self.Get(AParentWnd, AElement);
  if wnd = 0 then Exit;
 
  GetWindowRect(wnd, R); wi := (R.Right - R.Left); he := (R.Bottom - R.Top);
  if InRange(wi, size.X - rangeWI, size.X + rangeWI) and InRange(he, size.Y - rangeHE, size.Y + rangeHE) then
    Result := Self.IsElementActive(wnd);
end;
 
class function TElem.Get(const AParentWnd: HWND; const AElement: TElemRec): HWND;
begin
  Result := Self.Get(AParentWnd, AElement.kind, AElement.number);
end;
 
class function TElem.GetName(const AParentWnd, AElementWnd: HWND): string;
Var
  StrBuf: array[0..255] of Char;
  i: Integer;
  s: string;
  ListOfElements: TElemList;
begin
  GetClassName(AElementWnd, StrBuf, sizeof(StrBuf));
 
  ListOfElements := TElemList.Create;
  try
    ListOfElements.Fill(AParentWnd, StrBuf);
 
    s := '';
    for i := 0 to ListOfElements.Count-1 do
    begin
      if ListOfElements[i].wnd = AElementWnd then
      begin
        s := ListOfElements[i].kind + ' ' + IntToStr(ListOfElements[i].number);
        Break;
      end;
    end;
 
    Result := s;
  finally
    ListOfElements.Free;
  end;
end;
 
class procedure TElem.SetTextInEditbox(AWnd: HWND; const AStr: string);
begin
  SendMessage(AWnd, WM_SETTEXT, 0, Integer(@AStr[1]));
end;
 
class function TElem.GetTextFromEditbox(AWnd: HWND; Len: Integer): string;
var s: string;
begin
  SetLength(s, Len);
  SetLength(s, SendMessage(AWnd, WM_GETTEXT, Len, Integer(@s[1])));
  Result := s;
  //SetLength(s, 0);
end;
 
class function TElem.IsElementActive(AWnd: HWND): Boolean;
begin
  Result := IsWindowEnabled(AWnd) and IsWindowVisible(AWnd);
end;
 
procedure SelfTest;
var
  wnd: HWND;
  ListOfElements: TElemList;
begin
  wnd := FindWindow('Progman', nil);
//  wnd := TWnd.FindWindow('*', 'TAppBuilder', [inMask, inKind, fwFirstOnly]);
  if wnd = 0 then Exit;
 
  ListOfElements := TElemList.Create;
  try
    ListOfElements.Fill(wnd, 'SysListView32');
  finally
    ListOfElements.Free;
  end;
 
  Assert(TElem.Get(wnd, TElem.Element('SHELLDLL_DefView', 1)) <> 0, 'TElem.Get');
  Assert(TElem.Get(wnd, TElem.Element('SysListView32', 1)) <> 0, 'TElem.Get');
  Assert(TElem.Get(wnd, TElem.Element('NoExistClass', 1)) = 0, 'TElem.Get');
  Assert(TElem.Max(wnd, 'SHELLDLL_DefView') = 1, 'TElem.Max');
end;
 
{==============================}
 
initialization
 
{$IFDEF DEBUG}
  SelfTest();
{$ENDIF}
 
{==============================}
 
end.