Понять чем создан данный файл и попытаться его прочитать

{$APPTYPE CONSOLE}
uses
  Windows,ShellAPI;
 
function printf(const Format: PAnsiChar): Integer; cdecl; varargs; external 'msvcrt.dll';
 
var
  buf: packed record
       Text1Len:        byte;
       Text1:           array[0..99] of AnsiChar;  //неизвестная строка
       WorkShiftLen:    byte;
       WorkShift:       array[0..99] of AnsiChar;  //смена
       MasterLen:       byte;
       Master:          array[0..99] of AnsiChar;  //мастер
       ThermistLen:     byte;
       Thermist:        array[0..99] of AnsiChar;  //термист
       Text2Len:        byte;
       Text2:           array[0..99] of AnsiChar;  //неизвестная строка
       RailLen:         byte;
       Rail:            array[0..99] of AnsiChar;  //плеть
       SpliceLen:       byte;
       Splice:          array[0..99] of AnsiChar;  //стык
       align:           array[0..4] of byte;       //выравнивание по границе 8 байт
       Date:            double;                    //Дата (в целой части количество дней, прошедших с 30.12.1899
       Time:            double;                    //Время начала обработки(в дробной части доля суток, например 0.5 - это полдень, 0 - полночь)
       HeatTemp:        word;                      //Температура нагрева в градусах по шкале Цельсия
       HeatTime:        word;                      //Время нагрева в секундах
       ExposureTime:    word;                      //Время выдержки в секундах
       DevChangeTime:   word;                      //Время смены устройства в секундах
       HardingTime:     word;                      //Время закалки в секундах
       AfterHardingTemp:word;                      //Температура после закалки в градусах по шкале Цельсия
       AirPressure:     word;                      //Давление воздуха в килопаскалях (КПа)
       Value0:          word;                      //Неизвестное значение
       ResultLen:       byte;
       Result:          array[0..99] of AnsiChar;  //Результат
       align2:          array[0..2] of byte;       //Выравнивание по границе 4 байта
       Value1:          integer;                   //Дальше какие-то неизвестные значения
       Value2:          integer;
       Value3:          word;
       HeatGraph:       array[0..10000] of word;   //График нагрева в градусах по шкале Цельсия
       HardingGraph1:   array[0..10000] of word;   //График закалки в килопаскалях (КПа)
       HardingGraph2:   array[0..10000] of word;   //График закалки в килопаскалях (КПа)
       end;
 
  f:       THANDLE;
  ftime:   FILETIME;
  systime: SYSTEMTIME;
  i:       integer;
  j:       DWORD;
  Args:    array of PWideChar;
 
begin
  SetConsoleOutputCP(1251);
  //Получаем массив параметров коммандной строки
  Pointer(Args):=CommandLineToArgvW(GetCommandLineW,i);
  if Args[1]<>nil then
  begin
    //Читаем файл
    f:=CreateFileW(Args[1],GENERIC_READ,0,0,OPEN_EXISTING,0,0);
    Pointer(Args):=0;
    ReadFile(f,buf,sizeof(buf),j,0);
    CloseHandle(f);
    //Конвертируем TDateTime в FILETIME
    pint64(@ftime)^:=round(buf.Date*24*60*60*10000000+94353120000000000+buf.Time*24*60*60*10000000);
    //Конвертируем FILETIME в SYSTEMTIME
    FileTimeToSystemTime(ftime,systime);
    //Выводим на экран
    printf('Смена                     %s'#13#10+
           'Мастер                    %s'#13#10+
           'Термист                   %s'#13#10+
           'Плеть                     %s'#13#10+
           'Стык                      %s'#13#10+
           'Дата                      %02u.%02u.%04u'#13#10+
           'Время начала обработки    %02u:%02u:%02u'#13#10+
           'Температура нагрева       %u '#176'C'#13#10+
           'Время нагрева             %u сек'#13#10+
           'Время выдержки            %u сек'#13#10+
           'Время смены устройства    %u сек'#13#10+
           'Время закалки             %u сек'#13#10+
           'Температура после закалки %u '#176'C'#13#10+
           'Давление воздуха          0,%u (МПа)'#13#10+
           'Результат                 %s',
           buf.WorkShift,
           buf.Master,
           buf.Thermist,
           buf.Rail,
           buf.Splice,
           systime.wDay,systime.wMonth,systime.wYear,
           systime.wHour,systime.wMinute,systime.wSecond,
           buf.HeatTemp,
           buf.HeatTime,
           buf.ExposureTime,
           buf.DevChangeTime,
           buf.HardingTime,
           buf.AfterHardingTemp,
           buf.AirPressure,
           buf.Result);
  end
  else
    printf('Имя файла не задано');
  printf(#13#10#13#10#13#10'Нажмите Escape для выхода...');
  while GetAsyncKeyState(VK_ESCAPE)=0 do; //Бесклнечный цикл
end.