Работа с памятью

  
pzap = ^tzap;
  tzap = record
  nom,code,name,author,year: string;
prev,next: pzap;
 end;
 
 
  first,last,i,v,sp: pzap;

procedure TForm1.Button2Click(Sender: TObject);
type
  TPZap = ^TZap;
  TZap = record
    nom, code, name, author, year : string;
    prev, next: TPZap;
  end;
var
  PTmp, PCur : TPZap;
  PStart, PEnd : TPZap;
  i : Integer;
begin
  //Создаём первую запись и инициализируем список.
  New(PTmp);
  PTmp^.nom := '1';
  PStart := PTmp;
  PEnd := PTmp;
  PTmp^.prev := nil;
  PTmp^.next := nil;
 
  //Добавляем в список вторую запись.
  New(PTmp);
  PTmp^.nom := '2';
  PTmp^.prev := PEnd;
  PTmp^.next := nil;
  PEnd^.next := PTmp;
  PEnd := PTmp;
 
  //Добавляем в список третью запись.
  New(PTmp);
  PTmp^.nom := '3';
  PTmp^.prev := PEnd;
  PTmp^.next := nil;
  PEnd^.next := PTmp;
  PEnd := PTmp;
 
  //Добавляем в список четвёртую запись.
  New(PTmp);
  PTmp^.nom := '4';
  PTmp^.prev := PEnd;
  PTmp^.next := nil;
  PEnd^.next := PTmp;
  PEnd := PTmp;
 
  //1. Подсчитать общее количество записей в списке.
 
  PTmp := PStart;
  i := 0;
  while PTmp <> nil do begin
    Inc(i);
    PTmp := PTmp^.next;
  end;
 
  ShowMessage('1. Всего в списке ' + IntToStr(i) + ' записей.');
 
  //2. Переместиться к третьей записи, считая от начала списка.
 
  PTmp := PStart;
  i := 0;
  while ( PTmp <> nil ) and ( i < 3 ) do begin
    Inc(i);
    PCur := PTmp;
    PTmp := PTmp^.next;
  end;
 
  if i < 3 then begin
    ShowMessage('2. Не удалось перейти к 3 записи от начала списка, т. к. список оказался короче.');
  end else begin
    ShowMessage('2. Третья запись от начала списка: PCur^.nom = "' + PCur^.nom + '"');
  end;
 
  //3. Переместиться к третьей записи, считая от конца списка.
 
  PTmp := PEnd;
  i := 0;
  while ( PTmp <> nil ) and ( i < 3 ) do begin
    Inc(i);
    PCur := PTmp;
    PTmp := PTmp^.prev;
  end;
 
  if i < 3 then begin
    ShowMessage('3. Не удалось перейти к 3 записи от конца списка, т. к. список оказался короче.');
  end else begin
    //Так как в списке 4 записи, то текущей будет (4 - 3 + 1) = 2 запись, считая от начала списка.
    ShowMessage('3. Третья запись от конца списка: PCur^.nom = "' + PCur^.nom + '"');
  end;
 
  //4. Удалить 3 запись, считая от начала списка.
 
  PTmp := PStart;
  i := 0;
  while ( PTmp <> nil ) and ( i < 3 ) do begin
    Inc(i);
    PCur := PTmp;
    PTmp := PTmp^.next;
  end;
 
  if i < 3 then begin
    ShowMessage('4. Не удалось перейти к 3 записи от начала списка, т. к. список оказался короче.');
  end else begin
    if PCur^.next <> nil then
      PCur^.next^.prev := PCur^.prev
    else
      PEnd := PCur^.prev
    ;
    if PCur^.prev <> nil then
      PCur^.prev^.next := PCur^.next
    else
      PStart := PCur^.next
    ;
 
    Dispose(PCur);
 
    ShowMessage('4. Третья запись от начала списка удалена.');
  end;
 
  //5. Переместиться к третьей записи, считая от начала списка.
 
  PTmp := PStart;
  i := 0;
  while ( PTmp <> nil ) and ( i < 3 ) do begin
    Inc(i);
    PCur := PTmp;
    PTmp := PTmp^.next;
  end;
 
  if i < 3 then begin
    ShowMessage('5. Не удалось перейти к 3 записи от начала списка, т. к. список оказался короче.');
  end else begin
    //Т. к. ранее была удалена 3 запись и сейчас в списке осталось 3 записи,
    //то текущей окажется запись, у которой: PCur^.nom = '4'.
    ShowMessage('5. Третья запись от начала списка: PCur^.nom = "' + PCur^.nom + '"');
  end;
 
  //6. Удаялем список из памяти.
 
  PCur := PStart;
  while PCur <> nil do begin
    PTmp := PCur;
    PCur := PCur^.next;
    Dispose(PTmp);
  end;
  PStart := nil;
  PEnd := nil;
  PCur := nil;
  PTmp := nil;
 
  ShowMessage('6. Список удалён из памяти.');
 
end;