Как подключить include к flat компилятору

; Extended Win32 programming headers (ASCII)
include 'win32a.inc'
include 'macro/if.inc'
.....
; Что делать, если встретишь директиву 'Import'
macro import lib,[functions]
{ common macro import_#lib \{ import lib,functions \} }
 
; Что делать, если встретишь 'API'
macro api [functions]
{ common macro all_api \{ all_api
              api functions \} }
 
; Что делать, если встретишь 'ALL-API'
macro all_api {}               
 
include 'api/kernel32.inc'     ;<----; ВНИМАНИЕ!!!
include 'api/user32.inc'             ; Подключить все функции из указанных файлов!
include 'api/gdi32.inc'              ; т.е. вызвав 'win32ах.inc' не нужно вызывать остальные,
include 'api/advapi32.inc'           ; но при условии, что используем макрос '.end' (см.ниже)!
include 'api/comctl32.inc'
include 'api/comdlg32.inc'
include 'api/shell32.inc'
include 'api/wsock32.inc'
 
purge import,api                     ; (отменить последнее определение)
 
; А здесь макросы для описания укороченых директив,
; из которых интересна только директива '.end' - посмотрите, что она делает!!!
; (границы каждого макроса определяются фигурными скобками)
;-----------------------------------------------------------
macro .data { section '.data' data readable writeable }
macro .code { section '.text' code readable executable }
macro .end label
{    entry label
              section '.idata' import data readable writeable
 
library kernel32,'KERNEL32.DLL',\
         user32,'USER32.DLL',\
           gdi32,'GDI32.DLL',\
           advapi32,'ADVAPI32.DLL',\
           comctl32,'COMCTL32.DLL',\
           comdlg32,'COMDLG32.DLL',\
           shell32,'SHELL32.DLL',\
           wsock32,'WSOCK32.DLL'
 
        import_kernel32
        import_user32
        import_gdi32
        import_advapi32
        import_comctl32
        import_comdlg32
        import_shell32
        import_wsock32
 
        all_api           ;<-----; Вызываем макрос 'ALL-API' !!!
}                                ; конец макроса '.end'

format  PE  gui 4.0           ; делаю гуй-приложение
include 'win32ax.inc'         ; волшебный инклуд
 
.data
capt     db   'Читаем из реестра',0            ; заголовок окна
string   db   'Версия BIOS:  '                 ; текст в окне (продолжение в буфере ниже)
buff     db   32 dup(0)                        ; буфер под строку реестра
bSize    dd   32                               ; размер буфера
subKey   db   'Hardware\Description\System',0  ; ветка реестра (раздел - в самой функции)
key      db   'SystemBiosVersion',0            ; выбираем строку в правом окне реестра
hndl     dd   0                                ; дескриптор ветки
type     dd   0                                ; тип данных
 
.code
start:
; Открываем ветку реестра
       invoke   RegOpenKeyEx,HKEY_LOCAL_MACHINE,subKey,0,KEY_ALL_ACCESS,hndl
; Читаем строку реестра в свой буфер
       invoke   RegQueryValueEx,[hndl],key,0,type,buff,bSize
; Выводим строку в окошко
       invoke   MessageBox,0,string,capt,0
       invoke   ExitProcess, 0
.end start                       ;<------; макрос '.end' импортирует функции сам!